Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Makro soll doppelte Nr erkennen Wichitg !!!
zurück: Grafik in Zwischenablage in Variable auslesen weiter: Zelleninhalt an bestimmter Stelle trennen Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Tommy10_13
Im Profil kannst Du frei den Rang ändern


Verfasst am:
29. Okt 2009, 20:21
Rufname:
Wohnort: Hamburg

Makro  soll doppelte Nr erkennen Wichitg !!! - Makro soll doppelte Nr erkennen Wichitg !!!

Nach oben
       Version: Office 2003

Hallo Excel Fans

Ich möchte gerne ein makro erstellen , aber weiß nicht wie ich es anstellen soll.

Ich möchte das mein Makro von D9 bis D70 die Nr vergleicht.
das ist immer eine 8 stellige zahl, und wenn die zahl öffters vorkommt möchte ich das nach der 2 gleichen zahl zb 12345678 (02) steht und dann 12345678 (03) und so weiter und so weiter kommt darauf an wieviel gleiche zahlen es sind.
Die Tabelle heißt Linie 5

Gruß Tommy
Phelan XLPH
Fortgeschritten


Verfasst am:
29. Okt 2009, 20:50
Rufname: Phelan


AW: Makro  soll doppelte Nr erkennen Wichitg !!! - AW: Makro soll doppelte Nr erkennen Wichitg !!!

Nach oben
       Version: Office 2003

Code:
Sub y()
Dim i As Long, lz As Long, anz As Long
lz = Cells(Rows.Count, 4).End(xlUp).Row
For i = lz To 1 Step -1
    anz = WorksheetFunction.CountIf(Range("D1:D" & i), Cells(i, 4))
    If anz > 1 Then Cells(i, 4) = Cells(i, 4) & " (" & Format(anz, "00") & ")"
Next
End Sub


oder so:

Code:
Sub y()
Dim i As Long, lz As Long, anz As Long
lz = Cells(Rows.Count, 4).End(xlUp).Row
For i = lz To 1 Step -1
    anz = WorksheetFunction.CountIf(Range("D1:D" & i), Cells(i, 4))
    Cells(i, 4) = Cells(i, 4) & " (" & Format(anz, "00") & ")"
Next
End Sub

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
RO_SCH
Mädchen für (fast) alles


Verfasst am:
29. Okt 2009, 21:02
Rufname: Roland
Wohnort: Nürnberg

AW: Makro  soll doppelte Nr erkennen Wichitg !!! - AW: Makro soll doppelte Nr erkennen Wichitg !!!

Nach oben
       Version: Office 2003

Hi Tommy,

oder so
Code:
Sub x()
Dim objDic As Object
Dim iRow As Long
Dim letzte As Long

With Sheets("Linie 5")
letzte = .Cells(Rows.Count, 4).End(xlUp).Row

Set objDic = CreateObject("Scripting.Dictionary")

For iRow = 9 To letzte
    If Not objDic.Exists(.Cells(iRow, 4).Text) Then
        objDic.Add .Cells(iRow, 4).Text, 1
    Else
        objDic(.Cells(iRow, 4).Text) = objDic(.Cells(iRow, 4).Text) + 1
        .Cells(iRow, 4).Value = .Cells(iRow, 4).Text & " (" & Format(objDic(.Cells(iRow, 4).Text), "00") & ")"
    End If
Next iRow
End With
End Sub

_________________
De nihilo nihil fit

Gruß Roland
Gast



Verfasst am:
29. Okt 2009, 21:04
Rufname:

AW: Makro  soll doppelte Nr erkennen Wichitg !!! - AW: Makro soll doppelte Nr erkennen Wichitg !!!

Nach oben
       Version: Office 2003

..oder auch so:
Code:

Sub xxx()
Dim i As Integer, n As Integer, m As Integer, tmp
For i = 9 To 70
    tmp = Cells(i, 4).Value
    n = 1
    For m = i + 1 To 70
        If Cells(m, 4).Value = tmp Then
            n = n + 1
            Cells(m, 4).Value = Cells(m, 4).Value & "(" & Format(n, "00") & ")"
        End If
    Next m
Next i
End Sub

Gruß Frank
l.key
Excel (VBA) brauchbar


Verfasst am:
29. Okt 2009, 21:16
Rufname:

AW: Makro  soll doppelte Nr erkennen Wichitg !!! - AW: Makro soll doppelte Nr erkennen Wichitg !!!

Nach oben
       Version: Office 2003

Hallo, ja hier geht's ja ab,
trotzdem noch eine Möglichkeit:
Code:
Sub VorkommenZählen()
Dim rngBereich As Range, rngZelle As Range
Dim rngAnzahl As Long, lngX As Long
Dim arrTemp As Variant
Set rngBereich = Range("D9:D70")
    ReDim arrTemp(1 To rngBereich.Cells.Count)
    For lngX = 1 To rngBereich.Cells.Count
        rngAnzahl = WorksheetFunction.CountIf(Range(rngBereich(1), rngBereich(lngX)), rngBereich(lngX))
        If rngAnzahl > 1 Then
            arrTemp(lngX) = rngBereich(lngX) & "(" & Format(rngAnzahl, "00") & ")"
        Else
            arrTemp(lngX) = rngBereich(lngX)
        End If
    Next
    rngBereich = WorksheetFunction.Transpose(arrTemp)
End Sub

... oder ganz einfach mit 'ner Formel in Extraspalte:
=D9& WENN(ZÄHLENWENN(D$9:D9;D9)>1;"("&TEXT(ZÄHLENWENN(D$9:D9;D9);"00")&")";"")

_________________
Grüße, Klaus.
Gast



Verfasst am:
29. Okt 2009, 21:47
Rufname:

AW: Makro  soll doppelte Nr erkennen Wichitg !!! - AW: Makro soll doppelte Nr erkennen Wichitg !!!

Nach oben
       Version: Office 2003

Hallo,

Ist ja fast wie bei der Primzahl-Bestimmung. Wir schaffen es bestimmt noch bis Seite 100...

Code:
Private Sub CommandButton1_Click()
Dim Bereich As String, tempArr As Variant, i As Long, j As Long, Zähler As Long

Bereich = "D9:D70"
tempArr = Range(Bereich)
For i = LBound(tempArr, 1) To UBound(tempArr, 1)
    Zähler = 0
    For j = LBound(tempArr, 1) To UBound(tempArr, 1)
        If tempArr(i, 1) = tempArr(j, 1) Then
            Zähler = Zähler + 1
            If Zähler > 1 Then tempArr(j, 1) = tempArr(i, 1) & " (" & Format(Zähler, "00") & ")"
        End If
    Next j
Next i
Range(Bereich) = tempArr

End Sub


Gruß, Jens
Tommy10_13
Im Profil kannst Du frei den Rang ändern


Verfasst am:
29. Okt 2009, 23:26
Rufname:
Wohnort: Hamburg


AW: Makro  soll doppelte Nr erkennen Wichitg !!! - AW: Makro soll doppelte Nr erkennen Wichitg !!!

Nach oben
       Version: Office 2003

Danke Razz ihr habt mir super schnell geholfen . Laughing

Danke für die vielen antworten ...

Gruß Tommy Very Happy
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Bedingte Formatierung nicht drucken? (oder Makro?) 1 Gast 1223 23. Aug 2006, 13:46
Cabation Bedingte Formatierung nicht drucken? (oder Makro?)
Keine neuen Beiträge Excel Formeln: doppelte Ergebnisse in Zellbereich markieren 4 bin Anfaenger 4038 14. Jun 2006, 15:16
bin Anfaenger doppelte Ergebnisse in Zellbereich markieren
Keine neuen Beiträge Excel Formeln: Doppelte eintäge und dazu noch kleinere Zahl anzeigen 0 markusr_ 677 17. Mai 2006, 07:59
markusr_ Doppelte eintäge und dazu noch kleinere Zahl anzeigen
Keine neuen Beiträge Excel Formeln: fettgedruckte werte erkennen 9 styfo 1599 02. Mai 2006, 13:09
< Peter > fettgedruckte werte erkennen
Keine neuen Beiträge Excel Formeln: Makro durch Funktion starten 11 Borsty22 12858 01. Apr 2006, 18:35
Hübi Makro durch Funktion starten
Keine neuen Beiträge Excel Formeln: Bestimmte Zahlen erkennen 2 Pebbles 891 22. März 2006, 10:50
Pebbles Bestimmte Zahlen erkennen
Keine neuen Beiträge Excel Formeln: Mappe öffnen mit automatische Makro 0 Vase 1610 23. Feb 2006, 13:31
Vase Mappe öffnen mit automatische Makro
Keine neuen Beiträge Excel Formeln: Zählen ohne doppelte Werte 1 Holger42 18309 21. Feb 2006, 14:52
Alto Zählen ohne doppelte Werte
Keine neuen Beiträge Excel Formeln: doppelte wenn abfrage 5 unbelievable 7484 12. Feb 2006, 18:06
unbelievable doppelte wenn abfrage
Keine neuen Beiträge Excel Formeln: Doppelte Zahlen aus einer Spalte erkennen und definieren 4 dan123 872 14. Dez 2005, 16:28
dan123 Doppelte Zahlen aus einer Spalte erkennen und definieren
Keine neuen Beiträge Excel Formeln: makro beim öffnen starten und werte auswählen 0 werner100 636 24. Nov 2005, 13:30
werner100 makro beim öffnen starten und werte auswählen
Keine neuen Beiträge Excel Formeln: doppelte Einträge löschen 10 neelix2001 996 18. Nov 2005, 14:34
Blaze doppelte Einträge löschen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Word VBA