Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Mehrfach vorhandene Einträge in ComboBox entfernen
zurück: Adresse des kopierten Bereichs auslesen weiter: Rows().Delate erzeugt Fehler Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Domin2000
Im Profil kannst Du frei den Rang ändern


Verfasst am:
21. Jul 2009, 09:02
Rufname:

Mehrfach vorhandene Einträge in ComboBox entfernen - Mehrfach vorhandene Einträge in ComboBox entfernen

Nach oben
       Version: Office 2003

Hallo Leute!

Wie kann ich diese Funktion erweitern um mehrfachvorhandene Einträge aus einer Combobox zu entfernen? Gibt es da einen kleinen Trick?

Code:

Function cbo_fuellen(cbo As MSForms.ComboBox, spalte As Integer, tbl As Worksheet)
    Dim i As Integer
    For i = 2 To tbl.Cells(Rows.Count, spalte).End(xlUp).Row
        cbo.AddItem tbl.Cells(i, spalte)
    Next
End Function


Danke schonmal im Voraus!

LG
Dominik
bst
Programmierer


Verfasst am:
21. Jul 2009, 09:58
Rufname: Bernd
Wohnort: Ilsfeld


AW: Mehrfach vorhandene Einträge in ComboBox entfernen - AW: Mehrfach vorhandene Einträge in ComboBox entfernen

Nach oben
       Version: Office 2003

Hi Dominik,

versuche das mal so.

cu, Bernd
--
Code:
Function cbo_fuellen(cbo As MSForms.ComboBox, spalte As Integer, tbl As Worksheet)
   Dim i As Long, ar As Variant, objDic As Object
   
   Set objDic = CreateObject("scripting.dictionary")
   ar = tbl.Range(tbl.Cells(2, spalte), tbl.Cells(tbl.Rows.Count, spalte).End(xlUp))
       
   For i = 1 To UBound(ar)
      objDic(ar(i, 1)) = 1
   Next
   cbo.List = objDic.Keys
   
   objDic.RemoveAll
   Set objDic = Nothing
End Function
Phelan XLPH
Fortgeschritten


Verfasst am:
21. Jul 2009, 10:11
Rufname: Phelan

AW: Mehrfach vorhandene Einträge in ComboBox entfernen - AW: Mehrfach vorhandene Einträge in ComboBox entfernen

Nach oben
       Version: Office 2003

hallo,

Code:
Function cbo_fuellen(cbo As MSForms.ComboBox, spalte As Integer, tbl As Worksheet)
    Dim i As Integer
    Dim Dic As Object
    Set Dic = CreateObject("Scripting.Dictionary")
    For i = 2 To tbl.Cells(Rows.Count, spalte).End(xlUp).Row
        If Not Dic.Exists(tbl.Cells(i, spalte).Text) Then
            Dic(tbl.Cells(i, spalte).Text) = 0
            cbo.AddItem tbl.Cells(i, spalte)
        End If
    Next
End Function

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
Domin2000
Im Profil kannst Du frei den Rang ändern


Verfasst am:
21. Jul 2009, 10:39
Rufname:

AW: Mehrfach vorhandene Einträge in ComboBox entfernen - AW: Mehrfach vorhandene Einträge in ComboBox entfernen

Nach oben
       Version: Office 2003

Super! Danke für eure Antworten! Very Happy

Eine kleine Frage hätte ich noch: Die Liste ist leider ungeordnet. Lassen sich die Einträge absteigen/austeigen oder alphabetisch ordnen?
Phelan XLPH
Fortgeschritten


Verfasst am:
21. Jul 2009, 11:05
Rufname: Phelan

AW: Mehrfach vorhandene Einträge in ComboBox entfernen - AW: Mehrfach vorhandene Einträge in ComboBox entfernen

Nach oben
       Version: Office 2003

das muss ich was aus der Profi-Kiste holen:

Code:
Function cbo_fuellen(cbo As MSForms.ComboBox, spalte As Integer, tbl As Worksheet)
    Dim i As Integer, arr As Variant
    Dim SL As Object
    Set SL = CreateObject("System.Collections.sortedlist")
    arr = tbl.Range(tbl.Cells(2, spalte), tbl.Cells(tbl.Rows.Count, spalte).End(xlUp))
    For i = 1 To UBound(arr)
        If arr(i, 1) <> "" Then _
        SL(arr(i, 1)) = ""
    Next
    ReDim arr(SL.Count - 1)
    For i = 0 To SL.Count - 1
         arr(i) = SL.GetKey(i)
    Next
    cbo.List = arr
End Function

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
Jleppii
Gast


Verfasst am:
11. Okt 2009, 23:12
Rufname:

AW: Mehrfach vorhandene Einträge in ComboBox entfernen - AW: Mehrfach vorhandene Einträge in ComboBox entfernen

Nach oben
       Version: Office 2003

Hallo,

erstmal ein Danke an den Glücksritter für die netten beiden Funktionen!

Jetzt meine Frage warum ich das Thema nochmal aufgreife...

Ich hab schon ein wenig rumprobiert das ganze so umzuschreiben, dass alle
Sheets im Workbook durchsucht werden und die Daten zusammengefasst und sortiert werden.
Für die "nicht" Sortier Funktion funzt es auch einwandfrei, doch bei der Sortier Funktion hab ich so meine Probleme und es funzt nix mehr ;D
bst
Programmierer


Verfasst am:
12. Okt 2009, 08:30
Rufname: Bernd
Wohnort: Ilsfeld

AW: Mehrfach vorhandene Einträge in ComboBox entfernen - AW: Mehrfach vorhandene Einträge in ComboBox entfernen

Nach oben
       Version: Office 2003

Morgen,

versuche das mal so.

cu, Bernd
--
Code:
Option Explicit

Private Sub UserForm_Initialize()
   cbo_fuellen ComboBox1, 2
End Sub

Sub cbo_fuellen(cbo As MSForms.ComboBox, spalte As Integer)
   Dim i As Integer, arr As Variant, intIndex As Integer
   Dim tbl As Worksheet, SL As Object
   
   Set SL = CreateObject("System.Collections.sortedlist")
   For intIndex = 1 To Worksheets.Count
      Set tbl = Worksheets(intIndex)
      arr = tbl.Range(tbl.Cells(2, spalte), tbl.Cells(tbl.Rows.Count, spalte).End(xlUp))
      For i = 1 To UBound(arr)
         If arr(i, 1) <> "" Then SL(arr(i, 1)) = ""
      Next
   Next
   
   ReDim arr(SL.Count - 1)
   For i = 0 To SL.Count - 1
      arr(i) = SL.GetKey(i)
   Next
   cbo.List = arr
End Sub

JLeppii
Gast


Verfasst am:
12. Okt 2009, 17:44
Rufname:


AW: Mehrfach vorhandene Einträge in ComboBox entfernen - AW: Mehrfach vorhandene Einträge in ComboBox entfernen

Nach oben
       Version: Office 2003

funktioniert einwandfrei!
danke dir sehr!
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Summe bilden, aber einfache zählung von mehrfach genanntem I 1 Saarländerin 1921 16. Apr 2007, 12:16
Gast Summe bilden, aber einfache zählung von mehrfach genanntem I
Keine neuen Beiträge Excel Formeln: Alle Wörter in Klammern entfernen 1 Maxi1 1592 08. Apr 2007, 19:28
Gast Alle Wörter in Klammern entfernen
Keine neuen Beiträge Excel Formeln: copyright aus exceldatei entfernen 1 karli82 1818 16. Jan 2007, 18:19
karli82 copyright aus exceldatei entfernen
Keine neuen Beiträge Excel Formeln: Nicht vorhandene Zahlen zählen 3 Alex06 489 10. Dez 2006, 17:57
Kaischi Nicht vorhandene Zahlen zählen
Keine neuen Beiträge Excel Formeln: mehrere Werte - ComboBox 0 Daywalker187 783 15. Nov 2006, 16:14
Daywalker187 mehrere Werte - ComboBox
Keine neuen Beiträge Excel Formeln: mehrfach vorkommendes zählen 5 smarth 2818 18. Okt 2006, 12:37
smarth mehrfach vorkommendes zählen
Keine neuen Beiträge Excel Formeln: Monats einträge 10 Reto_m 598 08. Okt 2006, 22:23
Reto_m Monats einträge
Keine neuen Beiträge Excel Formeln: Suchkriterium kommt mehrfach vor, SVERWEIS dennoch mögl.??? 2 Gast 1199 01. Aug 2006, 13:50
Gast Suchkriterium kommt mehrfach vor, SVERWEIS dennoch mögl.???
Keine neuen Beiträge Excel Formeln: Aufrunden eines Betrages (vorhandene Formel) auf volle 10 € 8 Kaska 11093 24. Mai 2006, 17:34
Kaska Aufrunden eines Betrages (vorhandene Formel) auf volle 10 €
Keine neuen Beiträge Excel Formeln: Leerzeichen entfernen ( aber nur am ende ) 10 MsgWaldfee 992 16. Mai 2006, 19:13
fridgenep Leerzeichen entfernen ( aber nur am ende )
Keine neuen Beiträge Excel Formeln: Wverweis bei mehrfach vorkommendem Suchkriterium 4 surfer6 1608 16. Jan 2006, 22:28
surfer6 Wverweis bei mehrfach vorkommendem Suchkriterium
Keine neuen Beiträge Excel Formeln: "Ersetzen" mehrfach verschachteln 2 Schirschi 2211 21. Nov 2005, 20:24
Gast "Ersetzen" mehrfach verschachteln
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Word VBA