Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Drucken mit oder ohne Kopfzeilen
Gehe zu Seite 1, 2  Weiter
zurück: Word to PDF --- enthaltene Querseiten werden nicht gedreht! weiter: Feldtext zuschneiden Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
hYpa
Mitdermausarbeiter


Verfasst am:
06. Apr 2009, 10:37
Rufname:

Drucken mit oder ohne Kopfzeilen - Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Guten Tag

Ich habe folgende Problemstellung: Beim Drucken von Dokumenten muss entschieden werden:

1. PDF erstellen mit Kopf- und Fusszeile
2. Auf Papier drucken ohne Kopf- und Fusszeile (da wir vorgedrucktes Papier haben)

Wie lässt sich soetwas realisieren? Ich habe schon PDF-software gefunden wo soetwas enthalten, jedoch ist diese Lösung schlussendlich zu teuer.

Die Lösung sollte jetzt in den Vorlagen abgespeichert sein.


Freundliche Grüsse

_________________
Absoluter Obernoob mit einschlägigen Erfahrungen im Nichtstun.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
06. Apr 2009, 10:51
Rufname:
Wohnort: Leipzig


AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo hypa,

könnte man mit einem Makro realisieren. Ich habe hier zwei Beispiele gebaut, die Du mal probieren kannst. Falls Deine Bedingungen abweichen, nochmal genau sagen, wie das ablaufen soll:

Kopf- und Fußzeile wieder einblenden

Dieser Code müsste in der Dokumentvorlage *.dot hinterlegt werden. Wenn Du Deine Anforderungen spezifizierst, kann das auch direkt in den Druckbefehl integriert werden.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Gast



Verfasst am:
06. Apr 2009, 11:56
Rufname:

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo Lisa

Vielen dank für die schnelle Antwort.
Habe mich versucht in den code einzulesen, aber da kapiere ich überhaupt nichts -.-
Dein Code funktioniert aber soweit, nur dass er jetzt noch umgekehrt sein sollte.

Istzustand: beim drucken auf pdf wird kopf-und fusszeile ausgeblendet, und beim drucken auf papier bleibt es

Soll: genau umgekehrt

ich dachte das geht jetzt ganz einfach indem ich:
If ActivePrinter <> PDFPrinter Then
abändere -> hat leider nicht funktioniert.

habe auch versucht einige trues in false zu ändern, aber ich werd nicht schlau draus -.-
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
06. Apr 2009, 12:28
Rufname:
Wohnort: Leipzig

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo Gast,

nein, PDFPrinter ist hier eine Variable. Man braucht die genaue Bezeichnung möglichst beider Drucker, also des PDF-Printers und des normalen Druckers. In meinem Beispiel heißt der PDFPrinter "Acrobat Distiller". Wir brauchen also von beiden Druckern den genauen Namen. Am besten in der Windows- Systemsteuerung - Drucker nachsehen, jeweils den Drucker markieren, rechte Maustaste - Eigenschaften, den Namen genau herauskopieren.

Weiter solltest Du nochmal darüber nachdenken, ob Du in beiden Fällen den Druckdialog sehen willst. In meinem Beispiel wird er nur beim PDF angezeigt und im anderen Fall sofort losgedruckt. Wie möchtest Du das benutzen, willst Du trotzdem vorher noch den Druckdialog sehen?

Weiter wäre noch wichtig die gleichen Fragen wie im anderen Beitrag: Sollen Kopf- und Fußzeilen ausgeblendet werden oder nur eins von beiden? Ist die 1. Seite anders? Soll die Kopfzeile der 1. Seite oder die der Folgeseiten oder beide ausgeblendet werden?

Gruß
Lisa


Zuletzt bearbeitet von Lisa am 06. Apr 2009, 13:52, insgesamt einmal bearbeitet
Gast



Verfasst am:
06. Apr 2009, 13:23
Rufname:


AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo Lisa

Es ist so, dass diese Vorlage hier in der Firma verwendet wird, und ich habe nur den festen pdf Drucker, ich kann doch nicht die anderen ~100 Drucker im Code festhalten und was währe, wenn neue Drucker dazukommen?
Mein pdfprinter heisst: "pdf erstellen", das habe ich auch in der Variable PDFprinter definiert.
Da ich jetzt immer über datei-drucken bin, hatte ich so oder so immer ein Dialogfeld, ich denke du meinst jetzt einfach das normale Druckersymbol?
Ein Dialogfeld ist aufjedenfall von Vorteil.
In der Vorlage habe ich nur 1 Seite, also die Kopf und Fusszeilen sind immer dieselben auf den Folgeseiten.

Also beim PDF erstellen sollen die Kopf- UND Fusszeilen bleiben und beim Drucken auf einen Drucker der nicht "pdf erstellen" heisst sollen sie ausgeblendet werden.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
06. Apr 2009, 13:54
Rufname:
Wohnort: Leipzig

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo Gast,

so, ich habe das jetzt mal angepasst. Probier mal bitte, ob das jetzt richtig herum ist. Wenn der Drucker "PDF erstellen" heißt, wird der Druckdialog angezeigt und dann ausgedruckt. (Du kannst in dem Druckdialog auch noch die Anzahl auswählen oder die Seiten usw., ganz wie normal.)

Wenn es irgendein anderer Drucker ist, werden die Kopf- und Fußzeilen ausgeblendet und erst dann der Druckdialog angezeigt. Den kannst Du wieder bedienen, Anzahl eingeben und sonstwas. Dann wird gedruckt. Danach blendet das Makro die Kopf- und Fußzeilen wieder ein.

Hier der Code:
Code:
Sub NurKopfzeileEinblenden()

    Dim PDFPrinter As String
    Dim bHiddenTextDrucken As Boolean   'Zum Konservieren der Einstellung
    Dim sec As Word.Section
   
    PDFPrinter = "pdf erstellen"    'Hier den Namen des PDF-Druckers eintragen!
   
    If ActivePrinter = PDFPrinter Then
        Dialogs(wdDialogFilePrint).Show
        Exit Sub
    End If
   
    Options.PrintBackground = False
   
    If Options.PrintHiddenText = True Then
        bHiddenTextDrucken = True
        Options.PrintHiddenText = False
    End If
   
    For Each sec In ActiveDocument.Sections
        sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = True
        sec.Footers(wdHeaderFooterPrimary).Range.Font.Hidden = True
    Next sec
   
    Dialogs(wdDialogFilePrint).Show
    DoEvents
   
    For Each sec In ActiveDocument.Sections
        sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = False
        sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = False
    Next sec
   
    If bHiddenTextDrucken Then
        Options.PrintHiddenText = True
    End If
   
End Sub

Bitte berichte mal, ob das jetzt so passt.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Gast



Verfasst am:
06. Apr 2009, 14:35
Rufname:

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo nochmals Very Happy

ActivePrinter ist der Standartdrucker oder?
Ich glaub, das was ich will geht garnicht, der code müsste zwischen dem drucker auswählen und dem effektiven drucken ausgeführt werden. Es kommt ja nicht draufan, welches der Standart drucker ist, sondern welchen dass der Benutzer schlussendlich auswählt.

Danke trotzdem für deine mühe.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
06. Apr 2009, 14:51
Rufname:
Wohnort: Leipzig

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo Gast,

der obige Code richtet sich danach, welcher Drucker gerade eingestellt ist.

Eben, deswegen meine Frage. Wie genau soll das gehandhabt werden? Ich kann auch statt der jeweiligen Anzeige des Druckendialogs gleich losdrucken lassen, ohne dass der Benutzer noch die Anzahl und die Seiten festlegt. Ich kann auch die Auswahl des Druckers mit einbeziehen. Ich muss nur genau wissen, wie Du Dir die Handhabung vorstellst.

Denkbar wäre z.B. und aus meiner Sicht sinnvoll:

WENN in Dokumenten, die aus dieser Vorlage erzeugt werden, der Druckdialog aufgerufen wird (Menü Datei Drucken oder Strg P), dann wird zuerst gefragt, ob PDF oder nicht, danach wird ausgedruckt.

Oder WENN der Druckdialog angezeigt wird, wird je nachdem, welchen Drucker der Benutzer ausgewählt hat, die Kopfzeilen eingeblendet oder nicht. Meinst Du das so?
Das wäre etwa so:
Code:
Sub FilePrint()

    Dim PDFPrinter As String
    Dim bHiddenTextDrucken As Boolean   'Zum Konservieren der Einstellung
    Dim sec As Word.Section
    Dim UserDrucker As String
   
    PDFPrinter = "pdf erstellen"    'Hier den Namen des PDF-Druckers eintragen!
   
    Options.PrintBackground = False
   
    With Dialogs(wdDialogFilePrint)
        UserDrucker = ActivePrinter
        .Display
        If UserDrucker = PDFPrinter Then
            .Execute
            DoEvents
        Else
            If Options.PrintHiddenText = True Then
                bHiddenTextDrucken = True
                Options.PrintHiddenText = False
            End If
            For Each sec In ActiveDocument.Sections
                sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = True
                sec.Footers(wdHeaderFooterPrimary).Range.Font.Hidden = True
            Next sec
            .Execute
            DoEvents
            For Each sec In ActiveDocument.Sections
                sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = False
                sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = False
            Next sec
            If bHiddenTextDrucken Then
                Options.PrintHiddenText = True
            End If
        End If
    End With
       
End Sub

Der Prozedurname ist wichtig, damit man nichts weiter machen muss, als im Menü Datei - Drucken zu verwenden.

Oder ein anderes Szenario: Man macht zwei Knöpfchen, einen für PDF-Druck, einen für normalen Druck.

Oder oder ... Bitte denk Du nochmal über die Konzeption nach, wie Du das genau benutzen willst. So ein Makro ist letztlich immer auf die individuellen Bedürfnisse zugeschnitten. Wenn es Dir gelingt, mir zu erklären, was Du möchtest, schaff ich es, das Word zu erklären ;)

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
hYpa
Mitdermausarbeiter


Verfasst am:
07. Apr 2009, 09:25
Rufname:

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo Lisa

Ja genau so meine ich das, jetzt gibts nur noch ein kleines problem, wenn man das dialogfeld abbricht, druckt es trotzdem. Kann man das auch irgendwie unterbinden?

_________________
Absoluter Obernoob mit einschlägigen Erfahrungen im Nichtstun.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
07. Apr 2009, 11:33
Rufname:
Wohnort: Leipzig

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo hypa,

ah, sehr gut beobachtet. Da hast Du vollkommen recht. Das habe ich jetzt nochmal eingebaut:
Code:
Sub FilePrint()

    Dim PDFPrinter As String
    Dim bHiddenTextDrucken As Boolean   'Zum Konservieren der Einstellung
    Dim bPrintBackground As Boolean
    Dim sec As Word.Section
    Dim UserDrucker As String
   
    PDFPrinter = "pdf erstellen"    'Hier den Namen des PDF-Druckers eintragen!
   
    If Options.PrintBackground = True Then
        bPrintBackground = True
        Options.PrintBackground = False
    End If
   
    With Dialogs(wdDialogFilePrint)
        UserDrucker = ActivePrinter
        If .Display = -1 Then
            If UserDrucker = PDFPrinter Then
                .Execute
                DoEvents
            Else
                If Options.PrintHiddenText = True Then
                    bHiddenTextDrucken = True
                    Options.PrintHiddenText = False
                End If
                For Each sec In ActiveDocument.Sections
                    sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = True
                    sec.Footers(wdHeaderFooterPrimary).Range.Font.Hidden = True
                Next sec
                .Execute
                DoEvents
                For Each sec In ActiveDocument.Sections
                    sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = False
                    sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = False
                Next sec
                If bHiddenTextDrucken Then
                    Options.PrintHiddenText = True
                End If
            End If
        End If
    End With
   
    If bPrintBackground Then
        Options.PrintBackground = True
    End If
       
End Sub

Und bitte beachten, den Code in der Dokumentvorlage unterbringen, keinesfalls in der Normal.dot (sonst springt er bei allen Dokumenten an).

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
hYpa
Mitdermausarbeiter


Verfasst am:
07. Apr 2009, 12:03
Rufname:

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Du bist genial Very Happy

Wie kann ich dir dafür nur danken? das ist ja ein hammer service hier, ich bin überglücklich.

Lisa for President !!!! Laughing

_________________
Absoluter Obernoob mit einschlägigen Erfahrungen im Nichtstun.
hYpa
Mitdermausarbeiter


Verfasst am:
30. Apr 2009, 14:54
Rufname:

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Die Vorlage ist nun im Betrieb in verwendung und es hat sich ein problem herauskristallisiert Sad
Die Benutzer drücken nicht immer das DATEI - DRUCKEN.
über das Druckersymbol in der symbolleiste funktioniert das script leider nicht.
Gibts hier auch eine funktion irgendwie directprint odersowas.

unser programmierer der das skript angeschaut hat, meint ich muss hier eventhandler einbauen...

Ich habe bei microsoft ein befehl gefunden, der heisst DocumentBeforePrint.
Hier müssten wir das script reinpacken.

_________________
Absoluter Obernoob mit einschlägigen Erfahrungen im Nichtstun.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
30. Apr 2009, 15:30
Rufname:
Wohnort: Leipzig

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo hypa,

nein, es wird kein BeforePrint-Ereignis benötigt.
Du brauchst eine weitere Prozedur, die den Druckbutton "abfängt", zusätzlich. Ich habe das jetzt nochmal umgebaut. Bitte lösch die andere Prozedur und nimm diesen Code stattdessen. Bitte in ein eigenes normales (!) Modul, nicht in ThisDocument! Am besten ein neues Modul einfügen (Menü - Einfügen - Modul):
Code:
Option Explicit

Const PDFPrinter As String = "pdf erstellen" 'Hier Namen des PDF-Druckers eintragen!
Dim bHiddenTextDrucken As Boolean            'Zum Konservieren der Einstellung
Dim bPrintBackground As Boolean
Dim sec As Word.Section
Dim UserDrucker As String

Sub FilePrint()
   
    With Dialogs(wdDialogFilePrint)
        If .Display = -1 Then
            Call DruckenImHintergrundAus
            UserDrucker = ActivePrinter
            If UserDrucker = PDFPrinter Then
                .Execute
                DoEvents
            Else
                Call AusgeblendetenTextDrucken
                .Execute
                DoEvents
                Call KopfFusszeilenEinblenden
            End If
        End If
    End With
    Call DruckenImHintergrundWdh
       
End Sub
Sub FilePrintDefault()
 
    Call DruckenImHintergrundAus
    UserDrucker = ActivePrinter
    If UserDrucker = PDFPrinter Then
        ActiveDocument.PrintOut
        DoEvents
    Else
        Call AusgeblendetenTextDrucken
        ActiveDocument.PrintOut
        DoEvents
        Call KopfFusszeilenEinblenden
    End If
    Call DruckenImHintergrundWdh

End Sub
Sub DruckenImHintergrundAus()
'deaktiviert die Option, falls sie aktiv war,
'speichert den vorgefundenen Zustand im Flag

    If Options.PrintBackground = True Then
        bPrintBackground = True
        Options.PrintBackground = False
    End If

End Sub
Sub DruckenImHintergrundWdh()
'stellt den vorgefundenen Zustand wieder her

    If bPrintBackground Then
        Options.PrintBackground = True
    End If

End Sub
Sub AusgeblendetenTextDrucken()
'deaktiviert die Option, falls sie aktiv war,
'speichert den vorgefundenen Zustand im Flag
'blendet die Kopf- und Fußzeilen aus
   
    If Options.PrintHiddenText = True Then
        bHiddenTextDrucken = True
        Options.PrintHiddenText = False
    End If
    For Each sec In ActiveDocument.Sections
        sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = True
        sec.Footers(wdHeaderFooterPrimary).Range.Font.Hidden = True
    Next sec

End Sub
Sub KopfFusszeilenEinblenden()
'blendet die Kopf- und Fußzeilen wieder ein
'stellt den vorgefundenen Zustand wieder her
   
    For Each sec In ActiveDocument.Sections
        sec.Headers(wdHeaderFooterPrimary).Range.Font.Hidden = False
        sec.Footers(wdHeaderFooterPrimary).Range.Font.Hidden = False
    Next sec
    If bHiddenTextDrucken Then
        Options.PrintHiddenText = True
    End If

End Sub

Die Prozedurnamen FilePrint und FilePrintDefault müssen unverändert bleiben. Sie sorgen dafür, dass die Prozedur FilePrintDefault anspringt, wenn der Benutzer den Druckbutton in der Symbolleiste benutzt, während FilePrint anspringt, wenn der Benutzer über das Menü Datei - Drucken geht.
Den Namen des PDF-Druckers natürlich noch eintragen.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Meckert
Gast


Verfasst am:
04. Mai 2009, 19:58
Rufname:

AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hey Lisa,

was ein Zufall. Ich suche gerade das Selbe und bin gerade über deinen Code gestolpert.

Ich würde bevor ich Tage beim Einspielen verliere folgendes von dir wissen. Kann ich diesen Code auch für Office 2003 und 2007 einsetzen?

Wie soll ich den Code so verteilen, dass alle User davon etwas haben. Ich denke vor allem an Windows Terminalserver.

Ich habe den Part mit dem Modul und der Vorlagendatei noch nicht verstanden. Habe heute (leider vor der Suche hier) versucht ähnliches zu basteln und habe via Makroaufzeichnung Grafiken in die Kopf und Fußzeile eingefügt aber deine Lösung scheint mir eleganter.

Danke
hYpa
Mitdermausarbeiter


Verfasst am:
08. Mai 2009, 15:26
Rufname:


AW: Drucken mit oder ohne Kopfzeilen - AW: Drucken mit oder ohne Kopfzeilen

Nach oben
       Version: Office XP (2002)

Hallo Lisa

Hat dein Makro ein Zufallsprinzip obs funktioniert oder nicht?
Ich hab die Logik noch nicht herausgefunden...
Kein Plan Sad

1. Geht es nicht mit bildern? Wir haben nur Bilder in der Kopf-Fusszeile
2. Können andere Module / Makros stören?


Wenn ich das Script in ein leeres Dokument einfüge gehts, aber bei den bestehenden Vorlagen funktioniert es nicht. Ich habe es so gemacht wie du gesagt hast, habe ein neues Modul eingefügt und de Text dort reinkopiert und den Text von vorher aus dem ThisDokument gelöscht. Das einzige was ich noch abgeändert habe sind die Zeilen
UserDrucker = ActivePrinter
If UserDrucker Like "*PDF*" Then

Hast du evtl. eine Idee an was das liegen könnte?

_________________
Absoluter Obernoob mit einschlägigen Erfahrungen im Nichtstun.


Zuletzt bearbeitet von hYpa am 13. Mai 2009, 09:38, insgesamt einmal bearbeitet
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Word Serienbriefe: Bestimmte Seite nur drucken aufgrund Bedingung? 1 Supertramp 189 19. März 2014, 12:24
Gast Bestimmte Seite nur drucken aufgrund Bedingung?
Keine neuen Beiträge Word Serienbriefe: Serienetikett drucken Word 2010 aus Excel 2010 Datenquelle 0 Mini2012 1303 19. Nov 2012, 13:40
Mini2012 Serienetikett drucken Word 2010 aus Excel 2010 Datenquelle
Keine neuen Beiträge Word Serienbriefe: Seriendokument als Broschüre drucken 0 ow123 589 14. März 2012, 15:44
ow123 Seriendokument als Broschüre drucken
Keine neuen Beiträge Word Formate: Broschüre (Buch) drucken mit Problemen 9 Gast 11605 22. Dez 2011, 11:36
zaz Broschüre (Buch) drucken mit Problemen
Keine neuen Beiträge Word Serienbriefe: PLZ beim Label drucken erscheint als 0 1 santa claus 2010 893 26. Nov 2010, 23:17
charlybrown PLZ beim Label drucken erscheint als 0
Keine neuen Beiträge Word Serienbriefe: Geschütztes Dokument, Umschlag drucken 1 MrUmschlag 1601 30. Aug 2010, 08:45
MrUmschlag Geschütztes Dokument, Umschlag drucken
Keine neuen Beiträge Word Serienbriefe: Serienbrief beidseitig drucken - Probleme 3 Allgaier 2934 25. Feb 2010, 15:03
Allgaier Serienbrief beidseitig drucken - Probleme
Keine neuen Beiträge Word Serienbriefe: Serienbrief Word2000 - leere Seiten beim Drucken 10 Tevil 9185 15. Jan 2010, 10:51
Tinchenfc Serienbrief Word2000 - leere Seiten beim Drucken
Keine neuen Beiträge Word Serienbriefe: Word Serienbrief Seite von bis Drucken ? 1 Coolsero 4232 17. Apr 2009, 11:05
Schneewittchen Word Serienbrief Seite von bis Drucken ?
Keine neuen Beiträge Word Serienbriefe: Leere Zeilen nicht drucken in einer Word Tabelle 0 Gast 3212 26. Mai 2008, 11:40
Gast Leere Zeilen nicht drucken in einer Word Tabelle
Keine neuen Beiträge Word Serienbriefe: Umschläge drucken 11x16 mit Canon MP 510 0 Amitl 2515 18. Mai 2008, 10:42
Amitl Umschläge drucken 11x16 mit Canon MP 510
Keine neuen Beiträge Word Serienbriefe: Laufende Nummern auf Etiketten drucken- mal wieder! 2 Gast 15671 02. März 2007, 15:34
Gast Laufende Nummern auf Etiketten drucken- mal wieder!
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Access Tabellen