Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Leere Formularfelder nicht drucken/ anzeigen
zurück: Speicherproblem weiter: doppelseitiger Druck Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
grossermanitu
Im Profil kannst Du frei den Rang ändern


Verfasst am:
13. Mai 2009, 14:28
Rufname:

Leere Formularfelder nicht drucken/ anzeigen - Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo ich habe 2 Felder "Vorname" und "Nachname" in einer Zeile stehen. Wenn in Vorname nichts eingetragen wird, dann habe ich eine Lücke von 5 Leerzeilen mitten im Text. Wie stelle ich das an das Word leere Felder ignoriert und den nachfolgenden Text anfügt? Danke
grossermanitu
Im Profil kannst Du frei den Rang ändern


Verfasst am:
15. Mai 2009, 11:16
Rufname:


AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hm anscheinend gibt es keine einfache grundsätzliche Lösung. Dachte es gibt vielleicht in den optionen oder sonst wo einen Eintrag "Leere Felder nicht drucken"

Ich habe mir gerade folgendes überlegt: Man schreibt ein Makro das bei verlassen aktiviert wird. Das Makro prüft ob das jeweilige Feld leer ist und wenn ja dann wird das Feld ausgeblendet.

Also wenn Feld1=leer dann Feld1 ausblenden.

Macht das Sinn?
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
15. Mai 2009, 11:36
Rufname:
Wohnort: Leipzig

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo grossermanitu,

ja, das könnte man natürlich machen. Es ist halt nur so: Wenn der Formularbenutzer zuerst den Nachnamen eingibt, dabei das Vornamen-Feld "überspringt", z.B. mit Tab darüberläuft und erstmal hinten eingibt, dann würde mit dem Makro das Feld Vorname ausgeblendet (weil er ja nichts eingegeben hat). Der Nutzer sieht es dann nicht mehr Twisted Evil und wäre vermutlich irritiert.

Aus meiner Sicht besser wäre: Wenn der Benutzer mit der Eingabe fertig ist, werden alle Felder gecheckt und leer gebliebene ausgeblendet. Dabei könnte man auch gleich noch prüfen, ob der Nutzer etwa Felder leergelassen hat, die ausgefüllt werden müssen! Dazu könnte er dann noch aufgefordert werden: "Das Feld Name muss ausgefüllt werden." o.ä. Außerdem könnte man auch noch prüfen, ob in den Feldern gültige Angaben stehen, etwa dass im Feld Geburtsdatum nicht keine Buchstaben stehen, sondern ein Datum usw. Also sozusagen eine Validierung der ganzen Formularfelder.

Dafür müsste man sich überlegen, wodurch diese Validierung ausgelöst wird. Das Verlassen des letzten Feldes wäre aus obigen Überlegungen heraus nicht geeignet, wenn der Nutzer grundsätzlich von hinten nach vorne vorgeht ;)

Ich könnte mir vorstellen, dass es einen Button gibt, den der User dann zum Speichern oder Drucken des Formulars klicken muss. Dann wird zuerst die Validierung angestoßen, aufgefordert, fehlende Felder auszufüllen, leere Felder ausgeblendet, dann gedruckt bzw. gespeichert.

Das dürfte ohne VBA kaum zu machen sein.

Hier mal die Prüfung auf ein leeres Feld, das dann ausgeblendet wird (mit oben angesprochenem Dilemma):
Code:
Sub FeldPruefung()
' blendet das Feld Text1 aus, wenn es leer ist

    Dim bFormularschutz As Boolean
   
    If ActiveDocument.Bookmarks.Exists("Text1") Then
        If Len(ActiveDocument.FormFields("Text1").Result) = 0 Then
            If ActiveDocument.ProtectionType = wdAllowOnlyFormFields Then
                bFormularschutz = True
                ActiveDocument.Unprotect
            End If
            ActiveDocument.FormFields("Text1").Range.Font.Hidden = True
            If bFormularschutz Then
                ActiveDocument.Protect wdAllowOnlyFormFields, True
            End If
        End If
    End If
   
End Sub

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
grossermanitu
Im Profil kannst Du frei den Rang ändern


Verfasst am:
15. Mai 2009, 14:26
Rufname:

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo Lisa,

deine Überlegungen sind absolut richtig. Das Dokument irgendwann per Knopfdruck auf Fehler zuprüfen ist mein Ziel, das aber zum jetzigen Moment einfach noch zu früh kommt. Da ich bislang selbst in dieser Abteilung noch tätig bin habe ich meine Mitarbeiter schon geimpft das Dokument von oben nach unten auszufüllen und sich mit einblenden/ausblenden alle Zeichen somit auch die ausgeblendeten Felder anzeigen zulassen.

Dein Makro funktioniert wie immer einwandfrei. Wenn jemand nun doch einen Namen in das Feld hineinschriebt bleibt das Feld trotzdem noch ausgeblendet.

Zudem würde ich gerne statt das Feld "Text1" lieber die Textmarke "Textmarke1" aus- und einblenden lassen. Dies hätte den Vorteil das das Leerzeichen das danach kommt mit ausgblendet wird. Danke.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
15. Mai 2009, 17:47
Rufname:
Wohnort: Leipzig


AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo grossermanitu,

geht auch: Wenn das Feld namens "Text1" leer ist, wird "Textmarke1" ausgeblendet (natürlich müssen beide existieren):
Code:
Sub TMAusblenden()

    Dim bFormularschutz As Boolean
   
    If ActiveDocument.Bookmarks.Exists("Text1") Then
        If Len(ActiveDocument.FormFields("Text1").Result) = 0 Then
            If ActiveDocument.ProtectionType = wdAllowOnlyFormFields Then
                bFormularschutz = True
                ActiveDocument.Unprotect
            End If
            If ActiveDocument.Bookmarks.Exists("Textmarke1") Then
                If ActiveDocument.Bookmarks("Textmarke1").Range.Font.Hidden = False Then
                    ActiveDocument.Bookmarks("Textmarke1").Range.Font.Hidden = True
                End If
            End If
            If bFormularschutz Then
                ActiveDocument.Protect wdAllowOnlyFormFields, True
            End If
        End If
    End If

End Sub

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
grossermanitu
Im Profil kannst Du frei den Rang ändern


Verfasst am:
18. Mai 2009, 10:01
Rufname:

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Danke Lisa, das mit der Textmarke ausblenden klappt einwandfrei.

Ich war so frei und habe deinen Code erweitert. Jetzt wird der Text auch wieder eingeblendet sobald jemand doch noch etwas in das Feld hineinschreibt.

Langsam blicke ich ein wenig durch. Razz Nochmal danke.


Code:

Sub vn1()
    Dim bFormularschutz As Boolean
   
    If ActiveDocument.Bookmarks.Exists("vname1") Then
        If Len(ActiveDocument.FormFields("vname1").Result) = 0 Then
            If ActiveDocument.ProtectionType = wdAllowOnlyFormFields Then
                bFormularschutz = True
                ActiveDocument.Unprotect
            End If
            If ActiveDocument.Bookmarks.Exists("vname1") Then
                If ActiveDocument.Bookmarks("vname1").Range.Font.Hidden = False Then
                    ActiveDocument.Bookmarks("vname1").Range.Font.Hidden = True
                Else
                    ActiveDocument.Bookmarks("vname1").Range.Font.Hidden = False
                End If
            End If
            If bFormularschutz Then
                ActiveDocument.Protect wdAllowOnlyFormFields, True
            End If
        End If
    End If

End Sub
[quote][/quote]
grossermanitu
Im Profil kannst Du frei den Rang ändern


Verfasst am:
18. Mai 2009, 10:43
Rufname:

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hm also irgendwie brauche ich doch noch mal eine Nachhilfestunde.

Wenn in vname1 nichts steht wird beim verlassen die textmarke vname1 ausgeblendet. Wenn ich zurückgehe wird sie wieder eingeblendet auch wenn kein Text im Feld steht. Question
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
18. Mai 2009, 12:38
Rufname:
Wohnort: Leipzig

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo grossermanitu,

das ist genau das, was in Deinem (geänderten) Codestück steht. Mach Dir nichts draus, ist bloß eine Frage der Logik: Der Else-Zweig war an der falschen Stelle. Probier mal so:
Code:
Sub vn1()
   
    Dim bFormularschutz As Boolean
   
    If ActiveDocument.Bookmarks.Exists("vname1") Then
        If ActiveDocument.ProtectionType = wdAllowOnlyFormFields Then
            bFormularschutz = True
            ActiveDocument.Unprotect
        End If
        If Len(ActiveDocument.FormFields("vname1").Result) = 0 Then
            If ActiveDocument.Bookmarks("vname1").Range.Font.Hidden = False Then
                ActiveDocument.Bookmarks("vname1").Range.Font.Hidden = True
            End If
        Else
            If ActiveDocument.Bookmarks("vname1").Range.Font.Hidden = True Then
                ActiveDocument.Bookmarks("vname1").Range.Font.Hidden = False
            End If
        End If
        If bFormularschutz Then
            ActiveDocument.Protect wdAllowOnlyFormFields, True
        End If
    End If

End Sub

Die Abweichung besteht jetzt übrigens auch darin, dass im letzten Fall eine Textmarke und ein Formularfeld verknüpft waren, hier haben jedoch beide denselben Namen. Trifft das wirklich zu? Oder willst Du das Formularfeld ausblenden, wenn es leer ist. Dann wird es mit dem Einblenden (wenn gefüllt) schwierig, weil der Nutzer ja nichts eingeben kann, wenn er das Feld nicht sieht ;)

Textmarken sind im Dokument einmalig. Die Namen der Formularfelder sind ebenfalls Textmarken, also bitte nochmal prüfen, ob das zwei verschiedene Textmarken sind (das Feld und die Textmarke), dann müssen die Abfragen anders lauten!!

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
grossermanitu
Im Profil kannst Du frei den Rang ändern


Verfasst am:
18. Mai 2009, 13:09
Rufname:

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Also es ist so das ich dem Formularfeld Text1 plus dem nachfolgenden Leerzeichen die Textmarke vname1 verpasst habe. Dadurch hat sich der Feldname ebenfalls auf vname1 geändert.

Deswegen scheint wohl dein nue angepasster code leider auch nicht richtig zu funktionieren
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
18. Mai 2009, 13:21
Rufname:
Wohnort: Leipzig

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo grosser Manitu,

das geht nicht!! Die Namen müssen unterschiedlich sein. Jede Textmarke hat einen Namen, der muss als Textmarke einmalig sein. Es gibt keine zwei Textmarken mit gleichem Namen!

Jedes Formularfeld hat ebenfalls einen Textmarkennamen. Der muss sich von jedem anderen Textmarkennamen im Dokument unterscheiden. Also bitte vergibt zwei unterschiedliche Namen (so war es ja ursprünglich auch, das Formularfeld hieß "Text1" und die Textmarke hieß "Textmarke1".

Also: das Formularfeld erhält den Namen "vname1", die Textmarke (die das folgende Leerzeichen mit umfasst) erhält den Namen "vname1_tm"):
Code:
Sub vn1()
   
    Dim bFormularschutz As Boolean
   
    If ActiveDocument.Bookmarks.Exists("vname1") And ActiveDocument.Bookmarks.Exists("vname1_tm") Then
        If ActiveDocument.ProtectionType = wdAllowOnlyFormFields Then
            bFormularschutz = True
            ActiveDocument.Unprotect
        End If
        If Len(ActiveDocument.FormFields("vname1").Result) = 0 Then
            If ActiveDocument.Bookmarks("vname1_tm").Range.Font.Hidden = False Then
                ActiveDocument.Bookmarks("vname1_tm").Range.Font.Hidden = True
            End If
        Else
            If ActiveDocument.Bookmarks("vname1_tm").Range.Font.Hidden = True Then
                ActiveDocument.Bookmarks("vname1_tm").Range.Font.Hidden = False
            End If
        End If
        If bFormularschutz Then
            ActiveDocument.Protect wdAllowOnlyFormFields, True
        End If
    End If

End Sub

Das Dilemma, dass man das Formularfeld nicht mehr ausfüllen kann, wenn es unsichtbar ist, besteht trotzdem weiter.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
grossermanitu
Im Profil kannst Du frei den Rang ändern


Verfasst am:
18. Mai 2009, 14:16
Rufname:

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Ok ich habe es geändert. Feld=vname1. Textmarke die vname1 + Leerzeichen umschließt heißt vname1_tm.

Wenn das Feld einmal ausgeblendet ist wird es nicht mehr eingeblendet wenn text im feld vname1 steht.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
18. Mai 2009, 15:18
Rufname:
Wohnort: Leipzig

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo grossermanitu,

Zitat:
Wenn das Feld einmal ausgeblendet ist wird es nicht mehr eingeblendet wenn text im feld vname1 steht.

Ist das jetzt eine Zustandsbeschreibung als Feedback oder eine Fehlermeldung als Frage? Genau das ist das, was der Code macht und was Du vorgegeben hast. Ich fasse nochmal zusammen:
  • Du hast ein Formularfeld namens vname1.
  • Du hast eine Textmarke vname1_tm, sie umfasst den Inhalt des Formularfeldes + 1 folgendes Leerzeichen.
  • Wenn das Formularfeld vname1 beim Verlassen leer ist, wird die Textmarke vname1_tm ausgeblendet. Soweit klar.
  • Der Code sieht auch vor, dass die Textmarke wieder eingeblendet wird, wenn das Formularfeld nicht leer sein sollte (und zwar beim Verlassen des Feldes). Das würde auch funktionieren, wenn der Nutzer das Feld ausfüllen könnte. Das kann er schlechterdings nicht, weil er es nicht sieht, denn es ist ja ausgeblendet, weil es leer war (!). Wenn es dem Nutzer gelänge, das Feld auszufüllen, könnte er es auch wieder sehen. (Auch wenn Logik nicht zu Deinen Stärken gehört, sollte Dir dieser Satz doch zu denken geben ;))
  • Das ist die logische Folge Deiner Konstruktion, dass Formularfeld und Textmarke am selben Ort stehen. Es ist genau das, was Du beschrieben hast, erreichen zu wollen.
  • Ich halte das nicht für besonders performant und nutzerfreundlich, aber wenn Du das so möchtest.

Ansonsten gilt wie meist: Wenn es Dir gelingt, 1. zu wissen, 2. zu formulieren, was Word machen soll, gelingt es mir, Word beizubringen, was es machen soll. Hierbei ist die Reihenfolge nicht verhandelbar, sondern zwingend.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
grossermanitu
Im Profil kannst Du frei den Rang ändern


Verfasst am:
27. Mai 2009, 10:11
Rufname:

Re: AW: Leere Formularfelder nicht drucken/ anzeigen - Re: AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo Lisa sorry war die letzte Woch nicht auf der Arbeit.

Lisa - 18. Mai 2009, 15:18 hat folgendes geschrieben:


[*]Der Code sieht auch vor, dass die Textmarke wieder eingeblendet wird, wenn das Formularfeld nicht leer sein sollte (und zwar beim Verlassen des Feldes). Das würde auch funktionieren, wenn der Nutzer das Feld ausfüllen könnte. Das kann er schlechterdings nicht, weil er es nicht sieht, denn es ist ja ausgeblendet, weil es leer war (!). Wenn es dem Nutzer gelänge, das Feld auszufüllen, könnte er es auch wieder sehen. (Auch wenn Logik nicht zu Deinen Stärken gehört, sollte Dir dieser Satz doch zu denken geben ;))


Wenn in Extras-Optionen-Formatierungszeichen-Alle das Häkchen gesetzt ist dann kann der Benutzer auch ausgblendete Felder sehen.

Lisa - 18. Mai 2009, 15:18 hat folgendes geschrieben:
Hallo grossermanitu,

Zitat:
Wenn das Feld einmal ausgeblendet ist wird es nicht mehr eingeblendet wenn text im feld vname1 steht.

Ist das jetzt eine Zustandsbeschreibung als Feedback oder eine Fehlermeldung als Frage? Genau das ist das, was der Code macht und was Du vorgegeben hast.


Das ist eine Fehlerbeschreibung. Das Feld wird ausgeblendet wenn leer. Im nachhinein wird der Vorname bekannt und in das Feld eingefügt (Alle Formatieurngen anzeigen ist standartmäßig aktiviert)
Leider verändert sich danach die Textmarke vname1_tm samt Feld vname1 nicht in eingeblendet.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
28. Mai 2009, 14:20
Rufname:
Wohnort: Leipzig

AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Hallo grossermanitu,

ich habe im Moment auch nicht so viel Zeit, deswegen jetzt erst. Du hast Recht, solange das Formularfeld "ausgeblendet" ist, gibt die Result-Eigenschaft nichts zurück Twisted Evil

Probier mal das hier:
Code:
Sub vn1()
   
    Dim bFormularschutz As Boolean
   
    If ActiveDocument.Bookmarks.Exists("vname1") And ActiveDocument.Bookmarks.Exists("vname1_tm") Then
        If ActiveDocument.ProtectionType = wdAllowOnlyFormFields Then
            bFormularschutz = True
            ActiveDocument.Unprotect
        End If
        If ActiveDocument.FormFields("vname1").Range.Font.Hidden = True Then
            ActiveDocument.FormFields("vname1").Range.Font.Hidden = False
        End If
        If Len(ActiveDocument.FormFields("vname1").Result) = 0 Then
            If ActiveDocument.Bookmarks("vname1_tm").Range.Font.Hidden = False Then
                ActiveDocument.Bookmarks("vname1_tm").Range.Font.Hidden = True
            End If
        Else
            If ActiveDocument.Bookmarks("vname1_tm").Range.Font.Hidden = True Then
                ActiveDocument.Bookmarks("vname1_tm").Range.Font.Hidden = False
            End If
        End If
        If bFormularschutz Then
            ActiveDocument.Protect wdAllowOnlyFormFields, True
        End If
    End If

End Sub

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Gast



Verfasst am:
02. Jun 2009, 10:19
Rufname:


AW: Leere Formularfelder nicht drucken/ anzeigen - AW: Leere Formularfelder nicht drucken/ anzeigen

Nach oben
       Version: Office 2003

Klasse jetzt gehts. Danke
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Word Serienbriefe: Serienbrief aus Access: bestimmte Adresse anzeigen 12 Wolfgang27 6874 26. Sep 2011, 15:15
logicalsmile Serienbrief aus Access: bestimmte Adresse anzeigen
Keine neuen Beiträge Word Serienbriefe: Word 2007 - Serienbrief drucken !!!! 1 Bruno-bvt 4451 14. Dez 2009, 09:29
spaengle Word 2007 - Serienbrief drucken !!!!
Keine neuen Beiträge Word Serienbriefe: Etiketten drucken aus Word-Tabelle 5 Birgitta 2740 26. Nov 2009, 16:35
charlybrown Etiketten drucken aus Word-Tabelle
Keine neuen Beiträge Word Serienbriefe: Einzelnen Datensatz aus Access 2007 in Word 2007 anzeigen 0 ermso07 3429 29. Mai 2008, 17:31
ermso07 Einzelnen Datensatz aus Access 2007 in Word 2007 anzeigen
Keine neuen Beiträge Word Serienbriefe: Umschläge drucken 11x16 mit Canon MP 510 0 Amitl 2515 18. Mai 2008, 10:42
Amitl Umschläge drucken 11x16 mit Canon MP 510
Keine neuen Beiträge Word Serienbriefe: Seriendruck und Formularfelder 0 winzig 690 13. Feb 2008, 10:42
winzig Seriendruck und Formularfelder
Keine neuen Beiträge Word Serienbriefe: Vollständige Datenquelle anzeigen 4 jette 6080 18. März 2007, 01:05
jette Vollständige Datenquelle anzeigen
Keine neuen Beiträge Word Serienbriefe: Laufende Nummern auf Etiketten drucken- mal wieder! 2 Gast 15671 02. März 2007, 15:34
Gast Laufende Nummern auf Etiketten drucken- mal wieder!
Keine neuen Beiträge Word Serienbriefe: Serienbrief/-druck -- Leere löschen/aussortieren 3 Friegel 2003 17. Feb 2007, 09:52
Friegel. Serienbrief/-druck -- Leere löschen/aussortieren
Keine neuen Beiträge Word Serienbriefe: Serienbrief 2. Seite abhängig von Datenquelle drucken 5 karin1 4065 08. Dez 2006, 13:58
karin1 Serienbrief 2. Seite abhängig von Datenquelle drucken
Keine neuen Beiträge Word Serienbriefe: Datenquelle anzeigen 2 GrünesTelefon 1525 17. Nov 2006, 10:35
GrünesTelefon Datenquelle anzeigen
Keine neuen Beiträge Word Serienbriefe: Serienbrief Leerzeilen nicht anzeigen 6 Gast 7168 18. Mai 2006, 11:07
Gast Serienbrief Leerzeilen nicht anzeigen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: HTML Editor Forum