Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
fehlender Operator mit Dlookup im VBA code
zurück: Übergabe von datensätzen weiter: komischer dll funktionsname Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
derArb
getting better


Verfasst am:
06. Mai 2007, 20:35
Rufname: derArb
Wohnort: Berlin

fehlender Operator mit Dlookup im VBA code - fehlender Operator mit Dlookup im VBA code

Nach oben
       Version: Office XP (2002)

hallo,

irgendwie finde ich den Fehler nicht und weiss nicht, wo der Fehler liegt.
Bei der Ausführung des folgenden codes bekomm ich immer den Error 'fehlender Operator'
Das Tabellenfeld 'KursdatumVon' = Typ Datum/Uhrzeit
Das Tabellenfeld 'KursdatumBis' = Typ Datum/Uhrzeit
Code:
    '...
    If DLookup("ID_Kurse", "tbl_ZWTabelle1", _
               "ID_Kurse <> " & Me.Parent!ID_Kurse) And _
       DLookup("KursdatumVon", "tbl_Kurse", _
               "KursdatumVon Between " & Format(Me.Parent!KursdatumVon, _
                                                "\#yyyy\-mm\-dd\#") & _
                               " And " & Format(Me.Parent!KursdatumBis, _
                                                "\#yyyy\-mm\-dd\#")) Then
        MsgBox "Die Person ist schon in einem anderen Kurs gleichzeitig angemeldet."
        Me.Undo
        Exit Sub
      Else
    '...
ich würde mich freuen, wenn jemand mir da weiterhelfen würde.
mfg
derArb

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.



fehlender Operator.jpg
 Beschreibung:
 Dateigröße:  43.89 KB
 Angeschaut:  5359 mal

fehlender Operator.jpg


Tom2002
Der einzig Wahre Leuchtturm - Pilsum


Verfasst am:
06. Mai 2007, 23:35
Rufname:
Wohnort: Düsseldorf


AW: fehlender Operator mit Dlookup im VBA code - AW: fehlender Operator mit Dlookup im VBA code

Nach oben
       Version: Office XP (2002)

Moin,

das kann IMHO auch nicht funzen.

Das ist kein Access, sondern ein Logik Problem.

Schau mal genau, wie du das Kursdatum prüfst.

Ciao

Tom

_________________
Win7, Win2008 R2, Office 2010 Prof

Wer mit Fortuna Düsseldorf groß geworden ist, der fürchtet sich auch vor Access nicht.
Die Nutzlosigkeit des Daseins anzuerkennen heisst, Fortuna-Fan zu sein.
derArb
getting better


Verfasst am:
06. Mai 2007, 23:43
Rufname: derArb
Wohnort: Berlin

AW: fehlender Operator mit Dlookup im VBA code - AW: fehlender Operator mit Dlookup im VBA code

Nach oben
       Version: Office XP (2002)

hallo Tom,

danke...werde weiterwühlen
Welches Logikproblem kann das sein?...bei fehlendem Operator?

mfg
derArb

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.
steffen0815
VBA-Programmierer


Verfasst am:
07. Mai 2007, 08:57
Rufname:

AW: fehlender Operator mit Dlookup im VBA code - AW: fehlender Operator mit Dlookup im VBA code

Nach oben
       Version: Office XP (2002)

Hallo,
also der Fehler selbst dürfte darin liegen, dass das Feld "Me.Parent!KursdatumBis" leer ist, was eigentlich aus der Fehlermeldung eindeutig hervor geht:
Zitat:
'KursdatumVon beetween #2007-03-03# and'
and ... eben nichts Wink

Ansonsten hinkt aber meiner Meinung nach der Vergleich.
Aufgelöst käme in etwa heraus:
Code:
       DLookup("ID_Kurse", "tbl_ZWTabelle1", _
               "ID_Kurse <> " & Me.Parent!ID_Kurse) : eine Zahl (z.B. 123)

       DLookup("KursdatumVon", "tbl_Kurse", _
               "KursdatumVon Between " & Format(Me.Parent!KursdatumVon, _
                                                "\#yyyy\-mm\-dd\#") & _
                               " And " & Format(Me.Parent!KursdatumBis, _
                                                "\#yyyy\-mm\-dd\#"))  : ein Datum (z.B. 1.1.01)
Code:
 If 123 And #01-01-01# Then
Dies erschließt sich mir nicht Wink
_________________
Gruß Steffen
derArb
getting better


Verfasst am:
07. Mai 2007, 20:15
Rufname: derArb
Wohnort: Berlin

AW: fehlender Operator mit Dlookup im VBA code - AW: fehlender Operator mit Dlookup im VBA code

Nach oben
       Version: Office XP (2002)

hallo,
danke Steffen0815..das war es auch...fehlendes KursdatumBis im aktuellen Datensatz... Embarassed

ansonsten suche ich in Worten:
Wenn ein Teilnehmer in einem anderen Kurs im selben Zeitraum angemeldet ist,
dann soll ein Eintrag im aktuellen Datensatz verhindert werden.
andererseits
Wenn er schon in diesem Kurs eingetragen ist, dann soll eine doppelte Eintragung verhindert werden.

Mit meinem code schaff ich das so nicht.

Egon Süss möchte an Kurs 1 teilnehmen
Kurs 1
KursdatumVon: 01.03.2007
KursdatumBis: 10.03.2007
KursUhrzeitVon: 12:00
KursUhrzeitBis: 16:00
Teilnehmereingabe: Egon Süss
Status: akzeptiert

Nun möchte Egon Süss auch an Kurs 2 teilnehmen
Kurs 2
KursdatumVon: 04.03.2007 (Kurs 1: 01.03.2007)
KursdatumBis: 12.03.2007 (Kurs 1: 10.03.2007)
KursUhrzeitVon: 11:00
KursUhrzeitBis: 15:00
Teilnehmereingabe: Egon Süss
Status: nicht akzeptiert wegen Datumsüberlappung

Nun möchte Egon Süss auch an Kurs 3 teilnehmen
Kurs 3
KursdatumVon: 01.03.2007 (Kurs 1: 01.03.2007)
KursdatumBis: 10.03.2007 (Kurs 1: 10.03.2007)
KursUhrzeitVon: 16:30 (Kurs 1: 12:00)
KursUhrzeitBis: 18:00 (Kurs 1: 16:00)
Teilnehmereingabe: Egon Süss
Status: akzeptiert, da zwar dasselbe Datum, aber nicht überlappenende Uhrzeit
Code:
Private Sub cboPersonenauswahl_BeforeUpdate(Cancel As Integer)
    If DLookup("ID_Kurse", "tbl_ZWTabelle1", _
               "ID_Kurse <> " & Me.Parent!ID_Kurse) Then
        If DLookup("KursdatumVon", "tbl_Kurse", _
                   "KursdatumVon Between " & Format(Me.Parent!KursdatumVon, _
                                                    "\#yyyy\-mm\-dd\#") & _
                                   " And " & Format(Me.Parent!KursdatumBis, _
                                                    "\#yyyy\-mm\-dd\#")) Then
            If DLookup("KursdatumBis", "tbl_Kurse", _
                       "KursdatumBis Between " & _
                        Format(Me.Parent!KursdatumVon, "\#yyyy\-mm\-dd\#") & _
                                       " And " & _
                      Format(Me.Parent!KursdatumBis, "\#yyyy\-mm\-dd\#")) Then
                If DLookup("KursUhrzeitVon", "tbl_Kurse", _
                           "KursUhrzeitVon Between " & _
                          Format(Me.Parent!KursUhrzeitVon, "\#hh:nn:ss\#") & _
                                             " And " & _
                        Format(Me.Parent!KursUhrzeitBis, "\#hh:nn:ss\#")) Or _
                   DLookup("KursUhrzeitBis", "tbl_Kurse", _
                           "KursUhrzeitBis Between " & _
                          Format(Me.Parent!KursUhrzeitVon, "\#hh:nn:ss\#") & _
                                             " And " & _
                        Format(Me.Parent!KursUhrzeitBis, "\#hh:nn:ss\#")) Then
                    If DLookup("ID_persdat", "tbl_ZWTabelle1", _
                        "ID_persdat= " & Me!cboPersonenauswahl.Column(0)) Then
                        MsgBox "Die Person ist schon in einem anderen " & _
                               "Kurs gleichzeitig angemeldet."
                        Me.Undo
                      Else
                        If DLookup("ID_persdat", "tbl_ZWTabelle1", _
                        "ID_persdat= " & Me!cboPersonenauswahl.Column(0)) Then
                            MsgBox "Die Person ist schon in diesem " & _
                                   "Kurs eingetragen"
                            Me.Undo
                          Else
                            Me!txtVorname = Me!cboPersonenauswahl.Column(5)
                            Me!txtNachname = Me!cboPersonenauswahl.Column(6)
                            Me!txtTelefon = Me!cboPersonenauswahl.Column(8)
                        End If
                    End If
                End If
            End If
        End If
    End If
End Sub
vielen Dank für jeden Tip

mfg
derArb
Nachtrag: derArb am 08. Mai 2007 um 01:59 hat folgendes geschrieben:
Hallo,

hier die Lösung
Es wird geprüft, ob der Teilnehmer in einem anderen Kurs vorhanden ist,
dessen 'KursdatumVon' zwischen 'KursdatumVon' und 'KursdatumBis' des
aktuellen Datensatzes liegt und dessen 'KursUhrzeitVon' zwischen 'KursUhrzeitVon' und 'KursUhrzeitBis' des aktuellen Datensatzes liegt.
Eine zusätzliche Prüfung auf 'KursdatumBis' und 'KursUhrzeitBis' ist nur noch
ein bischen copy paste Arbeit.
Code:
Private Sub cboPersonenauswahl_BeforeUpdate(Cancel As Integer)
    If DLookup("ID_Kurse", "tbl_Kurse", _
               "ID_Kurse <> " & Me.Parent!ID_Kurse & _
          " AND KursdatumVon Between " & Format(Me.Parent!KursdatumVon, _
                                                "\#yyyy\-mm\-dd\#") & _
                               " And " & Format(Me.Parent!KursdatumBis, _
                                                "\#yyyy\-mm\-dd\#") & _
          " AND KursUhrzeitVon Between " & Format(Me.Parent!KursUhrzeitVon, _
                                                  "\#hh:nn:ss#\") & _
                                 " And " & Format(Me.Parent!KursUhrzeitBis, _
                                                  "\#hh:nn:ss#\")) Then
        MsgBox "Die Person ist schon in einem anderen Kurs gleichzeitig " & _
               "angemeldet."
        Me.Undo
        Me!txtVorname = ""
        Me!txtNachname = ""
        Me!txtTelefon = ""
     Else
        If DLookup("ID_Kurse", "tbl_ZWTabelle1", _
                   "ID_Kurse = " & Me.Parent!ID_Kurse & _
              " AND ID_persdat= " & Me!cboPersonenauswahl.Column(0)) Then
            MsgBox "Die Person ist schon in diesem Kurs eingetragen"
            Me.Undo
            Me!txtVorname = ""
            Me!txtNachname = ""
            Me!txtTelefon = ""
          Else
            Me!txtVorname = Me!cboPersonenauswahl.Column(5)
            Me!txtNachname = Me!cboPersonenauswahl.Column(6)
            Me!txtTelefon = Me!cboPersonenauswahl.Column(8)
        End If
    End If
End Sub

Private Sub Form_Current()
    Me!txtVorname = Me!cboPersonenauswahl.Column(5)
    Me!txtNachname = Me!cboPersonenauswahl.Column(6)
    Me!txtTelefon = Me!cboPersonenauswahl.Column(8)
End Sub

mfg
derArb

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.
Nouba
nicht ganz unwissend :)


Verfasst am:
08. Mai 2007, 06:02
Rufname:
Wohnort: Berlin

AW: fehlender Operator mit Dlookup im VBA code - AW: fehlender Operator mit Dlookup im VBA code

Nach oben
       Version: Office XP (2002)

Hallo derArb,

ich vermute, dass Du einer Scheinlösung aufgesessen bist - das And ist ein logisches Und, was nicht mit einem mathematischen Plus (+) verwechselt werden sollte. Du musst die Uhrzeiten schon zum Datum addieren oder besser gleich in einem Feld belassen. Außerdem solltest Du den kompletten Zeitraum von Anfang bis zum Ende des Kurses prüfen. Denn wenn z. Bsp. der zu prüfende Kurs um 9:00 Uhr beginnt und zwei Stunden dauert, der Teilnehmer aber ab 10:00 Uhr einen weiteren Kurs belegt hat, darf wohl auch kein neuer Datensatz statthaft sein. Schau Dir vielleicht in diesem Zusammenhang einmal Allen Brownes Clashing Events/Appointments an.

_________________
mit freundlichen Grüssen Nouba

Wenn beim Lesen eines Beitrags der Eindruck entsteht, dass sich der Fragesteller wenig Mühe gegeben hat, so erhöht das nicht unbedingt die Motivation, eine Antwort zu verfassen.
Tom2002
Der einzig Wahre Leuchtturm - Pilsum


Verfasst am:
08. Mai 2007, 11:18
Rufname:
Wohnort: Düsseldorf

AW: fehlender Operator mit Dlookup im VBA code - AW: fehlender Operator mit Dlookup im VBA code

Nach oben
       Version: Office XP (2002)

Hi,

ich denke, so könnte es gehen.

Verbesserungen sind gerne gesehen und Fehler dürfen korrigiert werden. Laughing

Ciao

Tom

_________________
Win7, Win2008 R2, Office 2010 Prof

Wer mit Fortuna Düsseldorf groß geworden ist, der fürchtet sich auch vor Access nicht.
Die Nutzlosigkeit des Daseins anzuerkennen heisst, Fortuna-Fan zu sein.



BspBelegung.zip
 Beschreibung:
Belegungsplan (Acc 2000)

Download
 Dateiname:  BspBelegung.zip
 Dateigröße:  14.88 KB
 Heruntergeladen:  204 mal

derArb
getting better


Verfasst am:
10. Mai 2007, 04:39
Rufname: derArb
Wohnort: Berlin


AW: fehlender Operator mit Dlookup im VBA code - AW: fehlender Operator mit Dlookup im VBA code

Nach oben
       Version: Office XP (2002)

derArb am 08. Mai 2007 um 22:51 hat folgendes geschrieben:
hallo,

20 Zeilen Erklärung, dann Datei anhängen und Vorschau einschalten....ALLES WEG

vielen Dank erst nochmal...
etwas verkürzt nochmal (sorry... ich hatte alles so schön geschrieben)

@Nouba,
and und "+" Problem erkenn ich in meinem code nicht
bis auf die von Tom2007 unten angegebenen Probleme gehts eigentlich (denke ich)
ich wollte es erst mal begreifen, ob ich das mit Dlookup schaffen kann.
In der ganzen Geschichte ist eine m:n Zwischentabelle drin und man sieht evtl. nicht sofort, worauf mein code hinaus will

@tom2007
danke..danke für Dein Beispiel
in Deinem Beispiel fehlt aber der Zimmermieter, der immer nur ein Zimmer
pro Datum und Uhrzeit mieten kann
aber der Hinweis auf Vor- und Nachüberlappungen von Terminen ist sehr wertvoll.
Ebenso Deine liebenswert zur Verfügung gestellte Funktion..., welche nur das Zimmer(Kurs), aber nicht den Benutzer des Zimmers(Kurs) berücksichtigt

Meine Idee ist:
Es gibt ein Kurssystem mit mehreren Kursen
Ein Interessent meldet sich allgemein
Die Daten des Interessenten werden allgemein aufgenommen, da er noch nicht
genau weiss, in welche Kurs er gehen will.
Ein paar Tage später entscheidet sich der Interessent für einen Kurs.
Er wird eingetragen.
Kurze Zeit später will er einen 2. schon existierenden Kurs ebenfalls belegen.
Wichtig ist also, ob der Kursteilnehmer sich selbst überlappt in den gewünschten Kursterminen bis hin zur Uhrzeitabfrage.
UND: Wichtig ist, dass bei der Eingabe des Teilnehmers in einen anderen Kurs
seine Verfügbarkeit abgefragt wird.

Ich will den Kursort noch aussen vorlassen, denn da müsste man wieder
die Erreichbarkeit innerhalb bestimmter Zeiten berücksichtigen.

hier meine bisherige DB
mfg
derArb

derArb am 08. Mai 2007 um 23:09 hat folgendes geschrieben:
hallo,

mein Problem ist als 'beantwortet' abgehakt.
schade..trotzdem danke für jeden Input bisher

mfg
derArb

Hallo,

Jetzt aber funktionert es...Danke nochmal Tom2007 für den Hinweis mit den Zeitüberlappungen.
Ich musste noch eine Vereinigungsabfrage erstellen, auf welche ich nun zugreife.

Ein Listenfeld in einem Meldungsformular zeigt den überlappenden Kurs an
Code:
Private Sub cboPersonenauswahl_BeforeUpdate(Cancel As Integer)
    Dim strSQL As String
    Dim DatumVon As String
    Dim DatumBis As String
    Dim UhrzeitVon As String
    Dim UhrzeitBis As String
   
    DatumVon = Format(Me.Parent!KursdatumVon, "\#yyyy\-mm\-dd\#")
    DatumBis = Format(Me.Parent!KursdatumBis, "\#yyyy\-mm\-dd\#")
    UhrzeitVon = Format(Me.Parent!KursUhrzeitVon, "\#hh:nn:ss\#")
    UhrzeitBis = Format(Me.Parent!KursUhrzeitBis, "\#hh:nn:ss\#")
    strSQL = "SELECT K.ID_Kurse, P.ID_Persdat, K.Kursname, P.Vorname, " & _
                    "P.Nachname, K.KursdatumVon, K.KursDatumBis, " & _
                    "K.KursUhrzeitVon, K.KursUhrzeitBis " & _
               "FROM tbl_persdat AS P " & _
                    "INNER JOIN (tbl_kurse AS K " & _
                                "INNER JOIN tbl_ZwTabelle1 AS Z " & _
                                "ON K.ID_Kurse = Z.ID_Kurse) " & _
                    "ON P.ID_Persdat = Z.ID_Persdat " & _
              "WHERE K.ID_Kurse <> " & Me.Parent!ID_Kurse & _
               " AND P.ID_Persdat = " & Me!cboPersonenauswahl.Column(0) & _
               " AND KursdatumVon <= " & DatumBis & _
               " AND KursdatumBis >= " & DatumVon & _
               " AND KursUhrzeitVon <= " & UhrzeitBis & _
               " AND KursUhrzeitBis >= " & UhrzeitVon
    If DLookup("ID_Kurse", "qry_Kurs", _
               "ID_Kurse <> " & Me.Parent!ID_Kurse & _
          " AND ID_persdat= " & Me!cboPersonenauswahl.Column(0) & _
          " AND KursdatumVon <= " & DatumBis & _
          " AND KursdatumBis >= " & DatumVon & _
          " AND KursUhrzeitVon <= " & UhrzeitBis & _
          " AND KursUhrzeitBis >= " & UhrzeitVon) Then
        DoCmd.OpenForm "frm_Kursmeldung", acDesign, , , , acDialog
        Forms!frm_Kursmeldung!LstKursübersicht.RowSource = strSQL
        DoCmd.Beep
        Me.Undo
        Me!txtVorname = ""
        Me!txtNachname = ""
        Me!txtTelefon = ""
        Exit Sub
      Else
        If DLookup("ID_Kurse", "tbl_ZWTabelle1", _
                   "ID_Kurse = " & Me.Parent!ID_Kurse & _
              " AND ID_persdat= " & Me!cboPersonenauswahl.Column(0)) Then
            MsgBox "Die Person ist schon in diesem Kurs eingetragen"
            Me.Undo
            Me!txtVorname = ""
            Me!txtNachname = ""
            Me!txtTelefon = ""
          Else
            Me!txtVorname = Me!cboPersonenauswahl.Column(5)
            Me!txtNachname = Me!cboPersonenauswahl.Column(6)
            Me!txtTelefon = Me!cboPersonenauswahl.Column(8)
        End If
    End If
End Sub

Private Sub Form_Current()
    Me!txtVorname = Me!cboPersonenauswahl.Column(5)
    Me!txtNachname = Me!cboPersonenauswahl.Column(6)
    Me!txtTelefon = Me!cboPersonenauswahl.Column(8)
End Sub
und die Beispiel DB im Anhang.

mfg
derArb
Nachtrag: derArb am 17. Mai 2007 um 22:23 hat folgendes geschrieben:
hallo,

tut mir leid...das Thema hat sich langsam in anderen Themen verteilt
hier das Ergebnis inkl. Beispiel DB und danke an Tom2002 nochmal
Listboxsteuereung in komplexer HF-Ufo Situation

mfg
derArb

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.



KursDB 2a.zip
 Beschreibung:

Download
 Dateiname:  KursDB 2a.zip
 Dateigröße:  62.14 KB
 Heruntergeladen:  184 mal

Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Bestandsführung mit DLookup 21 doni3331 702 22. Jun 2013, 16:25
Bitsqueezer Bestandsführung mit DLookup
Keine neuen Beiträge Access Tabellen & Abfragen: Like Operator in Abfrage 4 crack24 89 17. Apr 2013, 12:38
JMalberg Like Operator in Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: SQL Like Operator findet zu viele Ergebnisse 14 realShadow 391 05. Jun 2012, 16:44
MissPh! SQL Like Operator findet zu viele Ergebnisse
Keine neuen Beiträge Access Tabellen & Abfragen: Dlookup gibt keinen Wert zurück 31 licherman. 1333 19. Jan 2012, 11:44
Gast Dlookup gibt keinen Wert zurück
Keine neuen Beiträge Access Tabellen & Abfragen: VBA Code in Makro einbinden uns ausführen! 3 Gast 6975 12. Mai 2011, 17:32
MissPh! VBA Code in Makro einbinden uns ausführen!
Keine neuen Beiträge Access Tabellen & Abfragen: Fehlender Parameter in SQL 2 Slovak 592 13. Sep 2010, 09:01
Slovak Fehlender Parameter in SQL
Keine neuen Beiträge Access Tabellen & Abfragen: DLOOKUP funktioniert nicht mit deutscher Ländereinstellung 5 Smartie256 300 04. Jun 2010, 10:50
Smartie256 DLOOKUP funktioniert nicht mit deutscher Ländereinstellung
Keine neuen Beiträge Access Tabellen & Abfragen: Warum ändert Access den sql code? 12 abraxa 705 19. Jul 2009, 20:55
abraxa Warum ändert Access den sql code?
Keine neuen Beiträge Access Tabellen & Abfragen: DomWert / DLookup mit 2 Kriterien und Text 4 sucherbill 4673 07. Mai 2009, 15:19
Willi Wipp DomWert / DLookup mit 2 Kriterien und Text
Keine neuen Beiträge Access Tabellen & Abfragen: Darstellungsart "Kontrollkästchen" per Code setzen 3 fragerer 286 13. März 2009, 16:32
Gast Darstellungsart "Kontrollkästchen" per Code setzen
Keine neuen Beiträge Access Tabellen & Abfragen: parameterabfrage mit Dlookup? 0 Yak 606 13. Jan 2009, 15:39
Yak parameterabfrage mit Dlookup?
Keine neuen Beiträge Access Tabellen & Abfragen: SQL: Like Operator in Abfrage 3 mhw 1299 16. Okt 2008, 16:34
Willi Wipp SQL: Like Operator in Abfrage
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: PHP Forum