Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Grafik auf bestimmer Seite
zurück: Inhalte einer Aufzählung in neues Dok. kopieren und ergänzen weiter: Cursor beim Öffnen eines Dokuments an richtige Position... Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
MKey89
Blutiger Anfänger


Verfasst am:
06. Apr 2009, 11:47
Rufname:

Grafik auf bestimmer Seite - Grafik auf bestimmer Seite

Nach oben
       Version: Office 2003

Hallo zusammen,

ich versuche in Word 2003 Bilder aus einem bestimmten Pfad auszulesen ist bisher auch kein Problem. Das Bild wird mir eingefügt. Doch leider immer nur auf der ersten Seite meine Dokuments, da sich der Cursor beim öffnen auf der ersten Seite befindet (dies ist auch so gewollt).

Nun die frage wie bekomme ich mein Bild auf Seite 2 oder 3 ?

Code:

Sub imsmakro_end()
    Dim strTeilstring As String
    Dim oShape As Shape

    strTeilstring="Pfad"

Set oShape = ActiveDocument.Shapes.AddPicture(FileName:=strTeilstring, LinkToFile:=False, SaveWithDocument:=True)
        'optionale Formatierungen
         oShape.Height = 130
         oShape.Width = 122.45
         oShape.Left = CentimetersToPoints(12)
         oShape.Top = CentimetersToPoints(2)

End Sub




freundliche Grüße in Vorraus
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
06. Apr 2009, 22:47
Rufname:
Wohnort: Leipzig


AW: Grafik auf bestimmer Seite - AW: Grafik auf bestimmer Seite

Nach oben
       Version: Office 2003

Hallo MKey89,

eine Shape wird immer an einem bestimmten Absatz (in Word: Paragraph) verankert. Man kann die Anker sehen, wenn man in Extras - Optionen - Ansicht die "Objektanker" aktiviert.

Beim Erzeugen einer Shape muss das Argument Anchor mit angegeben werden, das muss einen Absatz bezeichnen. Dann wird die Shape an diesem Absatz "verankert". Entweder Du suchst Dir einen Absatz, der auf Seite 2 oder 3 steht, und nimmst den, z.B. so:
Code:
Sub GrafikimAbsatz3()

    Dim strTeilstring As String
    Dim oShape As Shape

    strTeilstring = "Pfad"
   
    Set oShape = ActiveDocument.Shapes.AddPicture(FileName:=strTeilstring, _
        LinkToFile:=False, SaveWithDocument:=True, _
        Anchor:=ActiveDocument.Paragraphs(3).Range)
        'optionale Formatierungen
    oShape.Height = 130
    oShape.Width = 122.45
    oShape.Left = CentimetersToPoints(12)
    oShape.Top = CentimetersToPoints(2)

End Sub

Alternativ kannst Du auch einen Hilfsrange bilden, um die Seite 2 oder X zu ermitteln (weil Seiten in Word leider keine Objekte sind, im Gegensatz zu Absätzen (Paragraphs) und Abschnitten (Sections):
Code:
Sub GrafikaufSeite2()

    Dim rng As Word.Range
    Dim lngAbsatz As Long
    Dim oShape As Shape
    Dim strTeilstring As String

    strTeilstring = "Pfad"

    Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Count:=2
    ' auf Seite 2 begeben
    Set rng = ActiveDocument.Range(Start:=ActiveDocument.Paragraphs(1).Range.Start, _
        End:=Selection.Paragraphs(1).Range.End)
    ' einen Hilfsrange vom Anfang bis Seite 2 bilden
    lngAbsatz = rng.Paragraphs.Count
    ' die Nr. des aktuellen Absatzes erfassen
    Set oShape = ActiveDocument.Shapes.AddPicture(FileName:=strTeilstring, _
        LinkToFile:=False, SaveWithDocument:=True, Anchor:=ActiveDocument.Paragraphs(lngAbsatz).Range)
        'optionale Formatierungen
    oShape.Height = 130
    oShape.Width = 122.45
    oShape.Left = CentimetersToPoints(12)
    oShape.Top = CentimetersToPoints(2)
       
End Sub

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
MKey89
Blutiger Anfänger


Verfasst am:
07. Apr 2009, 16:07
Rufname:

AW: Grafik auf bestimmer Seite - AW: Grafik auf bestimmer Seite

Nach oben
       Version: Office 2003

Hallo,
danke für den Tipp Lisa. Doch nun frag ich mich als Neuling wie kann ich meiner .dot Vorlage mitteilen, dass dort ein Paragraph exestiert? Ich kann doch nicht direkt in das Makro springen und dem mitteilen da wäre einer, wenn ich noch keinen definiert habe, oder?
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
07. Apr 2009, 16:19
Rufname:
Wohnort: Leipzig

AW: Grafik auf bestimmer Seite - AW: Grafik auf bestimmer Seite

Nach oben
       Version: Office 2003

Hallo MKey89,

aha, jetzt sind wir an dem Punkt, wo Du mir sagen solltest, was Du eigentlich wirklich willst ;) In der Vorlage gibt es noch gar keine Seite 2, 3 usw.? Wieso willst Du dann dort schon eine Grafik einfügen?

Bitte beschreibe mal genau, was Du erreichen willst.

Mir schwant da etwas: Falls es darum geht, dass eine Grafik auf ALLEN Seiten eingefügt werden soll, die ist besser in der Kopfzeile untergebracht. Dann braucht man sie nur einmal einzufügen und sie ist trotzdem auf allen Seiten zu sehen. Das geht z.B. so:
Code:
Sub GrafikInKopfzeile()

    Dim oShape As Shape
    Dim strTeilstring As String
   
    strTeilstring = "Pfad"
   
    Set oShape = ActiveDocument.Sections(1).Headers(wdHeaderFooterPrimary).Shapes.AddPicture _
        (FileName:=strTeilstring, _
        LinkToFile:=False, _
        SaveWithDocument:=True, _
        Anchor:=ActiveDocument.Sections(1).Headers(wdHeaderFooterPrimary).Range)
    With oShape
        .Height = 130
        .Width = 122.45
        .Left = CentimetersToPoints(12)
        .Top = CentimetersToPoints(2)
    End With
   
End Sub

Es stört nicht, wenn die Vorlage anfangs nur 1 Seite enthält. Die Kopfzeile kann man trotzdem befüllen.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
MKey89
Blutiger Anfänger


Verfasst am:
07. Apr 2009, 16:37
Rufname:

AW: Grafik auf bestimmer Seite - AW: Grafik auf bestimmer Seite

Nach oben
       Version: Office 2003

Doch ich habe schon eine Seite 2 und 3. Ich kann es leider nicht in die Kopfzeile machen, da das Bild eigentlich mehr in den Hauptbereich soll ( in html würde man Body dazu sagen).
Bisher habe ich in meinem Dokument halt Texte die auf jeder Seite unterschiedlich sind. Es soll aber auf jeder Seite dieses Bild sein, dass sich automatisch aus den Pfad generiert. Das Bild bekomme ich auch anezeigt, aber es erscheint Aufgrund meiner deklaration immer nur auf der ersten Seite.

Ich habe versucht durch Textmarken die ich über GoTo ansteuer, auf die anderen beiden Seiten zu springen, da ich bemerkt habe, dass die Zähler der Lineale immer pro Seite neu beginnen, aber das auch nix genützt. Das Bild wurde mir trotzdem auf der ersten Seite eingefügt.

Ich weiß nicht was du mit einem Paragraphen genau meinst. Irgendwie muss ich meinem Worddokument doch bestimmt sagen von dort bis dort ist der Paragraph oder nicht ?

Sag ich das über eine Textmarke, Seitenumbruch,oder wie ?
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
07. Apr 2009, 17:05
Rufname:
Wohnort: Leipzig


AW: Grafik auf bestimmer Seite - AW: Grafik auf bestimmer Seite

Nach oben
       Version: Office 2003

Hallo MKey89,

ähem, ich versuch's mal zu erklären. Die Kopfzeile heißt zwar Kopfzeile, ihr eigentliches Charakteristikum ist jedoch, dass es ein Bereich ist, der auf allen Seiten wiederholt wird. Der muss überhaupt nicht oben auf der Seite sein, sondern kann durchaus in der Mitte des Blattes liegen. Die Shape, die dort eingefügt wird, kann an eine ganz normale Stelle verschoben werden. Die Platzierung in der Kopfzeile sorgt nur dafür, dass sie nur einmal eingefügt wird, jedoch auf allen Seiten an derselben Stelle sichtbar ist. (Das spart auch Speicherplatz und Dokumentgröße!!)

Also am Beispiel: Ich habe ein Dokument mit 100 Seiten, in denen auf jeder Seite das gleiche Bild, z.B. ein Logo in der Mitte der Seite stehen soll (was Dussligeres fällt mir gerade nicht ein). Das platziere ich EINMAL in der Kopfzeile und schiebe es in die Mitte der Seite. Dann lege ich noch den Textumbruch passend fest, ob es vom Text umflossen werden soll, über dem Text oder dahinter liegen soll und fertig. Ich habe nur ein Bild im Dokument, das Dokument bleibt klein. Trotzdem ist das Bild auf allen Seiten zu sehen.

Nun zum Paragraph. Ein Paragraph ist ein Absatz im Word-Objektmodell. Er wird von einer abschließenden Absatzmarke begrenzt: ¶ Der Text zwischen zwei solchen Absatzmarken ist ein Absatz, nicht zu verwechseln mit einer Zeile. Ein Absatz hat mindestens 1 Zeile, es können aber auch mehr sein. Blende Dir mal mit Strg Shift + die nicht druckbaren Zeichen ein, dann sieht Du die Absatzmarken.

Ein Dokument besteht in dem Sinne aus Absätzen (Paragraphs). Die Absätze bestehen aus Wörtern (words). Die Wörter bestehen aus Zeichen (Characters). Absätze sind gut handelbare Objekt im Word-Objektmodell, weil sie ein festes Ende und einen festen Anfang haben. Seiten und Zeilen sind dagegen schlecht anzusteuern, weil sie sich verschieben, sobald Du irgendwo etwas einfügst, befindet sich die nächste Zeile eins weiter usw.

Eine Shape als frei im Dokument verschiebbares Element außerhalb des normalen Textflusses (im Gegensatz zu InlineShapes, die einfach wie ein einzelnes Zeichen in den Text eingefügt werden, können auch Bilder/Grafiken sein), also ein Shape braucht einen Ankerpunkt, das muss ein Absatz sein.

Gib mal Bescheid, ob das jetzt klar ist. Wenn Du also weist, an welchem Absatz die Shape "verankert" werden soll, kann man den einfach angeben. Deswegen hatte ich oben das Beispiel. Man geht mit dem Cursor auf Seite 2 und zählt, wie viele Absätze es vom Dokumentbeginn an sind.

Deswegen hatte ich oben im Beispiel den "Hilfsrange". Du könntest mal diesen Code nehmen:
Code:
Sub GrafikaufSeiteX()

    Dim rng As Word.Range
    Dim lngAbsatz As Long
    Dim oShape As Shape
    Dim strTeilstring As String

    strTeilstring = "Pfad"

    Set rng = ActiveDocument.Range(Start:=ActiveDocument.Paragraphs(1).Range.Start, _
        End:=Selection.Paragraphs(1).Range.End)
    ' einen Hilfsrange vom Anfang bis Seite 2 bilden
    lngAbsatz = rng.Paragraphs.Count
    ' die Nr. des aktuellen Absatzes erfassen
    Set oShape = ActiveDocument.Shapes.AddPicture(FileName:=strTeilstring, _
        LinkToFile:=False, SaveWithDocument:=True, Anchor:=ActiveDocument.Paragraphs(lngAbsatz).Range)
        'optionale Formatierungen
    oShape.Height = 130
    oShape.Width = 122.45
    oShape.Left = CentimetersToPoints(12)
    oShape.Top = CentimetersToPoints(2)
       
End Sub

Hier wird die Shape an demjenigen Absatz verankert, in dem der Cursor gerade steht. Du klickst also zuerst auf Seite 3 in den Absatz, an dem die Grafik verankert werden soll, und führst dann dieses Makro aus. Dann wird die Grafik an diesem Absatz verankert. Hilft Dir das weiter?

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Word Serienbriefe: Unterdrückung Ausgabe der zweiten Seite, wenn Datenfeld leer 4 fmerten 214 20. Aug 2013, 15:50
fmerten Unterdrückung Ausgabe der zweiten Seite, wenn Datenfeld leer
Keine neuen Beiträge Word Serienbriefe: Serienbrief druckt nur Seite 1 von 11 aus 1 Panoramaviewer 1220 14. Dez 2012, 01:30
MarkMH_K Serienbrief druckt nur Seite 1 von 11 aus
Keine neuen Beiträge Word Serienbriefe: Serienbrief Datenbericht letzte Seite 1 nette1 508 09. Aug 2012, 18:58
J_B Serienbrief Datenbericht letzte Seite
Keine neuen Beiträge Word Serienbriefe: Verknüpfung einer Excel Grafik in Word MSOFFICE 2010!! HELP! 4 Gast 3368 05. Jun 2012, 09:31
AlainCharre Verknüpfung einer Excel Grafik in Word MSOFFICE 2010!! HELP!
Keine neuen Beiträge Word Serienbriefe: Serienbrief mit mehreren Datensätzen auf einer Seite 0 oskar0815 715 07. Mai 2012, 12:01
oskar0815 Serienbrief mit mehreren Datensätzen auf einer Seite
Keine neuen Beiträge Word Serienbriefe: Datensätze auf einer Seite; Serienbrief Word 2010 1 Gast 1129 06. Mai 2012, 11:38
MarkMH_K Datensätze auf einer Seite; Serienbrief Word 2010
Keine neuen Beiträge Word Serienbriefe: Ettikettendruck - immer nur ein Datensatz pro Seite 3 anschi 714 05. Apr 2012, 15:47
Löwi Ettikettendruck - immer nur ein Datensatz pro Seite
Keine neuen Beiträge Word Serienbriefe: Seriendruck: Alles doppelt auf jeder Seite.... 1 tomsan 1138 17. Dez 2011, 23:51
charlybrown Seriendruck: Alles doppelt auf jeder Seite....
Keine neuen Beiträge Word Serienbriefe: Seite in Serienbrief überspringen 1 tiger28 1113 06. Jan 2011, 15:11
charlybrown Seite in Serienbrief überspringen
Keine neuen Beiträge Word Serienbriefe: Seriendruck mehrere Daten pro Seite 3 Envy 3297 10. Sep 2010, 11:09
charlybrown Seriendruck mehrere Daten pro Seite
Keine neuen Beiträge Word Serienbriefe: Serienbrief: Pro Seite je 2 Felder je 2 mal??? 4 misterwro 1823 17. Mai 2010, 17:47
misterwro Serienbrief: Pro Seite je 2 Felder je 2 mal???
Keine neuen Beiträge Word Serienbriefe: Serienbrief, gleiches Feld mehrmals auf Seite anderer Inhalt 3 Crey 1941 07. Apr 2010, 00:31
Gast Serienbrief, gleiches Feld mehrmals auf Seite anderer Inhalt
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft-Excel Diagramme