Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Wie ist die Kalenderwoche des 31.12.2012?
Gehe zu Seite 1, 2  Weiter
zurück: Outlook Kontakte - Geburtsdatum - Objekt ist ungültig! weiter: Feldwert des zuletzt eingegebenen Datensatzes Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
JMalberg
Es wird so langsam sinnig ...


Verfasst am:
02. Jan 2012, 12:06
Rufname:
Wohnort: Saarbrücken

Wie ist die Kalenderwoche des 31.12.2012? - Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Ein gutes neues Jahr 2012!

Der 31.12.2012 ist ein Montag, aber welche Kalenderwoche ist es den jetzt?

Bisher nutze ich diese Funktion um die Wochennummer zu errechnen:
Code:
Public Function Week(AnyDate As Date) As Byte
'nach ISO 8601-Regel  http://de.wikipedia.org/wiki/ISO_8601#Zusammenfassung
'   Wochenanfang immer Montag, Erste Woche wenn der erste Januar-Donnerstag
    Week = DatePart("ww", AnyDate, vbMonday, vbFirstFourDays)
    If Week > 52 Then
        If Format(AnyDate + 7, "ww", vbMonday, vbFirstFourDays) = 2 Then
            Week = 1
        End If
    End If
' dauert länger
'    If Week > 52 And Format(AnyDate + 7, "ww", vbMonday, vbFirstFourDays) = 2 Then Week = 1
End Function
Diese ergibt auch DIN-gerecht für den 31.12.2012 die Woche 2013-01.

Dummerweise verschwinden dann alle Vorgänge/Buchungen des 31.12.2012 dann aber aus dem Jahr 2012. Für den 31.12.2012 muss ich sie aber noch in einer Woche 2012-53 haben.

_________________
Gruß
Jürgen

Der Unterschied zwischen Theorie und Praxis ist in der Praxis größer als in der Theorie!
Marsupilami72
Office-VBA-Programmierer


Verfasst am:
02. Jan 2012, 12:25
Rufname:
Wohnort: Goslar


AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Die Antwort ist naheliegend: um alle Buchungen eines Jahres zu erfassen, darfst Du nicht nach der KW filtern, sondern nur nach dem Datum.
Eine 53.KW 2012 würde ja auch alle Tage bis zum 6.1.2013 enthalten.

_________________
Gruß,
Martin

Bitte keine Fragen per PN - dafür ist das Forum da!
JMalberg
Es wird so langsam sinnig ...


Verfasst am:
02. Jan 2012, 12:50
Rufname:
Wohnort: Saarbrücken

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Stimmt, die Fragestellung ist nicht ganz korrekt.

Ich brauche zwingend auch bei Kalenderwoche eine Jahresabgrenzung unabhängig von der DIN8601.

_________________
Gruß
Jürgen

Der Unterschied zwischen Theorie und Praxis ist in der Praxis größer als in der Theorie!
Bitsqueezer
Office-VBA-Programmierer


Verfasst am:
02. Jan 2012, 13:28
Rufname:

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Hallo,

genaugenommen gibt Dir Deine Funktion lediglich einen Byte-Wert zurück, also nur die Wochennummer. Von daher liegt das Problem nicht hier in dieser Funktion, sondern da, wo Du die Wochennummer mit der Jahreszahl zu einem String verknüpfst.

Gruß

Christian
JMalberg
Es wird so langsam sinnig ...


Verfasst am:
02. Jan 2012, 13:38
Rufname:
Wohnort: Saarbrücken


AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Jepp, es ist das Jahr das Probleme machte.

Mit der Funktion von hier ist es soweit korrekt, wenn Jahr und Woche ausgegeben werden sollen.
Berechnung von Kalenderwochen (DIN 1355)
Code:
Function Week(AnyDate As Date, Optional IsYearWeek As Boolean) As Long
    Dim lngJahr As Long
    Dim intWocheTmp As Integer
    Dim bytWoche As Byte
   
    If Not IsDate(AnyDate) Then Week = Null: Exit Function
    If IsMissing(IsYearWeek) Then IsYearWeek = False
    lngJahr = Year(AnyDate)
    bytWoche = CByte(Format(AnyDate, "ww", vbMonday, vbFirstFourDays))
    intWocheTmp = Int((AnyDate - DateSerial(Year(AnyDate), 1, 1) + ((Weekday(DateSerial(Year(AnyDate), 1, 1)) + 1) Mod 7) - 3) / 7) + 1
    If intWocheTmp = 0 Then
        bytWoche = Format(DateSerial(lngJahr - 1, 12, 31), "ww", vbMonday, vbFirstFourDays)
        If bytWoche >= 52 Then
            lngJahr = lngJahr - 1
        End If
      ElseIf intWocheTmp > 52 And (Weekday(DateSerial(lngJahr, 12, 31)) - 1) Mod 7 <= 3 Then
        If Format(AnyDate + 7, "ww", vbMonday, vbFirstFourDays) = 2 Then
            bytWoche = 1
        End If
        If bytWoche = 1 Then
            lngJahr = lngJahr + 1
        End If
    End If
    If IsYearWeek = True Then
        Week = lngJahr * 100 + bytWoche
      Else
        Week = bytWoche
    End If
End Function

_________________
Gruß
Jürgen

Der Unterschied zwischen Theorie und Praxis ist in der Praxis größer als in der Theorie!
Bitsqueezer
Office-VBA-Programmierer


Verfasst am:
02. Jan 2012, 14:23
Rufname:

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Hallo,

oder man erledigt das ganze mit einem Einzeiler...Wink:
Code:
?Year ("31.12.2011") & DatePart("ww", "31.12.2011", , vbFirstFourDays)

Gruß

Christian
JMalberg
Es wird so langsam sinnig ...


Verfasst am:
02. Jan 2012, 15:35
Rufname:
Wohnort: Saarbrücken

Re: AW: Wie ist die Kalenderwoche des 31.12.2012? - Re: AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

@Bitsqueezer

... und genau dieser Einzeiler ergibt eine falsche Woche für 31.12.12 mit 2012-1 statt richtig 2013-1. Es ist eben doch nicht so einfach;) leider.

_________________
Gruß
Jürgen

Der Unterschied zwischen Theorie und Praxis ist in der Praxis größer als in der Theorie!
Bitsqueezer
Office-VBA-Programmierer


Verfasst am:
02. Jan 2012, 16:11
Rufname:

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Hallo,

Du wolltest doch das Vorjahr ausgegeben haben. Wenn es denn die Woche 53 sein soll, dann ersetze den letzten Parameter einfach gegen vbFirstFullWeek, dann hast Du 2012 53.

Erscheint mir aber so oder so als ob hier bei den Daten anzusetzen wäre. Entweder hast Du ein ISO-Datum, dann ist 2013/1 richtig, oder eben das US Format, dann ist 2012/53 richtig.

In beiden Fällen würdest Du z.B. ein Endlosformular mit dem entsprechenden Jahr/Woche-Feld haben und könntest dann entweder nach 2013/1 oder nach 2012/53 filtern.

Aber auch für ISO Woche mit Jahr hätte ich eine bedeutend kürzere Variante:
Code:
Public Function fnISOWeekYear(AnyDate As Date) As String
    Dim strISOWeek As String
    Dim D As Long
   
    D = DateSerial(Year(AnyDate - Weekday(AnyDate - 1) + 4), 1, 3)
    strISOWeek = Right("00" & Int((AnyDate - D + Weekday(D) + 5) / 7), 2)
    fnISOWeekYear = IIf(Month(AnyDate) = 12 And Val(strISOWeek) = 1 _
                      , Year(AnyDate) + 1 _
                      , Year(AnyDate)) & strISOWeek
End Function
Gruß

Christian

PS.: Die Berechnung der ISO-Woche habe ich konvertiert aus dieser Seite: Berechnung der Kalenderwoche
JMalberg
Es wird so langsam sinnig ...


Verfasst am:
06. Jan 2012, 18:38
Rufname:
Wohnort: Saarbrücken

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

JMalberg am 02. Jan 2012 um 22:07 hat folgendes geschrieben:
Auch nicht schlecht. Smile

Ich habe die Geschichte nochmal durchdacht:
Die Kalenderwoche (nach DIN/ISO) wird anhand von Tagesdatum jetzt korrekt berechnet und demnach ist eben die Kalenderwoche 31.12.2012 korrekterweise die 1.KW 2013. Diese Kalenderwochen werden aber nur für Auswertungen und Wochendarstellungen benutzt.
Wird nun wirklich eine Jahresabgrenzung benötigt muss eben noch zusätzlich das Tagesdatum mit berücksichtigt werden. Dies ist aber zumindest in meinen DBs sehr selten der Fall.

Trotzdem Danke für die Hilfe und Hinweise: Sie haben noch ein paar Fehler ausgemerzt.

Es wäre so schön gewesen, hätte letzteres gestimmt ... Smile

Leider ist die Funktion "fnISOWeekYear" doch nicht korrekt.
Code:
Sub testYearWeek()
    Dim dt As Date
    Dim intJahr As Integer
    Dim dtMin, dtMax As Date
    Dim lngA, lngB, lngC As Long
   
    Debug.Print "=============================================================="
    Debug.Print "Jahr", "Datum", "YearWeek", "ISOWeekYear", "DateTest"
    For intJahr = 2011 To 2018
        Debug.Print "Jahr:"; intJahr
        dtMin = DateSerial(intJahr, 12, 30)
        dtMax = DateSerial(intJahr + 1, 1, 4)
        For dt = dtMin To dtMax
'            Debug.Print Year(dt),
'            Debug.Print Format(dt, "ddd dd.mm.yyyy"),
'            Debug.Print Week(dt, True), fnISOWeekYear(dt)
            lngA = YearWeek(dt)
            lngB = fnISOWeekYear(dt)
'            lngC = 0
            Debug.Print Year(dt), Format(dt, "ddd dd.mm.yyyy"), lngA, lngB, (lngA = CLng(lngB))
        Next dt
    Next intJahr
End Sub

Public Function Week(AnyDate As Date, Optional IsYearWeek As Boolean) As Long
    Dim bytWeek As Byte
    Dim lngFirstThursday As Long
    Dim dtAnyDateThursday As Date
    Dim dtFirstThursday As Date
   
' überflüssig    If Not IsDate(AnyDate) Then Week = Null: Exit Function
    If IsMissing(IsYearWeek) Then IsYearWeek = False
    dtAnyDateThursday = AnyDate - Weekday(AnyDate - 1) + 4
    lngFirstThursday = DateSerial(Year(dtAnyDateThursday), 1, 3)
    dtFirstThursday = CDate(lngFirstThursday)
    bytWeek = Int((AnyDate - lngFirstThursday + Weekday(lngFirstThursday) + 5) / 7)
    If IsYearWeek = True Then
        If Month(AnyDate) = 12 And bytWeek = 1 Then
            Week = (Year(AnyDate) + 1) * 100 + bytWeek
          Else
            If Weekday(AnyDate) > vbSunday And Weekday(AnyDate) < vbThursday Then
                Week = (Year(AnyDate)) * 100 + bytWeek
              Else
                Week = (Year(dtFirstThursday)) * 100 + bytWeek
            End If
        End If
      Else
        Week = bytWeek
    End If
End Function

Public Function fnISOWeekYear(AnyDate As Date) As String
    Dim strISOWeek As String
    Dim D As Long
   
    D = DateSerial(Year(AnyDate - Weekday(AnyDate - 1) + 4), 1, 3)
    strISOWeek = Right("00" & Int((AnyDate - D + Weekday(D) + 5) / 7), 2)
    fnISOWeekYear = IIf(Month(AnyDate) = 12 And Val(strISOWeek) = 1 _
                      , Year(AnyDate) + 1 _
                      , Year(AnyDate)) & strISOWeek
End Function
Testet man es mit "testYearWeek" so kommen in einigen Jahreswechseln falsche Jahreszahlen heraus:
- 2011/2012
- 2015/2016
- 2016/2017

Die Funktion "Week" ergibt jetzt die richtige Kalenderwoche mit korrekter Jahreszahl.

Hat jemand noch eine Idee "Week" noch kompakter und performanter zu machen?

_________________
Gruß
Jürgen

Der Unterschied zwischen Theorie und Praxis ist in der Praxis größer als in der Theorie!
derArb
getting better


Verfasst am:
06. Jan 2012, 18:59
Rufname: derArb
Wohnort: Berlin

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Hallo,
siehe: Kalenderwoche und Jahr ausgeben

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.
JMalberg
Es wird so langsam sinnig ...


Verfasst am:
06. Jan 2012, 19:39
Rufname:
Wohnort: Saarbrücken

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Danke derArb, beide Funktionen liefern die gleichen Ergebnisse. Smile

Da ich diese Kalenderwoche sehr oft einsetze bei meist mehr als 200.000 Datensätze, geht es jetzt noch darum sie möglichst performant aufzubauen.

_________________
Gruß
Jürgen

Der Unterschied zwischen Theorie und Praxis ist in der Praxis größer als in der Theorie!
derArb
getting better


Verfasst am:
06. Jan 2012, 19:46
Rufname: derArb
Wohnort: Berlin

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Hallo,
ich vertraue da auf den Profi TommyK
Meine Datensätze bewegen sich allerdings nur um die 100 000

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.
Bitsqueezer
Office-VBA-Programmierer


Verfasst am:
07. Jan 2012, 15:11
Rufname:

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Hallo Jürgen,

Du hast recht, ich hatte die Jahresberechnung nicht intensiv getestet, die habe ich der (korrekten) Wochenberechnung nur schnell hinzugefügt, aber nicht intensiv genug darüber nachgedacht.

Die Funktion "Week", die Du zuletzt gepostet hast, bedient sich der exakt gleichen Berechnung der Wochennummer, nur die Jahreszahl wird richtiger ermittelt. Allerdings enthält die Funktion auch Überflüssiges, wenn sie sowieso nur für Jahr UND Woche eingesetzt werden soll. Die Zeile mit "IsMissing" ist darüber hinaus falsch, weil die Funktion "IsMissing" nur funktioniert, wenn der optionale Parameter vom Typ "Variant" ist (weil sie dann auf Nothing/Null testen kann, was mit allen anderen Datentypen nicht geht). Bei allen anderen Datentypen setzt man einfach einen Standardwert für den optionalen Parameter, also z.B. "Optional IsYearWeek As Boolean = False" und spart sich die IsMissing-Zeile, die auch nur einen Default-Wert setzt.

Läßt man diese Option ganz weg und kürzt überflüssige Variablen, sieht die Funktion dann so aus (und besteht auch Deinen Test):
Code:
Public Function fnISOWeekYear(AnyDate As Date) As Long
    Dim bytWeek As Byte
    Dim lngFirstThursday As Long
   
    lngFirstThursday = DateSerial(Year(AnyDate - Weekday(AnyDate - 1) + 4), 1, 3)
    bytWeek = Int((AnyDate - lngFirstThursday + Weekday(lngFirstThursday) + 5) / 7)

    If Month(AnyDate) = 12 And bytWeek = 1 Then
        fnISOWeekYear = (Year(AnyDate) + 1) * 100 + bytWeek
      Else
        If Weekday(AnyDate) > vbSunday And Weekday(AnyDate) < vbThursday Then
            fnISOWeekYear = (Year(AnyDate)) * 100 + bytWeek
          Else
            fnISOWeekYear = (Year(CDate(lngFirstThursday))) * 100 + bytWeek
        End If
    End If
End Function
Ich würde auch keine selbstgeschriebene Funktion "Week" nennen, weil da immer die Gefahr besteht, mit irgendwelchen Schlüsselwörtern zu kollidieren (wenn nicht jetzt, dann evtl. in Zukunft).

Ich denke, viel kürzer kann man es nicht machen. Es lohnt hier nicht, das in IIf umzuwandeln, weil es dazu zu viele Ifs sind, denn IIf wird immer komplett ausgewertet, daher würde ein IIf hier wieder Performance kosten (und es ist so ja auch übersichtlicher).

Gruß

Christian

PS.: Was ich nicht getestet habe, man aber auch beachten sollte: Je nach Windows-Systemeinstellung ("Regional Settings") könnte es sein, daß ein anderer Wochentag als erster der Woche eingestellt ist, abhängig davon könnte die Funktion "WeekDay" einen anderen Wert ausgeben, vbSunday usw. sind aber Konstanten, die sich m.W. nicht mit den Systemeinstellungen ändern. Man müßte also testen, ob die Funktion in internationalen Umgebungen standhält, wenn man die Funktion in internationalen Datenbanken verwenden möchte.
derArb
getting better


Verfasst am:
07. Jan 2012, 16:02
Rufname: derArb
Wohnort: Berlin

AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Hallo,
und da Bitsqueezer ebenfalls ein Profi ist, kannste dem auch vertrauen.
Ich hab halt irgendwann mal die TommyK-Version gefunden und da sie fuktioniert,
mich nicht mehr weiter gekümmert.

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.
Gast



Verfasst am:
07. Jan 2012, 17:19
Rufname:


AW: Wie ist die Kalenderwoche des 31.12.2012? - AW: Wie ist die Kalenderwoche des 31.12.2012?

Nach oben
       Version: (keine Angabe möglich)

Zitat:
Da ich diese Kalenderwoche sehr oft einsetze bei meist mehr als 200.000 Datensätze, geht es jetzt noch darum sie möglichst performant aufzubauen.
An der Stelle hilft regelmäßig eine Hilfstabelle, hier eine Kalendertabelle.

Eine solche Kalendertabelle würde fortlaufend alle Tage des benötigten Zeitraums enthalten, bei Bedarf in weiteren Feldern daraus berechnete Werte: Woche, Wochentag, Monat, Jahr, Quartal, verwendete bestimmte Formate daraus zur Gruppierung (alles herrlich unnormalisiert) - wobei man alle Felder darin indizieren würde.
Das "Verbot" der Speicherung von berechneten Werten trifft hier nicht zu, da man hier immer einen Datensatz insgesamt bzw. eher die gesamte Tabelle bei Bedarf neu berechnen würde. Eine Neuberechnung würde überdies nur wegen einer Zeitraumerweiterung bzw. -verschiebung notwendig, der Kalender selber hat sich ja seit 1582 (Gregorianischer Kalender) nicht mehr geändert. Man beachte: Es gibt auch Papierkalender, eine jeweilige Neuberechnung per VBA, z.B. das der heutige 7. Januar ein Samstag ist, ist verzichtbar mit einem Blick auf diesen Papierkalender.
Eine Hilfstabelle muss man zusätzlich etwas anders betrachten als eine Stammdatentabelle.

Großer Vorteil der Kalendertabelle: Die benötigten Werte müssen nicht jeweils pro Datensatz der eigenen Abfrage berechnet werden, sondern können indizierten Feldern entnommen werden.
Die Berechnung eines Wertes wie Kalenderwoche im SELECT-Teil einer Abfrage ist, abgesehen von dem etwas höheren Aufwand, noch ein kleineres Problem. Das eigentliche Problem besteht in der nachfolgenden Nutzung eines solchen berechneten Feldes: Für Maßnahmen wie Filtern, Gruppieren und Sortieren entfällt eine Indexnutzung und damit ein Haupt-Performancebringer, der, insbesondere bei größeren Datenmengen, dringend gebraucht wird.

Die genannte zusätzliche Tabelle würde man dann ersatzweise für die Berechnungen in die eigene(n) Abfrage(n) einbinden und dabei aufpassen, dass auch das verwendete Abfragedesign nicht die Indexnutzung nachträglich unterbindet = Standardaufgabe für einen Datenbankentwickler.
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tipps & Tricks: Kalenderwoche nach DIN1355 mit/ohne Jahreszahl 2 JMalberg 1506 08. Jul 2013, 12:52
JMalberg Kalenderwoche nach DIN1355 mit/ohne Jahreszahl
Keine neuen Beiträge Access Programmierung / VBA: Wochentag und Kalenderwoche wird falsch ermittelt 14 joem 179 13. Apr 2013, 18:03
JMalberg Wochentag und Kalenderwoche wird falsch ermittelt
Keine neuen Beiträge Access Tabellen & Abfragen: Frage zu Donkarls Geburtstagsliste 3.12 4 tonyitaliano 401 03. Nov 2011, 01:01
Gast Frage zu Donkarls Geburtstagsliste 3.12
Keine neuen Beiträge Access Programmierung / VBA: Kalenderwoche in Datum umwandeln in einer Abfrage 3 swisslanders 811 02. Sep 2011, 06:39
swisslanders Kalenderwoche in Datum umwandeln in einer Abfrage
Keine neuen Beiträge Access Programmierung / VBA: Abfrage Antworten nach Kalenderwoche gruppiert 1 69geissbock 1214 22. März 2011, 10:30
jb4cl Abfrage Antworten nach Kalenderwoche gruppiert
Keine neuen Beiträge Access Tabellen & Abfragen: Kalenderwoche mit führender Null? 3 Hochrheiner 1410 30. Nov 2010, 10:56
KlausMz Kalenderwoche mit führender Null?
Keine neuen Beiträge Access Tabellen & Abfragen: Kalenderwoche immer eine voraus 2 nakoda 288 21. Jul 2010, 12:37
nakoda Kalenderwoche immer eine voraus
Keine neuen Beiträge Access Programmierung / VBA: Anfangsdatum und Enddatum einer Kalenderwoche 8 Martha123 1712 21. Dez 2009, 08:28
Martha123 Anfangsdatum und Enddatum einer Kalenderwoche
Keine neuen Beiträge Access Tabellen & Abfragen: Probleme mit Umrechnung Datum in Kalenderwoche 2 Access_newbie111 1413 11. Apr 2009, 15:32
Access_newbie111 Probleme mit Umrechnung Datum in Kalenderwoche
Keine neuen Beiträge Access Tabellen & Abfragen: Einfügen einer Kalenderwoche! 2 Easy091981 3225 15. Feb 2008, 18:39
KlausMz Einfügen einer Kalenderwoche!
Keine neuen Beiträge Access Hilfe: Kalenderwoche von Datum, auch für Oracle SQL 1 Markos 12754 18. Jan 2008, 11:14
Gast Kalenderwoche von Datum, auch für Oracle SQL
Keine neuen Beiträge Access Tabellen & Abfragen: Problem mit Datum bzw. Kalenderwoche nach Jahreswechsel 14 Cinderella_2008 4138 16. Jan 2008, 10:17
Willi Wipp Problem mit Datum bzw. Kalenderwoche nach Jahreswechsel
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: CSS Forum