Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Werte innerhalb Zeitintervalle eintragen lassen
zurück: Werte zur bestimmten zeit in Tabelle eintragen weiter: *T*Frage zu einer zeitlichen WENN DANN SONST Bedingung Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
TwoCubed
Excel-Kenner mit (geringer) VBA-Erfahrung


Verfasst am:
16. Mai 2011, 00:39
Rufname:

Werte innerhalb Zeitintervalle eintragen lassen - Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Moin moin!

Ich erstelle derzeit ein Abrechnungsformular in dem es notwendig ist, dass der Nutzer gewisse Prozentstufen zu gewissen Zeiten einträgt. Das sieht beispielsweise so aus:

In den Spalten A und B werden halt die Schaltzeiten und die Stufen der Signale angegeben. Aufgrund der Zeitdifferenz aus End- und Anfangszeit werden in Spalte D 15-minütige Zeitintervalle erzeugt. Das habe ich soweit auch schon mit VBA hinbekommen. Jetzt ist es jedoch wichtig, dass die Prozentstufen auch zu den entsprechenden Zeitintervallen gelistet werden. Es soll zum Zeitinterval des Signalaufrufs und dem Folgezeitinterval beispielsweise "##" ausgegeben werden. Die restlichen Intervalle müssen die korrekte Prozentzahl bekommen.

Ich hoffe die Tabelle ist einigermaßen verständlich. Ich habe bislang versucht die vom Nutzer eingegebenen Zeiten auf jeweils 15 Minuten abzurunden und dann mittels SVERWEIS zumindest die Prozentstufen zu den Aufrufsintervallen zuzuweisen. Das hat geklappt, aber das ist nicht annähernd das, was ich brauche Wink

Ich wäre für Vorschläge/Lösungen äußerst dankbar!

Tabelle1

 ABCDEF
1Datum [TT.MM.JJJJ hh:mm]Stufe [%] Datum [TT.MM.JJJJ hh:mm]Signalstufe [%] 
2      
302.02.2011 11:310 02.02.2011 11:30##<-- Signalaufruf (0%)
402.02.2011 13:4560 02.02.2011 11:45##<-- Folgezeitinterval
502.02.2011 13:560 02.02.2011 12:000 
602.02.2011 14:2160 02.02.2011 12:150 
702.02.2011 16:1630 02.02.2011 12:300 
802.02.2011 16:320 02.02.2011 12:450 
903.02.2011 07:1730 02.02.2011 13:000 
1003.02.2011 07:2660 02.02.2011 13:150 
1103.02.2011 07:31100 02.02.2011 13:300 
12   02.02.2011 13:45##<-- Signalaufruf (60% und im selben Interval 0%)
13   02.02.2011 14:00##<-- Folgezeitinterval
14   02.02.2011 14:15##<-- Signalaufruf (60%)
15   02.02.2011 14:30##<-- Folgezeitinterval
16   02.02.2011 14:4560 
17   02.02.2011 15:0060 
18   02.02.2011 15:1560 
19   02.02.2011 15:3060 
20   02.02.2011 15:4560 
21   02.02.2011 16:0060 
22   02.02.2011 16:15##<-- Signalaufruf (30%)
23   02.02.2011 16:30##<-- Signalaufruf (0%)
24   02.02.2011 16:45##<-- Folgezeitinterval
25   02.02.2011 17:000 
26   02.02.2011 17:150 
27   02.02.2011 17:300 
28   02.02.2011 17:450 
29   02.02.2011 18:000 
30   02.02.2011 18:150 
31   02.02.2011 18:300 
32   02.02.2011 18:450 
33   02.02.2011 19:000 
34   02.02.2011 19:150 
35   02.02.2011 19:300 
36   02.02.2011 19:450 
37   02.02.2011 20:000 
38   02.02.2011 20:150 
39   02.02.2011 20:300 
40   02.02.2011 20:450 
41   02.02.2011 21:000 
42   02.02.2011 21:150 
43   02.02.2011 21:300 
44   02.02.2011 21:450 
45   02.02.2011 22:000 
46   02.02.2011 22:150 
47   02.02.2011 22:300 
48   02.02.2011 22:450 
49   02.02.2011 23:000 
50   02.02.2011 23:150 
51   02.02.2011 23:300 
52   02.02.2011 23:450 
53   03.02.2011 00:000 
54   03.02.2011 00:150 
55   03.02.2011 00:300 
56   03.02.2011 00:450 
57   03.02.2011 01:000 
58   03.02.2011 01:150 
59   03.02.2011 01:300 
60   03.02.2011 01:450 
61   03.02.2011 02:000 
62   03.02.2011 02:150 
63   03.02.2011 02:300 
64   03.02.2011 02:450 
65   03.02.2011 03:000 
66   03.02.2011 03:150 
67   03.02.2011 03:300 
68   03.02.2011 03:450 
69   03.02.2011 04:000 
70   03.02.2011 04:150 
71   03.02.2011 04:300 
72   03.02.2011 04:450 
73   03.02.2011 05:000 
74   03.02.2011 05:150 
75   03.02.2011 05:300 
76   03.02.2011 05:450 
77   03.02.2011 06:000 
78   03.02.2011 06:150 
79   03.02.2011 06:300 
80   03.02.2011 06:450 
81   03.02.2011 07:000 
82   03.02.2011 07:15##<-- Signalaufruf (60%)
83   03.02.2011 07:30##<-- Signalaufruf (100%)


Excel Jeanie Html
Heinz Schweigert
.


Verfasst am:
16. Mai 2011, 01:27
Rufname: Heinz


AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Hallo

Und so wie die eingestellte Tabelle soll dann das Ergebnis aussehen?

Dann stell doch mal deinen Code hier ein, mit dem du die Zeitintervalle erzeugst, das sollte doch schon die halbe Miete sein Wink

Grüße Heinz
TwoCubed
Excel-Kenner mit (geringer) VBA-Erfahrung


Verfasst am:
16. Mai 2011, 01:51
Rufname:

AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Die Zeitwerte werden abgerundet und in vollen viertel Stunden angegeben. Das ist notwendig, da ein Stromzähler alle 15 Minuten halt einen Wert ausspuckt. Diese Werte werden dann weiterverarbeitet, was alles kein Problem ist. Das Problem ist, dass für gewisse Werte eine "Deckelung" greift, wenn ein Wert größer wird als der Wert, der mit der entsprechenden Prozentstufe verrechnet wird...

Die Tabelle soll nachher so aussehen wie oben (die Prozentstufen und rauten hab ich per Hand eingetragen, diese sollen automatisch erzeugt werden)

Um die korrekte Anzahl an Viertel-Stunden Werten auszuspucken habe ich folgende Formel benutzt:
Code:

=AUFRUNDEN(((B7*1440)/15);0)-ABRUNDEN(((B6*1440)/15);0)


Wobei in B6 die Anfangszeit und in B7 die Endzeit der Regelung steht. Die dabei entstehende Zahl wird in VBA als Countervariable benutzt, um die dynamische Tabelle zu erzeugen, in der die Zeitintervalle stehen. Die Prozedur sieht so aus:
Code:

Sub p_ist_zeiten()
    With Worksheets("Eingabe")
        .Cells(39, 29).Interior.Color = 49407
        .Cells(39, 29).Locked = False
        .Cells(39, 28).NumberFormat = "dd/mm/yyyy hh:mm"
        .Cells(39, 28).FormulaR1C1 = "=ROUNDDOWN(R6C2 * 24 * 60 / 15, 0) * 15 / 24 / 60"
        n = Range("B2").Value
        Dim i As Integer
        For i = 1 To n - 1
            .Cells(39 + i, 29).Interior.Color = 49407
            .Cells(39 + i, 28).NumberFormat = "dd/mm/yyyy hh:mm"
            .Cells(39 + i, 28).FormulaR1C1 = "=ROUND(R[-1]C + TIME(0,15,0))"
        Next
    End With
End Sub


Es wird also nur der erste Wert berechnet und dann für i = 1 bis n-1 jeweils 15 minuten auf die Zeit addiert. n ist hier die Anzahl der viertel Stunden innerhalb der Gesamtzeit.

Ich kann leider nicht die ganze Mappe hochladen (zumal ich auch noch nicht die Berechtigung habe).
Heinz Schweigert
.


Verfasst am:
16. Mai 2011, 14:25
Rufname: Heinz

AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Hallo TwoCubed

Also mit deinem Code komm ich irgendwie nicht weiter Twisted Evil

Hab das jetzt mal neu gestaltet. Das Folgende berechnet alles, einschliesslich der Anfangszeit auf ganze 15 Minuten "gerundet", und gibt die zugehörigen Prozentstufen aus. Sollte es zumindest und in Bezug auf dein eingestelltes Ergebnis stimmt das Ergebnis auch. Test mal selber, bitte:
Code:
Option Explicit

Sub Get_List()
Dim vntstart As Variant
Dim arr As Variant
Dim i As Integer, s As Integer
Dim n As Long

Const TimeConst As String = "00:15:00"

With Sheets("Tabelle1")
    .Range("D2:E" & .Cells(Rows.Count, 4).End(xlUp).Row + 1).ClearContents
    arr = .Range("A3:B" & .Cells(Rows.Count, 1).End(xlUp).Row)
    vntstart = arr(1, 1)
   
        Do_start_time vntstart, TimeConst
   
    n = 2
    For i = 2 To UBound(arr, 1)
        s = 1
        n = n + 1
        vntstart = vntstart + TimeValue(TimeConst)
        .Cells(n, 4) = vntstart
        .Cells(n, 5) = "##"
        Do While CDbl(vntstart) + TimeValue(TimeConst) < CDbl(arr(i, 1)) - TimeValue(TimeConst)
            n = n + 1
            s = s + 1
            vntstart = vntstart + TimeValue(TimeConst)
            .Cells(n, 4) = vntstart
            If s < 3 Then
                .Cells(n, 5) = "##"
            Else
                .Cells(n, 5) = arr(i - 1, 2)
            End If
        Loop
    Next i
End With
   
End Sub
Sub Do_start_time(vntstart As Variant, TimeConst As String)
Dim vnttime As Variant
Dim vntdate As Variant

    vntdate = DateValue(vntstart)
    vnttime = TimeValue(vntstart)
    vntstart = 0
   
    Do While vntstart <= vnttime - TimeValue(TimeConst)
        vntstart = vntstart + TimeValue(TimeConst)
    Loop
   
    If TimeValue(vntstart + TimeValue(TimeConst)) > vnttime Then
        vntstart = vntdate + vntstart - TimeValue(TimeConst)
    Else
        vntstart = vntdate + vntstart
    End If

End Sub


Der Code passt auf den Tabellenaufbau des eingestellten Beipiels.

Grüße Heinz
TwoCubed
Excel-Kenner mit (geringer) VBA-Erfahrung


Verfasst am:
16. Mai 2011, 15:23
Rufname:


AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Hallo!

Ja, ich merke gerade, dass es gestern spät wurde und ich wenig Sinnvolles geschrieben hatte Smile

Die Angaben, die ich im 2. Post gemacht habe, bezogen sich auf das eigentlich Blatt... die Tabelle im OP ist nur ein Beispiel. Dein Code sieht ja schon etwas professioneller aus, ich blicke da derzeit jedoch noch nicht durch. Ich werde das ganze mal austesten, sobald ich Feierabend habe! Funktioniert dein Code denn auch, wenn ich mehrere Zeiten und Prozentstufen eintrage (Also in Spalten A und B noch mehr Daten eintragen)?

Ich bedanke mich auf jeden Fall schon recht herzlich! Ich würde mich freuen, wenn du Zeit und Lust hättest einige Kernpunkte deines Codes zu erläutern, da ich noch VBA-Anfänger bin. Ich habe nämlich bislang immer dynamische Tabellen mittels Countervariablen erzeugt und bearbeitet, was natürlich nach einer Weile recht unübersichtlich wird, bzw. vermutlich auch wahnsinnig langsam ist. Ein Paar Erklärungen zu deiner Lösung würde vermutlich auch in anderen Bereichen meiner Tabelle was bringen Smile

Gruß,

Shane
Heinz Schweigert
.


Verfasst am:
16. Mai 2011, 21:13
Rufname: Heinz

AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Hallo Shane

Der Code funktioniert vollautomatisch, heißt dass er
  • die Eingabedaten bis zur letzten Eintragung in Spalte A bearbeitet
  • alte Daten im Ausgabebereich löscht

Sollte dein Eingabebereich mehr als 32767 Zeilen umfassen mußt du i als long deklarieren, da dann integer nicht mehr ausreicht. Sollte die Ausgabe die max. zur Verfügung stehenden Zeilen deines Sheets überschreiten läuft der Code in einen Fehler.

Falls du ein anderes Zeitintervall als 15 Minuten einstellen willst, dann die Zeitkonstante anpassen.

Und so funktionierts (grob):
Der Zeitwert in Zelle A3 ist Startzeit. Über die Unterprozedur wird einfach über eine Do while Schleife die Zeit solange um das Intervall erhöht, bis die Startzeit erreicht ist.
Im Anschluß wird für jede Eintragung in der Eingabe (i-Schleife) eine Doppelraute zur Zeit ausgegeben, und über eine neue Do while Schleife die Zeitintervalle und zugehörigen Prozente solange weitergeschrieben, bis ein neuer Eintrag in der Eingabe vorhanden ist. Das ganze wird solange wiederholt bzw. fortgeführt bis alle Eintragungn aus der Eingabe abgearbeitet sind. Die Zählervariable n läuft dabei nur mit um ohne Abfrage nach der zuletztbeschriebenen Zeile die Eintragung im Tabellenblatt vornehmen zu können.

Die Variable s dient dazu im "Folgezeitintervall" die Doppelraute einzutragen.

Hier noch der kommentierte Code:
Code:
Option Explicit

Sub Get_List()
Dim vntstart As Variant
Dim arr As Variant
Dim i As Integer, s As Integer
Dim n As Long

Const TimeConst As String = "00:15:00" 'Zeitkonstante (hier 15 Minuten kann verändert werden)

With Sheets("Tabelle1") 'Tabellenblattnamen ggf. anpassen
    'alte Ergebnisse löschen
    .Range("D2:E" & .Cells(Rows.Count, 4).End(xlUp).Row + 1).ClearContents
    'Eingabe in Array speichern, dynamisch nach Länge der Eintragungen
    arr = .Range("A3:B" & .Cells(Rows.Count, 1).End(xlUp).Row)
    'Übergabe Starttermin
    vntstart = arr(1, 1)
   
        'Starttermin auf 15 Minuten gerundet ermitteln
        Do_start_time vntstart, TimeConst
   
    'Zähler für Zeilen zur Ergebnisausgabe
    n = 2
    'Schleife durch vorhandene Eingaben
    For i = 2 To UBound(arr, 1)
        s = 1 'Zähler für Rauteneintrag
        n = n + 1
        'ersten Zeitwert je Eingabe immer mit "##"
        vntstart = vntstart + TimeValue(TimeConst)
        .Cells(n, 4) = vntstart
        .Cells(n, 5) = "##"
        'schreibe Zeitwerte mit Prozentangabe solange bis neuer Eingabewert
        Do While CDbl(vntstart) + TimeValue(TimeConst) < CDbl(arr(i, 1)) - TimeValue(TimeConst)
            n = n + 1
            s = s + 1
            vntstart = vntstart + TimeValue(TimeConst)
            .Cells(n, 4) = vntstart
            If s < 3 Then 'Folgezeitintervall mit "##"
                .Cells(n, 5) = "##"
            Else 'ansonsten Prozentwert
                .Cells(n, 5) = arr(i - 1, 2)
            End If
        Loop
    Next i
End With
   
End Sub
Sub Do_start_time(vntstart As Variant, TimeConst As String)
Dim vnttime As Variant
Dim vntdate As Variant

    vntdate = DateValue(vntstart)
    vnttime = TimeValue(vntstart)
    vntstart = 0 'Startzeit auf 0 setzen
   
    'erhöhe Startzeit um Zeitkonstanste bis Startzeit erreicht ist
    Do While vntstart <= vnttime - TimeValue(TimeConst)
        vntstart = vntstart + TimeValue(TimeConst)
    Loop
   
    'Aufbereitung Startzeit
    If TimeValue(vntstart + TimeValue(TimeConst)) > vnttime Then
        vntstart = vntdate + vntstart - TimeValue(TimeConst)
    Else
        vntstart = vntdate + vntstart
    End If

End Sub


Grüße Heinz
TwoCubed
Excel-Kenner mit (geringer) VBA-Erfahrung


Verfasst am:
17. Mai 2011, 11:13
Rufname:

AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Oh wow!

Wahnsinn, vielen Dank für de ausfürhliche Hilfe! Das hätte ich mir nicht besser erhoffen können Very Happy Ich denke das wird mir auch bei den restlichen Sachen in meiner Tabelle eine riesige Hilfe sein!

Gruß,

Shane
TwoCubed
Excel-Kenner mit (geringer) VBA-Erfahrung


Verfasst am:
19. Mai 2011, 22:23
Rufname:

AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Ich muss leider doch noch mal eine kleine Frage stellen.

Manchmal ist das letzte Intervall nicht richtig, d.h. die Tabelle hört mit einem Wert zu wenig auf. Das passiert beispielsweise, wenn man als Intervall 00:10:00 nimmt... das letzte Intervall ist denn 7:20. Dabei liegt der eingegeben Endwert bei 7:31. Hier müsste korrekterweise als letztes Intervall 7:30 stehen... Das passiert auch für die 15 Minuten Intervalle, wenn gewisse Start/Endwerte eingegeben werden.

Wie bekomme ich das korrigiert? Ich vermute da muss irgendwo noch eine If-then-else abfrage erstellt werden. Ich hatte gehofft es langt in der Prozedur Do_start_time bei der Else Bedingung hinten ein "+ TimeValue(TimeConst)" dranzuhängen, was leider nicht so war.

Vielen Dank schonmal im Voraus!

Shane
Heinz Schweigert
.


Verfasst am:
19. Mai 2011, 22:51
Rufname: Heinz

AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Hallo Shane

Hm, da hast du recht da fehlt dann ne Raute Sad

Tell me, seh ich das richtig, dass das letzte Zeitintervall immer mit einer Raute endet? Wenn nicht, kannst du nen Datensatz posten wie das dann aussieht?

Grüße Heinz
TwoCubed
Excel-Kenner mit (geringer) VBA-Erfahrung


Verfasst am:
19. Mai 2011, 23:02
Rufname:

AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Doch, das stimmt... das letzte Intervall ist im Prinzip ja die Signalstufe auf 100%, da erfolgt auch keine Deckelung der dazugehörigen Werte (dafür sind die Rauten nachher...). Wichtig ist aber, dass dieses Intervall vorhanden ist, denn der Benutzer muss für jedes Intervall Werte eingeben (in diesem Fall Windgeschwindigkeiten), die weiter verrechnet werden (u.a. mit einem sverweis auf eine Leistungskennlinie und mit den Prozentstufen).

Die korrekten Intervalle hatte ich damals hinbekommen, indem ich die Anfangszeit abgerundet und die Endzeit aufgerundet habe (auf je volle 15 bzw. 10 minuten) dann die Differenz dieser Zeiten durch eben 15 minuten/10 minuten geteilt. Dafür kam dann eine Zahl heraus, die meine benötigte Anzahl an Zeilen darstellen sollte. Das hat zwar gut geklappt, jedoch ist es damit nicht möglich eine dynamische Eingabetabelle zu verarbeiten.

Deine Variante finde ich auch wesentlich flexibler und interessanter (habe alleine daraus schon eine ganze Menge hinzugelernt Smile )

Edit:
Es kann übrigens auch die 100 eingetragen werden, statt einer Raute, falls das was bringen sollte!
Heinz Schweigert
.


Verfasst am:
19. Mai 2011, 23:19
Rufname: Heinz

AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Hallo Shane

Verantwortlich an dem Fehlen des letzten Eintrags (bei ungünstiger Konstellation von TimeConst), ist dieser Teil:
Code:
Do While CDbl(vntstart) + TimeValue(TimeConst) < CDbl(arr(i, 1)) - TimeValue(TimeConst)

Diese Rechnerei sieht unsinnig aus, ist aber notwendig, weil der Code sich sonst an anderer Stelle verhaspelt.

Da der Fehler nur am Ende auftreten kann, wenn kein weiterer Eintrag mehr in arr vorhanden ist, wäre mein Vorschlag, einfach am Ende der i-Schleife eine If-Abfrage anzuhängen, die prüft ob die Zeiten auch vollständig vorhanden sind:
Code:
.
.
.
    Next i
    If .Cells(n, 4) + TimeValue(TimeConst) < CDbl(arr(UBound(arr, 1), 1)) Then
        vntstart = vntstart + TimeValue(TimeConst)
        .Cells(n + 1, 4) = vntstart
        .Cells(n + 1, 5) = "##"
    End If
   
End With

End Sub


Da das letzte Zeitintervall immer mit einer Raute endet, kann man diese dann auch ohne irgendwelche Prüfung zusammen mit dem letzen Intervall eintragen.

Grüße Heinz
Gast



Verfasst am:
20. Mai 2011, 00:23
Rufname:


AW: Werte innerhalb Zeitintervalle eintragen lassen - AW: Werte innerhalb Zeitintervalle eintragen lassen

Nach oben
       Version: Office 2007

Sauber, das funktioniert!

Vielen Dank nochmal! Ich hoffe es tauchen keine weiteren Schwierigkeiten mehr auf Very Happy

Einen schönen Abend noch!

Gruß,

Shane
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Werte aus Liste raussuchen 8 KARL 1217 30. Apr 2014, 18:10
Holger1968 Werte aus Liste raussuchen
Keine neuen Beiträge Excel Formeln: Mehrere Werte aus einer Zelle einzeln darstellen 2 Gast 1113 24. Mai 2005, 11:25
Gast Mehrere Werte aus einer Zelle einzeln darstellen
Keine neuen Beiträge Excel Formeln: Werte von einer Tabelle in eine andere Übernehmen 11 Blue_Whirlwind 2311 22. Mai 2005, 17:18
Blue_Whirlwind Werte von einer Tabelle in eine andere Übernehmen
Keine neuen Beiträge Excel Formeln: vertikale ausgabe einer anzahl werte 7 grim reaper 688 21. Apr 2005, 19:14
Detlef 42 vertikale ausgabe einer anzahl werte
Keine neuen Beiträge Excel Formeln: Alle Werte einer Spalte zusammenzählen 4 Gaaast 1109 13. Apr 2005, 22:14
Scelina Alle Werte einer Spalte zusammenzählen
Keine neuen Beiträge Excel Formeln: werte aus trendlinie übernehmen 3 Gast 7577 06. Apr 2005, 18:19
fl618 werte aus trendlinie übernehmen
Keine neuen Beiträge Excel Formeln: Werte aus einer Tabelle nach mehreren Kriterien auswerten 3 Daniel 2901 07. März 2005, 14:15
Hübi Werte aus einer Tabelle nach mehreren Kriterien auswerten
Keine neuen Beiträge Excel Formeln: Werte aus 2. Datei/Tabellenblatt übertragen //Zusatzfrage 6 original-m 1708 25. Feb 2005, 11:25
Sigrid Werte aus 2. Datei/Tabellenblatt übertragen //Zusatzfrage
Keine neuen Beiträge Excel Formeln: Zelle im 14 Tage Rhythmus automatisch generieren lassen 2 MrMr 2413 21. Feb 2005, 07:55
AnBo Zelle im 14 Tage Rhythmus automatisch generieren lassen
Keine neuen Beiträge Excel Formeln: Werte vergleichen und übernehmen 8 10823berlin 2409 08. Feb 2005, 20:40
rainberg Werte vergleichen und übernehmen
Keine neuen Beiträge Excel Formeln: Vergleichen 2 Tabellen mit ausgabe der fehlenden werte 1 Julie 2923 25. Jan 2005, 16:53
fridgenep Vergleichen 2 Tabellen mit ausgabe der fehlenden werte
Keine neuen Beiträge Excel Formeln: Anzahl identischer Werte 2 Toledo 2627 04. Dez 2004, 01:19
Toledo Anzahl identischer Werte
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: CSS Forum