Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Internetseite öffnen und automatisch anmelden
zurück: Focus soll in Textfeld bleiben, wenn keine Eingabe war weiter: Fenster mit Variable als Name ansprechen Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Bitte Status wählen ! Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Ein Bastler
Gast


Verfasst am:
02. Okt 2007, 11:08
Rufname:

Internetseite öffnen und automatisch anmelden - Internetseite öffnen und automatisch anmelden

Nach oben
       Version: Office XP (2002)

Mal wieder Hallo alle zusammen,

Die Suchfunktion konnte mir nicht so richtig weiterhelfen und somit hoffe ich, dass mir jemand so weiterhelfen kann.

- Ist es möglich sich über ein Makro eine bestimmte Internetseite öffnen zu lassen ?
- Ist es möglich ein Makro zu erstellen, dass die Eingabe des Users und Passwortes, also somit die Anmeldung auf der Internetseite automatisch übernimmt ?
- Ist es möglich ein Makro zu erstellen, dass das Hochladen von mehreren Dateien (Dateinamen sind immer die selben) auf eine Internetseite automatisch durchführt ?

Vor allem wäre die Frage, ob dies sehr kompliziert wäre zu erstellen, da ich mich nicht so mit Makros auskenne.
Schnurble
Excel-VBA-Kenner


Verfasst am:
02. Okt 2007, 13:18
Rufname:
Wohnort: BaWü


AW: Internetseite öffnen und automatisch anmelden - AW: Internetseite öffnen und automatisch anmelden

Nach oben
       Version: Office XP (2002)

Hi,

das ist sicherlich möglich, aber nicht ganz trivial...

Ich habe mir kürzlich etwas ähnliches zusammengebastelt, evtl. ist das ja schonmal ein Ansatz für Dich...

Bei meiner gewünschten Seite ist es so, dass bei Eingabe der URL entweder die gewünschte Seite geladen wird, falls ich schon angemeldet bin, oder falls ich nicht angemeldet bin, kommt statt dessen eine Login-Seite.

Mein Code schaut also erstmal, ob die Seite evtl. schon im IE offen ist, navigiert dann zu der Seite bzw. nimmt die schon offene, und erkennt dann am Titel der Seite, ob es jetzt die gewünschte Seite ist, oder die Login-Seite.
Falls es die Login-Seite ist, wird der Username/Passwort eingetragen und der Login-Button betätigt, ansonsten wird gleich mit dem, was ich eigentlich tun möchte, fortgefahren.

Wie das genau bei Deiner Seite läuft, must Du selber rausfinden, die Namen für die Eingabefelder und Buttons kriegst Du raus, wenn Du Dir den Sourcecode der html-Seite anschaust...

Damit mein Beispiel tut, müssen im VB-Editor zuerst noch unter
Tools -> References die "Microsoft HTML Library" und "Microsoft Internet Controls" eingebunden werden.

Dann müssen natürlich die Konstanten mit sinnvollen Werten belegt werden, und das Login funktioniert auch nur, wenn die Eingabefelder/Login-Button auch so heissen, ansonsten entsprechend Deiner Seite anpassen...

Code:
 Option Explicit

Const PageTitle As String = "Titel der gewünschten Seite"
Const PageLogin As String = "Titel der Login-Seite"
Const PageURL As String = "URL der gewünschten Seite"
Const PageUser As String = "Username"
Const PagePW As String = "Passwort"

Sub ExplorerTest()
Dim myIE As SHDocVw.InternetExplorer
Dim myDoc As HTMLDocument

  'find site in Internet Explorer
  Set myIE = GetIE(PageTitle)
  If myIE Is Nothing Then
    'open page
    Set myIE = New SHDocVw.InternetExplorer
    myIE.Navigate PageURL
    'wait until site is fully loaded
    Application.Wait Now + TimeValue("0:00:02")
    Do While myIE.ReadyState <> READYSTATE_COMPLETE
      Application.Wait Now + TimeValue("0:00:01")
    Loop
    Set myDoc = myIE.Document
    If myDoc.Title = PageLogin Then
      'site asks for login
      With myDoc.forms(0)
        .elements("username").Value = PageUser
        .elements("password").Value = PagePW
        .elements("login").Click
      End With
      'wait until site is fully loaded
      Application.Wait Now + TimeValue("0:00:02")
      Do While myIE.ReadyState <> READYSTATE_COMPLETE
        Application.Wait Now + TimeValue("0:00:01")
      Loop
    ElseIf myDoc.Title <> PageTitle Then
      'page not found
      MsgBox "Couldn't open page"
      Exit Sub
    End If
  End If
 
  If myIE Is Nothing Then
    MsgBox "Couldn't open page"
  Else
    'hier müsste jetzt der Code hin, um die
    'Dateien hochzuladen, also wahrscheinlich
    'Dateinamen/Pfade in die entsprechenden
    'Felder eintragen und
    'Upload-Button drücken...
   
  End If
End Sub

'finds open IE site by checking the window title
Private Function GetIE(ByVal i_WindowTitle As String) As Object
Dim objShellWindows As New SHDocVw.ShellWindows

  'Ignore errors when accessing the Document property
  On Error Resume Next
  'loop over all Shell-Windows
  For Each GetIE In objShellWindows
    'is the document of type HTMLDocument, it's an IE window
    If TypeName(GetIE.Document) = "HTMLDocument" Then
      'check the title
      If GetIE.Document.Title = i_WindowTitle Then
        Exit Function 'leave, we found the right window
      End If
    End If
  Next GetIE
End Function


Sehr hilfreich fand ich übrigens diese Seite hier:
http://www.activevb.de/tutorials/tut_browsertags/browsertags.html

LG,
Anja
Ein Bastler
Gast


Verfasst am:
04. Okt 2007, 08:44
Rufname:

AW: Internetseite öffnen und automatisch anmelden - AW: Internetseite öffnen und automatisch anmelden

Nach oben
       Version: Office XP (2002)

Hallo Schnurble,

Erstmal Danke für die ausführliche Antwort und Hilfestellung.
Sieht für mich erst mal etwas "kompliziert" aus, werde ich aber auf jeden Fall ausprobieren und dann eine Rückinfo geben, kann nur halt etwas länger dauern.

Außerdem Danke für den Link ! Die Seite sieht sehr gut und hilfreich aus und vor allen (gut für mich) auf Deutsch . . . . . . Wink
Ein Bastler
Gast


Verfasst am:
10. Okt 2007, 15:05
Rufname:


AW: Internetseite öffnen und automatisch anmelden - AW: Internetseite öffnen und automatisch anmelden

Nach oben
       Version: Office XP (2002)

Ich bekomme es leider nicht hin . . . . .
Entweder läuft er ohne das etwas passiert bis zur Meldung "Couldn't open page" durch oder ich bekomme die Meldung "Fehler beim Kompilieren" oder mein Rechner hängt sich auf.
Es öffnet sich nicht mal der IE ?
Habe es noch mit etwas basteln versucht, es kommt aber immer nur zu den oben genannten Resultaten.

Gibt es vielleicht noch andere Möglichkeiten ?
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Text automatisch in anderes Tabellenblatt übernehmen 0 Zimbomann 1104 09. März 2006, 19:16
Zimbomann Text automatisch in anderes Tabellenblatt übernehmen
Keine neuen Beiträge Excel Formeln: Formeln automatisch in neu eingefügte Zeile übertragen 3 Ferencz 1727 27. Feb 2006, 15:22
Klaus-Dieter Formeln automatisch in neu eingefügte Zeile übertragen
Keine neuen Beiträge Excel Formeln: Mappe öffnen mit automatische Makro 0 Vase 1610 23. Feb 2006, 13:31
Vase Mappe öffnen mit automatische Makro
Keine neuen Beiträge Excel Formeln: Automatisch komprimieren? 12 Gast 2217 11. Feb 2006, 12:23
Gast Automatisch komprimieren?
Keine neuen Beiträge Excel Formeln: Komma getrennte Datensätze automatisch Zellen zuweisen 3 shniberkiis 2003 12. Dez 2005, 11:47
shniberkiis Komma getrennte Datensätze automatisch Zellen zuweisen
Keine neuen Beiträge Excel Formeln: Zellwerte automatisch korrigieren 1 Timo123 1204 01. Dez 2005, 20:49
ae Zellwerte automatisch korrigieren
Keine neuen Beiträge Excel Formeln: makro beim öffnen starten und werte auswählen 0 werner100 636 24. Nov 2005, 13:30
werner100 makro beim öffnen starten und werte auswählen
Keine neuen Beiträge Excel Formeln: ExcelTabellen sollen automatisch daten übernehmen 5 Gast 1843 17. Okt 2005, 16:55
Arnim ExcelTabellen sollen automatisch daten übernehmen
Keine neuen Beiträge Excel Formeln: automatisch Code generieren 17 Niceguy 2530 08. Sep 2005, 13:43
Niceguy automatisch Code generieren
Keine neuen Beiträge Excel Formeln: automatisch nur aufrunden?! 2 RobinsonHamburg 3545 30. Apr 2005, 19:10
Gast automatisch nur aufrunden?!
Keine neuen Beiträge Excel Formeln: Automatisch Verlinken 13 Gast 4649 19. Apr 2005, 13:18
Gast Automatisch Verlinken
Keine neuen Beiträge Excel Formeln: Auto-Filter aktualisiert nicht automatisch 2 Michi 1325 04. März 2005, 13:10
Michi Auto-Filter aktualisiert nicht automatisch
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Access Tabellen