Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
VBA GetFolder Dialog, ganzen Ordner auswählen
zurück: Daten der letzten sechs Monate Anzeigen lassen weiter: VBA DOPPELTE EINTRÄGE: LEERE ZELLEN AUSCHLIEßEN Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Bandito23
Mag Excel & VBA


Verfasst am:
28. März 2008, 11:02
Rufname: Bandito
Wohnort: Bayern

VBA GetFolder Dialog, ganzen Ordner auswählen - VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

Hey Leute.

Bin gerade über einer Userform und möchte einen "get Folder" Button erstellen, aber irgendwie stehe ich auf dem Schlauch.

Get file funktioniert, aber wie wähle ich nicht eine Datei, sondern einen ganzen Ordner aus?
Code:
    Dim ZuÖffnendeDatei
   
    ZuÖffnendeDatei = Application.GetOpenFilename(, , "Bitte Datei auswählen", , False)
    If ZuÖffnendeDatei = False Then
        Exit Sub
    End If
Grüße 8)
_________________
A programmer is just a tool which converts caffeine into code...
gast123456_
Gast


Verfasst am:
28. März 2008, 15:27
Rufname:


AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

Hallo ,

so z.B.:
Code:
Sub ordnerauswahl()
    Dim AppShell As Object
    Dim BrowseDir As Variant
    Dim Pfad As String

    Set AppShell = CreateObject("Shell.Application")
    Set BrowseDir = AppShell.BrowseForFolder(0, "Ordner auswählen", &H1000, 17)
    On Error Resume Next
    Pfad = BrowseDir.items().Item().Path
    If Pfad = "" Then Exit Sub
    MsgBox Pfad
    On Error Goto 0
End Sub
mfg Georg
Bandito23
Mag Excel & VBA


Verfasst am:
03. Apr 2008, 11:28
Rufname: Bandito
Wohnort: Bayern

AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

Bandito23 am 31. März 2008 um 08:05 hat folgendes geschrieben:
Hey Georg.

Vielen Dank!
Hat super funktioniert.
Schöne Woche.

MfG 8)

Hallo Leute!

Hat jemand eine Idee, wieso der Code nur unter XP funktioniert?
Unter 2000 prof kann das Ok beim Ordnerauswählen nicht angeklickt werden.
(Ausgegraut)

Grüße 8)

_________________
A programmer is just a tool which converts caffeine into code...
gast123456_
Gast


Verfasst am:
03. Apr 2008, 15:45
Rufname:

AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

Hallo ,

noch eine Variante:
Code:
'Herbers Excel/VBA-Beispiele
'Verzeichnisbaum aufrufen und Verzeichnis auswählen

Option Private Module

Public Type BROWSEINFO
    hOwner As Long
    pidlRoot As Long
    pszDisplayName As String
    lpszTitle As String
    ulFlags As Long
    lpfn As Long
    lParam As Long
    iImage As Long
End Type

Declare Function SHGetPathFromIDList Lib "shell32.dll" _
    Alias "SHGetPathFromIDListA" (ByVal pidl As Long, ByVal pszPath As String) As Long

Declare Function SHBrowseForFolder Lib "shell32.dll" _
  Alias "SHBrowseForFolderA" (lpBrowseInfo As BROWSEINFO) As Long

Sub DirAuswahl()
    Dim msg As String

    msg = "Wählen Sie bitte einen Ordner aus:"
    MsgBox getdirectory(msg)
End Sub

Function getdirectory(Optional msg) As String
    Dim bInfo As BROWSEINFO
    Dim Path As String
    Dim r As Long, x As Long, pos As Integer

    bInfo.pidlRoot = 0&
    If IsMissing(msg) Then
        bInfo.lpszTitle = "Wählen Sie bitte einen Ordner aus."
      Else
        bInfo.lpszTitle = msg
    End If
    bInfo.ulFlags = &H1
    x = SHBrowseForFolder(bInfo)
    Path = Space$(512)
    r = SHGetPathFromIDList(ByVal x, ByVal Path)
    If r Then
        pos = InStr(Path, Chr$(0))
        getdirectory = Left(Path, pos - 1)
      Else
        getdirectory = ""
    End If
End Function
mfg Georg
Bandito23
Mag Excel & VBA


Verfasst am:
04. Apr 2008, 07:57
Rufname: Bandito
Wohnort: Bayern


AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

Vielen Dank Georg.
Grüße

_________________
A programmer is just a tool which converts caffeine into code...
Seb123
Gast


Verfasst am:
20. Jan 2010, 10:05
Rufname:

AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

gibt es auch die Möglichkeit ein anderes Dialogfenser aufzurufen, in dem man direkt "Eigene Dateien" o.ä. auswählen kann ohne sich lange durchklicken zu müssen?
Case
Coder


Verfasst am:
20. Jan 2010, 10:34
Rufname: Case
Wohnort: Schwäbisch Hall

AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

Hallo, Razz

ab Excel 2002 (XP) kannst Du den "Application.FileDialog" nutzen, um Dateien oder Ordner auszuwählen.
Code:
Option Explicit

Public Sub Ordnerauswahl()
    Dim strOrdner As String

    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = "C:\"
        .Title = "Ordnerauswahl"
        .ButtonName = "Auswahl..."
        .InitialView = msoFileDialogViewList
        If .Show = -1 Then
            strOrdner = .SelectedItems(1)
            If Right(strOrdner, 1) <> "\" Then strOrdner = strOrdner & "\"
          Else
            strOrdner = ""
        End If
    End With
    If strOrdner = "" Then MsgBox ("Kein Ordner gewählt!") Else MsgBox strOrdner
End Sub
Bei ".InitialFileName" kannst Du den entsprechenden Ordner vorgeben.

Servus
Case
R34L
Gast


Verfasst am:
27. Jan 2010, 17:17
Rufname:

AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

Spitzenmäßig!

Danke Case, das hat mir sehr geholfen.

Gruß, D.
Gast



Verfasst am:
04. Jan 2012, 15:38
Rufname:

AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

Hallo zusammen,
mir gefällt der erste Code sehr gut, da einfach & knapp.
Wenn man öfter Folder auswählen möchte, macht es u.U. Sinn das Ganze in eine benutzerdefinierte Funktion zu packen, so dass man den Code nur einmal aufschreibt.
VG RSSG
rssg
Im Profil kannst Du frei den Rang ändern


Verfasst am:
04. Jan 2012, 15:43
Rufname:

AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2003

...sorry, hatte 1. nicht realisiert, dass ich nicht eingeloggt war und 2. meinte ich auch den letzten Code, nicht den ersten!
VG RSSG
Nossi
Im Profil frei geänderter Rang


Verfasst am:
12. Jan 2012, 14:55
Rufname:


AW: VBA GetFolder Dialog, ganzen Ordner auswählen - AW: VBA GetFolder Dialog, ganzen Ordner auswählen

Nach oben
       Version: Office 2010

Moin,

ich benutz Office 2010 und bei mir gibt es einen Fehler wenn ich den das Makro starte und dann direkt auf "ok" klicke (mit dem vorausgewählten Ordner). Er sagt mir Pfad ist nicht vorhanden. Geh ich dann eine Ebene raus und wähl den Ordner funktioniert alles.

Ansonsten finde ich den letzten Code auch super, hab immer das mit dem durchklicken verwendet und das letzter ist natürlich sehr viel komfortabler.

Gruß

Nossi

_________________
Wer einen Mann kritisieren möchte sollte zwei Meilen in seinen Schuhen gelaufen sein. Es hat zwei Vorteile
1) Man ist zwei Meilen weit weg
2) Man hat seine Schuhe
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Kleinere Zahl auswählen, aber nicht Null nehmen 6 Gast12399 1522 09. Apr 2010, 12:40
Maddin7 Kleinere Zahl auswählen, aber nicht Null nehmen
Keine neuen Beiträge Excel Formeln: Vergleichen und auswählen 7 bine1971 281 15. Feb 2010, 11:17
neopa Vergleichen und auswählen
Keine neuen Beiträge Excel Formeln: Bestimmte Anzahl von Datensätzen zufällig auswählen 2 Smartie256 2119 14. Jan 2010, 15:37
Smartie256 Bestimmte Anzahl von Datensätzen zufällig auswählen
Keine neuen Beiträge Excel Formeln: Gesperrte Zellen auswählen 4 Rhalik 2329 11. Jan 2010, 10:54
Gast Gesperrte Zellen auswählen
Keine neuen Beiträge Excel Formeln: Wie kann ich eine Zelle mit einer ganzen Spalte abgleichen 3 frazenfragen 507 08. Okt 2009, 13:26
Schlabbe Wie kann ich eine Zelle mit einer ganzen Spalte abgleichen
Keine neuen Beiträge Excel Formeln: aus Liste mehrere Namen auswählen und in eine Zelle übernehm 1 HUMER 805 08. Sep 2009, 18:50
neopa aus Liste mehrere Namen auswählen und in eine Zelle übernehm
Keine neuen Beiträge Excel Formeln: Bilddaten aus externem Ordner mit Excel verknüpfen 0 Anke2505 1913 18. Aug 2009, 11:57
Anke2505 Bilddaten aus externem Ordner mit Excel verknüpfen
Keine neuen Beiträge Excel Formeln: Gültigkeitliste synchronisiert auswählen 7 me2 285 29. März 2009, 14:15
me2 Gültigkeitliste synchronisiert auswählen
Keine neuen Beiträge Excel Formeln: Zellbezug zu anderer Datei in anderem Ordner 1 Gastmensch 298 06. März 2009, 00:42
Gastmensch Zellbezug zu anderer Datei in anderem Ordner
Keine neuen Beiträge Excel Formeln: Text aus einer ganzen Zeile in ein neues Feld 2 Domo 304 11. Jan 2009, 21:01
Domo Text aus einer ganzen Zeile in ein neues Feld
Keine neuen Beiträge Excel Formeln: Wert aus DropDownFeld (Gültigkeit) mit VBA auswählen 0 Uomo476 1099 07. Nov 2008, 11:45
Uomo476 Wert aus DropDownFeld (Gültigkeit) mit VBA auswählen
Keine neuen Beiträge Excel Formeln: wenn-dann-prüfung mit einer ganzen spalte 0 Gast 1212 06. Nov 2008, 16:12
Gast wenn-dann-prüfung mit einer ganzen spalte
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft Excel Tricks