Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Mehrfachselektion bei Abfrage+Listenfeld im Formular
Gehe zu Seite 1, 2  Weiter
zurück: Prüfen, ob Wert aus Tabelle A in Tabelle B vorkommt weiter: Einfügen eines Datums in vorhandenes Feld (Endlosformular) Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
rantz
lernfähig


Verfasst am:
07. Jul 2008, 16:26
Rufname:

Mehrfachselektion bei Abfrage+Listenfeld im Formular - Mehrfachselektion bei Abfrage+Listenfeld im Formular

Nach oben
       Version: Office 2003

Hallo,

ich hab eine Access Datenbank in der Informationen zugeordnet nach Jahr, Land, Produkt und Branche sind.
Nun möchte ich eine Abfrage erstellen, die mich zuerst fragt für welches Jahr ich die jeweiligen Daten haben möchte, dann für welches Land, für welches Produkt, welche Branche.
Das ist ja erstmal ganz einfach und ohne tiefer gehende Kenntnisse zu bewältigen.

Nun aber der Knackpunkt: Wie krieg ich es hin, dass ich auch mehrere Daten eingeben kann (aber nicht muss)? Also beispielseweise 2006 & 2007, für Österreich und Deutschland, Produkte A, B, C etc...
Oder aber auch nur 2006, Österreich, Produkte A, B, C, Branche 1, 2, 3, 4, ...

Damit wäre mir schon sehr geholfen!

Nun aber zur Kür:
Idealerweise würde ich die Daten gerne per Drop-Down Menu auswählen lassen, da die meisten Mitarbeiter hier noch viel viel weniger Ahnung haben und sich mit der Handhabung von Access Datenkbanken immer schwer tun. Mir ist klar, dass das nur aus einer Kombination der Abfrage mit einem Formular geht. Habe jetzt schon mehrere Posts hier im Forum zu dem Thema gelesen, aber leider ist mir noch nicht klar, wie ich den ausgewählten Wert aus dem Drop-Down Menu an die Abfrage weitergebe. Dazu dann auch direkt noch eine Detailfrage: Wenn ich den Wert zu einer Abfrage selber eingebe und trotzdem alle Datensätze haben will (also, um beim Beispiel zu bleiben, sage ich erst 2006, aber das für alle Länder) mache ich das ja einfach per * . Wenn ich jetzt ein Drop-Down Menu aus einer Tabelle heraus erstelle, wie krieg ich so einen "Alle" Wert hin?

Gruß und Dank
David


Zuletzt bearbeitet von rantz am 10. Jul 2008, 13:21, insgesamt 2-mal bearbeitet
JörgG
Access-Team


Verfasst am:
07. Jul 2008, 17:29
Rufname:
Wohnort: b. Dresden


AW: Mehrfachselektion bei Abfrage + DropDown im Formular - AW: Mehrfachselektion bei Abfrage + DropDown im Formular

Nach oben
       Version: Office 2003

Hallo,

die Abfrage ist dabei das kleinere Problem, die läuft auch ohne Kriterien Wink

Kombifelder kennen keine Mehrfachauswahl, Listenfelder schon. Du brauchst also nur die Listenauswahl auszulesen und zu einem Kriterienstring aufzufädeln:
Code:
    Dim varItem As Variant, strFilter As String

    For Each varItem In Me!Liste.ItemsSelected
        strFilter = strFilter & " OR LandID = " & Me!Liste.Column(0, varItem)
       'für ein Land als String
       'strFilter = strFilter & " OR Land = '" & Me!Liste.Column(0, varItem) & "'"
    Next varItem
    Me.Filter = Mid(strFilter, 5)
    Me.FilterOn = True

Idea Mehrere strFilter's müssen dann mit AND zu einem kompletten Filter zusammengesetzt werden, beachte dabei die Klammersetzung AND>OR (!) und die Leerzeichen zwischen den Teilstrings.

_________________
MfG, Jörg Very Happy

Bitte das Feedback nicht vergessen.
rantz
lernfähig


Verfasst am:
08. Jul 2008, 08:49
Rufname:

AW: Mehrfachselektion bei Abfrage + DropDown im Formular - AW: Mehrfachselektion bei Abfrage + DropDown im Formular

Nach oben
       Version: Office 2003

Hallo Jörg,

danke für deine Antwort - hilft mir nur leider noch nicht weiter.
Ich fürchte wir müssen da ein wenig weiter vorne anfangen Very Happy

Den Code-Schnippsel versteh ich so weit, aber wie lese ich jetzt aus?
Code:
Private Sub Liste0_AfterUpdate()
    ' Den mit dem Steuerelement übereinstimmenden Datensatz suchen.
    Dim rs As Object

    Set rs = Me.Recordset.Clone
    rs.FindFirst "[Land_ID] = " & Str(Nz(Me![Liste0], 0))
    If Not rs.EOF Then Me.Bookmark = rs.Bookmark
End Sub
Das produziert mir der Assistent, wenn ich das Listenfeld in einem Übergeordneten Formular erstelle. Kann dann auch auswählen und der Inhalt im Unterformular ändert sich. So weit so gut. Nur funktioniert mehrfachselektion damit natürlich nicht.

Meine Idealvorstellung ist, dass ich mehrere Listenfelder hintereinander habe:

Land --> Jahr --> Produkt --> Und dann die diversen Werte zu den selektierten Werte dabei rauskommen.

Verknüpfung zum Code mach ich @ Ereignis: Nach Aktualisierung, richtig?

Gruß und Dank
David
JörgG
Access-Team


Verfasst am:
08. Jul 2008, 15:37
Rufname:
Wohnort: b. Dresden

AW: Mehrfachselektion bei Abfrage + Listenfeld im Formular - AW: Mehrfachselektion bei Abfrage + Listenfeld im Formular

Nach oben
       Version: Office 2003

Hallo,

  • von einem Ufo war noch keine Rede Confused , das sind primäre Infos, weil sich damit die Syntax ändert. Wie heisst das Ufo-Steuerelement im Hfo? ( Exclamation Ufo und Ufo-Steuerelement sind zwei Objekte, ihr Name kann identisch sein, das Ufo wird über das Ufo-Steuerelement gesteuert!)
  • das Ereignis "nach Aktualisierung" wird bei Listen nach JEDEM Klick ausgelöst, ist wohl nicht das Gelbe Wink , nimm besser einen Button.
  • Da die Kriterien sicher mehrere Treffer ergeben ist rs.FindFirst der falsche Weg, nimm besser wie oben den Formularfilter. Diese Codezeile beinhaltet keine Mehrfachselektion, sie liefert NUR einen einzelnen Wert:
    Code:
        rs.FindFirst "[Land_ID] = " & Str(Nz(Me![Liste0], 0))
Idea Schaue Dir die SQL-Ansicht einer Abfrage mit mehreren Kriterien an, wie hier die Kriterien mit AND/OR verkettet werden (der Filter entspricht einer Where-Klausel ohne das Wörtchen Where.
  • Wie heisst das Ufo-Steuerelement?
  • Wie heissen die Listenfelder und zeige bitte die SQL-Ansicht ihrer Datensatzherkunft?
  • Wie heissen die Felder im Ufo auf die sich die Listen beziehen?
  • Greift das Jahr auf eine Jahreszahl oder ein Datumsfeld zu?
  • Gib Deinen Listen sinnvolle Namen
Codebeispiel, ein Filterbutton + Mehrfachauswahl für Land+Jahr könnte so aussehen:
Code:
Private Sub SFFilter_Click()
    Dim varItem As Variant, strFilter As String, strSelect As String

'Listenauswahl "LstLand" auslesen
    For Each varItem In Me!LstLand.ItemsSelected
        strSelect = strSelect & " OR Land_ID = " & Me!LstLand.Column(0, varItem)
    Next varItem
    If strSelect <> "" Then strFilter = "(" & Mid(strSelect, 5) & ")"
'Listenauswahl "LstJahr" auslesen
    strSelect = ""
    For Each varItem In Me!LstJahr.ItemsSelected
        strSelect = strSelect & " OR Jahr = " & Me!LstJahr.Column(0, varItem)
    Next varItem
    If strSelect <> "" Then strSelect = "(" & Mid(strSelect, 5) & ")"
    If strFilter <> "" And strSelect <> "" Then
        strFilter = strFilter & " AND " & strSelect
      ElseIf strSelect <> "" Then
        strFilter = strSelect
    End If
'hier folgt später die nächste Liste, mit dem analogen Code von LstJahr
'Debug.Print strFilter   'Direktfenster einschalten <Strg+G>, Filter kontrollieren
'Stop                    'schrittweise weiter mit [F8]
    Me!UfoSteuerelementname.Form.Filter = strFilter
    Me!UfoSteuerelementname.Form.FilterOn = True
End Sub
Ein weiterer Button um die Listenauwahl/den Filter zu löschen:
Code:
Private Sub SFReset_Click()
    Dim i As Integer

    For i = 0 To Me!LstLand.ListCount - 1
        Me!LstLand.Selected(i) = False
    Next i
    For i = 0 To Me!LstJahr.ListCount - 1
        Me!LstJahr.Selected(i) = False
    Next i
    Me!UfoSteuerelement.Form.Filter = ""
    Me!UfoSteuerelement.Form.FilterOn = False
End Sub
Idea Namen noch anpassen! Wenn Du später auf den Filterbutton verzichten willst, ändere:
Code:
Private Sub SFFilter_Click()
'in
Private Function FktFilter()
den Button selbst kannst Du dann löschen. Rufe die Funktion in den Listenfeldereignissen "nach Aktualisierung" auf:
Code:
Private Sub LstLand_AfterUpdate()
    Call FktFilter
End Sub

_________________
MfG, Jörg Very Happy

Bitte das Feedback nicht vergessen.
rantz
lernfähig


Verfasst am:
09. Jul 2008, 10:51
Rufname:


AW: Mehrfachselektion bei Abfrage + Listenfeld im Formular - AW: Mehrfachselektion bei Abfrage + Listenfeld im Formular

Nach oben
       Version: Office 2003

Vielen Dank, wir kommen der Sache schon sehr nahe!
Entschuldige, dass ich noch Ufos reingebracht habe - ist für mich nicht zwingend notwendig, nur war ich beim ausprobieren so der Lösung schon ein wenig näher gekommen Wink

Bin jetzt auf folgendem Stand:
Habe 3 Listen, LstLand1, LstProd & LstJahr die ich alle über deinen Code per Button steuer. Für LstProd & LstJahr funktioniert der Filter auch, nur beim Land kriege ich keine Werte, obwohl der richtige Wert übergeben wird. (Kontrolle per Direktfenster).

Hängt das irgendwie damit zusammen, dass das Ufo über die Land_ID verknüpft ist
// ja damit hängt es zusammen, Verknüpfung raus nun läuft es, ganz großes Danke!
JörgG
Access-Team


Verfasst am:
09. Jul 2008, 14:53
Rufname:
Wohnort: b. Dresden

AW: Mehrfachselektion bei Abfrage + Listenfeld im Formular - AW: Mehrfachselektion bei Abfrage + Listenfeld im Formular

Nach oben
       Version: Office 2003

Hallo,

ja, diese Verknüpfung wirkt wie ein zusätzlicher Filter, das Ufo-Recordset ist also bereits auf das Land_ID "vorgefiltert". Evtl reicht es ja die Verknüpfung zu löschen (siehe im Hfo, Eigenschaftsfenster des Ufo-Steuerelements - "verknüpfen von/nach")

Alternativ kannst Du zur Anzeige ein weiteres Formular gefiltert öffnen (am Ende des Buttoncodes):
Code:
'. . .
'Stop                    'schrittweise weiter mit [F8]
'   Me!UfoSteuerelementname.Form.Filter = strFilter
'    Me!UfoSteuerelementname.Form.FilterOn = True
    DoCmd.OpenForm "Formname", , , strFilter, , acDialog
End Sub

Idea Allerdings machen dann die oben beschriebenen Listenereignisse "nach Aktualisierung" keinen Sinn mehr. Beachte acDialog stoppt die Codeausführung bis das Formular wieder geschlossen ist!

_________________
MfG, Jörg Very Happy

Bitte das Feedback nicht vergessen.
rantz
lernfähig


Verfasst am:
09. Jul 2008, 15:17
Rufname:

AW: Mehrfachselektion bei Abfrage + Listenfeld im Formular - AW: Mehrfachselektion bei Abfrage + Listenfeld im Formular

Nach oben
       Version: Office 2003

Wie gesagt, löschen der verknüpfung von/nach hat geholfen 8)

Also nochmals danke für die Hilfe, die nächste Frage kommt bestimmt! Very Happy

10.07.2008 13:23, Rantz hat folgendes geschrieben:
Ich öffne das Thema nochmal, da ich eine sich hieran anschließende Frage habe:


Wenn ich nun per Filter das Unterformular steuer, ist es technisch möglich als letzte Zeile eine Summenzeile zu haben?
Wenn ja, wie?
JörgG
Access-Team


Verfasst am:
10. Jul 2008, 15:06
Rufname:
Wohnort: b. Dresden

AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd - AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd

Nach oben
       Version: Office 2003

Hallo,

Razz hm, Du bist sehr sparsam mit Infos, da muss man soviel raten Laughing.

Wenn das Ufo ein Endlosformular ist ( Idea Du kannst ein Endloses wie ein Datenblatt designen, hast dann aber Kopf-/Fussbereich verfügbar), dann kannst Du im Fussbereich ungebundene Textfelder einfügen. In deren Steuerelementinhalt käme so etwas in Frage:
Code:
=Anzahl(*)
=Summe([Preis])

Evtl reicht das ja, wenn ich aber Deinen ersten Post anschaue und ein bisschen weiterspinne kommst Du wohl mit einem weiteren Mini-Ufo das auf einer Gruppierungsabfrage aufsetzt, eher zum Ziel. Es soll doch bestimmt nach Land/Branchen & Co gruppiert werden? Erstelle dazu eine Abfrage (auf die gleiche Tabelle wie das Ufo) mit den relevanten Feldern, in der Symbolleiste findest Du den [Σ]-Button, in der Zeile Funktion kannst Du jetzt für die Spalten einstellen Gruppierung, Anzahl, Summe ... ( Idea soll zB eine Spalte gruppiert + summiert werden, ziehe sie 2* in den Abfrageentwurf). Erstelle dann das neue Ufo und baue es ins Hfo, oder ins Ufo ein (das Ufo ist dann kein Endlos-Ufo mehr!). Die SQL-Ansicht der Query müsstest Du dann am Ende des Filtercodes mit dem aktuellen Filter ergänzen und dem Ufo als neue Recordsource zuweisen:
Code:
Private Sub SFFilter_Click()
    Dim varItem As Variant, strFilter As String, strSelect As String
    Dim strSQL As String

    '. . .
    Me!Ufo1Steuerelementname.Form.Filter = strFilter
    Me!Ufo1Steuerelementname.Form.FilterOn = True
'Ufo-Summen
    If strFilter <> "" Then strFilter = "WHERE " & strFilter
                               ' & aus String befreit (s.u.) by Willi Wipp ;-)
    strSQL = "SELECT Jahr, Sum(Preis) AS SummePreis, " & _
                    "Count(Land) AS AnzahlLand " & _
               "FROM Tabelle " & _
               strFilter & " " & _
           "GROUP BY Jahr, Land, Branche " & _
           "ORDER BY Jahr, Land, Branche;"
   'das Ufo-Summen sitzt im Hfo
    Me!Ufo2Steuerelementname.Form.RecordSource = strSQL
   'das Ufo-Summen ist Ufo von Ufo1
   'Me!Ufo1Steuerelementname!Ufo2Steuerelementname.Form.RecordSource = strSQL
End Sub

Idea Das wirst Du brauchen DbWiki - Access Bedienungsanleitung: Bezug auf Hfo/Ufo

Edit: Dieser Teil sollte/muss (?) (=ausprobieren) im Reset-Button ergänzt werden:
Code:
    Dim strSQL As String

    strSQL = "SELECT Jahr, Sum(Preis) AS SummePreis, Count(Land) AS AnzahlLand " & _
               "FROM Tabelle " & _
           "GROUP BY Jahr, Land, Branche " & _
           "ORDER BY Jahr, Land, Branche;"
   'das Ufo-Summen sitzt im Hfo
    Me!Ufo2Steuerelementname.Form.RecordSource = strSQL
   'das Ufo-Summen ist Ufo von Ufo1
   'Me!Ufo1Steuerelementname!Ufo2Steuerelementname.Form.RecordSource = strSQL

_________________
MfG, Jörg Very Happy

Bitte das Feedback nicht vergessen.
rantz
lernfähig


Verfasst am:
11. Jul 2008, 14:45
Rufname:

AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd - AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd

Nach oben
       Version: Office 2003

Danke für die Info, wird am Wochenende ausprobiert Smile

Mit dem Begriff Endlosformular kann ich jetzt nicht viel anfangen.
Die Anzahl der Daten im Ufo richtet sich halt nach der Selektion im Hfo - wobei die Bildung von Hfo und Ufo in meinem Fall wahrscheinlich eigentlich überflüssig ist *schulterzuck*
Genau wie du schon richtig gemutmaßt hast, möchte ich dann auf Basis der Auswahl kumulierte Daten bspw pro Land, pro Produktgruppe etc.

Als Anhang mal ne Grafik, falls das weiterhilft.

Aber wie gesagt, ich werd erstmal deine Ideen ausprobieren, danke dafür Smile



qry.jpg
 Beschreibung:
 Dateigröße:  31.53 KB
 Angeschaut:  1795 mal

qry.jpg


JörgG
Access-Team


Verfasst am:
11. Jul 2008, 15:02
Rufname:
Wohnort: b. Dresden

AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd - AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd

Nach oben
       Version: Office 2003

Hallo,

schon aus Platzgründen ist die Hfo/Ufo-Konstruktion von Vorteil. In Deinem Datenblatt-Ufo kannst Du keine Ergebnistextfelder einbauen, das wäre nur möglich wenn Du seine Ansicht auf Endlosformular umschaltest (siehe Eigenschaftsfenster - Standardansicht. Da Dein Ergebniswunsch mehrere Ergebniszeilen liefern wird benutze die 2. Variante, im Hfo ein zusätzliches Ufo das eine Gruppierungsabfrage benutzt. Das lässt sich ja so zusammenfrickeln das die Ergebnisse direkt unter den Spalten von Ufo1 stehen.

_________________
MfG, Jörg Very Happy

Bitte das Feedback nicht vergessen.
rantz
lernfähig


Verfasst am:
14. Jul 2008, 14:55
Rufname:

Re: AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular - Re: AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular

Nach oben
       Version: Office 2003

Code:
Private Sub SFFilter_Click()
    Dim varItem As Variant, strFilter As String, strSelect As String
    Dim strSQL As String
   '. . .
    Me!Ufo1Steuerelementname.Form.Filter = strFilter
    Me!Ufo1Steuerelementname.Form.FilterOn = True
'Ufo-Summen
    If strFilter <> "" Then strFilter = "WHERE & " strFilter
    strSQL = "SELECT Jahr, Sum(Preis) AS SummePreis, " & _
                    "Count(Land) AS AnzahlLand " & _
               "FROM Tabelle " & _
               strFilter & " " & _
           "GROUP BY Jahr, Land, Branche " & _
           "ORDER BY Jahr, Land, Branche;"
   'das Ufo-Summen sitzt im Hfo
    Me!Ufo2Steuerelementname.Form.RecordSource = strSQL
   'das Ufo-Summen ist Ufo von Ufo1
   'Me!Ufo1Steuerelementname!Ufo2Steuerelementname.Form.RecordSource = strSQL
End Sub
In der If-Abfrage steckt irgendwie n Syntaxfehler, sofern ich hier nicht irgendwas falsch mache. Verrätst du mir wo? Smile

Darüber hinaus: Wofür ist das & _ nach den diversen Anweisungen?

Hab aber auch darüber hinaus noch ein anderes Problem:
Ich kriege die Abfrage nicht so hin, dass sie für alle Listauswahlmöglichkeiten funktioniert: Bei obigem Bild kann ich ja nach Land, Jahr und Produktgruppe selektieren. Als Abfrage krieg ich es aber nur hin, entweder pro Jahr, pro Produktgruppe oder pro Land zu gruppieren und die entsprechenden Werte zu summieren und die jeweils anderen Selektionsmöglichkeiten außen vor zu lassen.
Im Formular ist es ja aber auch möglich, eine Kombination aus Jahr, Land und Produktgruppe zu selektieren, bei der ich dann trotzdem gerne die Summe für bspw Marktgröße und Umsatz anzeigen würde.
Verstehst du mein Problem? Fällt mir grad schwer das in Worte zu fassen...
Willi Wipp
Moderator


Verfasst am:
14. Jul 2008, 16:06
Rufname:
Wohnort: Raum Wiesbaden

Re: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd - Re: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd

Nach oben
       Version: Office 2003

Hi rantz,

da hat Joerg sich vertippt ;)
Code:
    If strFilter <> "" Then strFilter = "WHERE " & strFilter
Das & verkettet Strings und das _ erlaubt die Fortsetzung des Codes in der naechsten Zeile.
Das macht den Code ueberschaubarer.

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
rantz
lernfähig


Verfasst am:
15. Jul 2008, 09:39
Rufname:

AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd - AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd

Nach oben
       Version: Office 2003

Ah danke dir... darauf hätt ich auch selber kommen können Confused

Hab es jetzt wie folgt am laufen: (in eigenem Ufo im Hfo)
Code:
    'Ufo-Summen
    If strFilter <> "" Then strFilter = "WHERE " & strFilter
    strSQL = "SELECT J.Jahr, Count(L.Land_ID) AS AnzahlvonLand_ID, " & _
                    "Count(B.Branche_Nummer) AS AnzahlvonBranche_Nummer, " & _
                    "Count(L.Landkürzel) AS AnzahlvonLandkürzel, " & _
                    "Count(B.Branche_Name) AS AnzahlvonBranche_Name, " & _
                    "Sum(D.Branche_Marktgroesse) AS Marktgroesse, " & _
                    "Avg(D.Branche_Wachstum) AS Wachstum, " & _
                    "Sum(D.AundD_Value) AS AundD_Value, " & _
                    "Avg(D.AundD_Share) AS AundD_Share " & _
               "FROM Land_Namen AS L " & _
                    "INNER JOIN (Jahr AS J " & _
                        "INNER JOIN (Branche_Namen AS B " & _
                            "INNER JOIN Daten_BR AS D " & _
                            "ON B.Branche_Nummer = D.Branche_ID) " & _
                        "ON J.Jahr = D.Jahr) " & _
                    "ON L.Land_ID = D.Land_ID " & _
                  strFilter & " " & _
           "GROUP BY J.Jahr " & _
           "ORDER BY J.Jahr;"
'Debug.Print strSQL  'Direktfenster einschalten <Strg+G>, Filter kontrollieren
'Stop                    'schrittweise weiter mit [F8]
    'das Ufo-Summen sitzt im Hfo
    Me!Ufo_br2.Form.RecordSource = strSQL
BIn damit aber in sofern noch nicht zufrieden, als das ich Landkürzel und/oder Branche_Nummer eigentlich nicht als Anzahl stehen haben möchte,
sondern die jeweils selektierten Werte. Wenn ich aber danach gruppiere, krieg ich ja wieder keine gesamt Summe sonder nur die Summe pro Gruppe...
Sprich immernoch das Problem, was ich im vorigen Post angesprochen hatte.

Was für Möglichkeiten bietet Access darüber hinaus, die Sachen vernünftig darzustellen?
Zwei Ufos so untereinander sieht ja für die Summenzeile ziemlich bescheiden aus...
JörgG
Access-Team


Verfasst am:
15. Jul 2008, 12:00
Rufname:
Wohnort: b. Dresden

AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd - AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular[Upd

Nach oben
       Version: Office 2003

Hallo,

in Deiner Gruppierungsabfrage gar nicht mehr, es gibt zwar Konstruktionen mit Unterabfragen, das dürfte hier aber nicht passen.

Beschreibe doch mal als Textformel, welche Ergebnisse Du wirklich sehen willst, das hab ich noch so ganz verstanden, also sinngemäss
      Zeige pro Jahr pro Branche die Anzahl der Produktgruppen
Man könnte evtl den strSQL als Abfrage speichern und darauf mit DSum() die Gesamtsumme ermitteln.

Die beiden Ufos schön zu desigen sollte ja wohl möglich sein Very Happy , wenn Du sie Endlosformular darstellst und allen Blabbrich, wie Ränder & Co ausblendest, dann wird es auch aussehen wie aus einem Guss.

_________________
MfG, Jörg Very Happy

Bitte das Feedback nicht vergessen.
rantz
lernfähig


Verfasst am:
15. Jul 2008, 12:13
Rufname:


AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular - AW: Mehrfachselektion bei Abfrage+Listenfeld im Formular

Nach oben
       Version: Office 2003

Hallo Jörg,

um bei obigem Beispiel zu bleiben sind ja verschiedene Konstruktionen möglich:

1. Mit einer Selektion:
Umsatz (u.a. Werte) pro Jahr / Land / Branche
Bsp: Gesamtumsatz in 2008, Gesamtumsatz in Deutschland, Gesamtumsatz in Branche A
2. Mit zwei Selektionen
Umsatz pro Jahr pro Land / pro Jahr pro Branche / pro Land pro Branche /
Bsp: Umsatz in Deutschland in 2008 / Umsatz in Branche A ind 2008 / Umsatz in Deutschland in Branche A
3. Mit drei Selektionen
Umsatz pro Jahr pro Land pro Branche
Bsp: Umsatz in 2008 in Deutschland in Branche A

Aber eine Gruppierung macht ja nur bei manchen dieser Abfragen Sinn, also lassen wir das jetzt an dieser Stelle erstmal Smile

Endlosformular find ich bei der Menge an Daten nicht so schön, werd das lieber als Tabelle behalten.

Vielen Dank auf jedenfall für die unmenge an Hilfestellungen, bis demnächst ;)
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Access Abfrage Uhrzeit (von bis) 1 new 2078 02. März 2004, 11:12
new Access Abfrage Uhrzeit (von bis)
Dieses Thema ist gesperrt, du kannst keine Beiträge editieren oder beantworten. Access Tabellen & Abfragen: Parameter Abfrage 3 shorty 2270 29. Feb 2004, 15:07
Willi Wipp Parameter Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: Abfrage nach Berufssparten 3 Fabian_bkk 1537 20. Feb 2004, 10:25
Willi Wipp Abfrage nach Berufssparten
Keine neuen Beiträge Access Tabellen & Abfragen: Problem im Abfrage Generator mit Wenn() und Zwischen() 1 snowman 4094 13. Feb 2004, 10:42
Willi Wipp Problem im Abfrage Generator mit Wenn() und Zwischen()
Keine neuen Beiträge Access Tabellen & Abfragen: Wie kann ich mehr als 255Felder in eine Abfrage legen? 1 D.R. 2235 12. Feb 2004, 09:05
faßnacht(IT); Wie kann ich mehr als 255Felder in eine Abfrage legen?
Keine neuen Beiträge Access Tabellen & Abfragen: Diese Abfrage geht nicht. Kann ir jemand helfen 4 Oliver 1438 02. Feb 2004, 13:21
Willi Wipp Diese Abfrage geht nicht. Kann  ir jemand helfen
Keine neuen Beiträge Access Tabellen & Abfragen: In Abfrage nach Monat sortiert ausgeben 3 Torsten 2150 29. Jan 2004, 19:52
Torsten In Abfrage nach Monat sortiert ausgeben
Keine neuen Beiträge Access Tabellen & Abfragen: Unterscheid zwischen 2 Daten berechnen in Abfrage 2 itarus 1441 26. Jan 2004, 17:01
i_tarus Unterscheid zwischen 2 Daten berechnen in Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: Verschachtelte Abfrage? 3 Fragesteller 2581 22. Jan 2004, 08:46
ffdabei Verschachtelte Abfrage?
Keine neuen Beiträge Access Tabellen & Abfragen: Abfrage in Kombifeld 3 Gast 1255 06. Jan 2004, 19:21
Krokette Abfrage in Kombifeld
Keine neuen Beiträge Access Tabellen & Abfragen: kommentare im sql code einer abfrage? 1 Caladan 1744 22. Dez 2003, 20:15
Ludger kommentare im sql code einer abfrage?
Keine neuen Beiträge Access Tabellen & Abfragen: Formular schließen und öffnen 3 daMike 14586 26. Nov 2003, 20:50
Gast Formular schließen und öffnen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: MS Frontpage