Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
eMail + Attachments per Makro ins Dateisystem speichern
zurück: PDF Anhänge (250'000 Stk) aus Email auf Festplatte kopieren weiter: Signatur des Users anfügen Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
RTausD
Excel-Anwender mit ersten Makro-Erfahrungen


Verfasst am:
20. Jan 2012, 17:39
Rufname:

eMail + Attachments per Makro ins Dateisystem speichern - eMail + Attachments per Makro ins Dateisystem speichern

Nach oben
       Version: Office 2010

Hallo

ich muss alle eMails in einem Outlook Verzeichnis in ein Windows Verzeichnis speichern. Natürlich könnte ich die einfach aus dem Outlook in den Windows Explorer ziehen. Dabei wird aber der Betreff zum Dateinamen und damit die chronologische Reihenfolge zerstört. Außerdem habe ich die Befürchtung, dass eMails mit gleichem Betreff sich gegenseitigen überschreiben.
Da hatte ich die Idee, den Betreff um Datum (im Format YYYY-MM-DD), Uhrzeit (im Format hh-mm-ss) und Absender (eMailadresse) zu erweitern.
Das von Hand zu machen scheidet auf Grund der Menge leider aus.

Weiterhin müssten Attachments (sofern sie enthalten sind) ebenfalls im Dateisystem gespeichert werden. Auch hier wäre eine derartige Erweiterung des Dateinamens notwendig.

Ich stelle mir das ungefähr so vor:
- Öffnen einer eMail in einem Ordner
- Ermittlung von Absenderadresse, Datum und Uhrzeit der eMail und Zuweisung im entsprechenden Format an eine Stringvariable
- Überprüfung auf Attachements
-Speicherung der Attachments unter Ergänzung des Dateinamens um den zuvor definierten String
- Entfernung der Attachments aus der eMail
- Speicherung der eMail (Dateiname = String + Betreff) im Windows Dateisystem
- Löschung der eMail aus dem Outlook-Ordner

Hat jemand Ideen, wie ich zumindest einen Teil dieser Abläufe automatisieren kann?

Vielen Dank im Voraus

Rolf

P.S.: Ich muss die ganzen Dateien dann noch alle chronologisch drucken. Aber das packe ich dann in eine andere Anfrage.
anne_1212
Neuling


Verfasst am:
03. Feb 2012, 18:36
Rufname:


AW: eMail + Attachments per Makro ins Dateisystem speichern - AW: eMail + Attachments per Makro ins Dateisystem speichern

Nach oben
       Version: Office 2010

Hallo,
ich nutze dafür das folgende Makro:


Code:

Private Const BIF_RETURNONLYFSDIRS = 1
Private Const BIF_DONTGOBELOWDOMAIN = 2
Private Const MAX_PATH = 512

Private Declare Function GetActiveWindow Lib "User32" () As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, _
                                                           ByVal lpBuffer As String) As Long
'appends lpString2 to lpString1
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" _
                               (ByVal lpString1 As String, ByVal lpString2 As String _
                               ) As Long
Private Type BrowseInfo
   hwndOwner       As Long
   pIDLRoot        As Long
   pszDisplayName  As Long
   lpszTitle       As Long
   ulFlags         As Long
   lpfnCallback    As Long
   lParam          As Long
   iImage          As Long
End Type

Public Function Browse_Directory() As String
   Dim lpIDList As Long
   Dim sBuffer As String
   Dim szTitle As String
   Dim tBrowseInfo As BrowseInfo
   Dim lnghwnd As Long
   On Error GoTo err_Browse_Directory
   lnghwnd = GetActiveWindow
   
   szTitle = "Test Browser"
   With tBrowseInfo
       .hwndOwner = lnghwnd
       .lpszTitle = lstrcat(szTitle, "")
       .ulFlags = BIF_RETURNONLYFSDIRS + BIF_DONTGOBELOWDOMAIN
   End With
   
   lpIDList = SHBrowseForFolder(tBrowseInfo)
   
   If (lpIDList) Then
       sBuffer = Space(MAX_PATH)
       SHGetPathFromIDList lpIDList, sBuffer
       sBuffer = Left(sBuffer, InStr(1, sBuffer, vbNullChar) - 1)
       Browse_Directory = sBuffer
   End If
exit_Browse_Directory:
   Exit Function
err_Browse_Directory:
   Resume exit_Browse_Directory
   Browse_Directory = ""
End Function


Sub test_Browse_Directory()
   Dim strPath As String
   strPath = Browse_Directory

   If strPath <> "" Then
      MsgBox "You chose '" & strPath & "'."
   Else
      MsgBox "nothing was chosen in browse box"
   End If
End Sub



Function VonSonderzeichenBereinigen(filename) As String
    'Die Zeichen \/:?*"<>| sind in Dateinamen nicht zulässig werden deshalb ersetzt durch:
    ersatz = "_"
   
    Dim zuErsetzendeZeichen(0 To 8) As String
    zuErsetzendeZeichen(0) = "\"
    zuErsetzendeZeichen(1) = "/"
    zuErsetzendeZeichen(2) = ":"
    zuErsetzendeZeichen(3) = "?"
    zuErsetzendeZeichen(4) = "*"
    zuErsetzendeZeichen(5) = """"
    zuErsetzendeZeichen(6) = "<"
    zuErsetzendeZeichen(7) = ">"
    zuErsetzendeZeichen(8) = "|"
   
    For I = 0 To 8
        zuErsetzen = zuErsetzendeZeichen(I)
        If InStr(filename, zuErsetzen) Then
            filename = Replace(filename, zuErsetzen, ersatz, , , vbTextCompare)
        End If
    Next I
   
    VonSonderzeichenBereinigen = filename
End Function


Function FormatiereDatumMitLeerzeichen(receivedDatum) As String
    datum = DatePart("yyyy", receivedDatum)
    ' das geht sicherlich eleganter aber was soll's
   
    ' Trennzeichen ins Datum eingebaut
    datum = datum & "-"
   
    If (Len(DatePart("m", receivedDatum)) < 2) Then
        datum = datum & "0"
    End If
    datum = datum & DatePart("m", receivedDatum)
   
    datum = datum & "-"
   
    If (Len(DatePart("d", receivedDatum)) < 2) Then
        datum = datum & "0"
    End If
    datum = datum & DatePart("d", receivedDatum)
    FormatiereDatumMitLeerzeichen = datum
End Function

Function FormatiereDatum(receivedDatum) As String
    datum = DatePart("yyyy", receivedDatum)
    ' das geht sicherlich eleganter aber was soll's
   
    ' ich möchte lieber keine Trennzeichen im Datum
    'datum = datum & "-"
   
    If (Len(DatePart("m", receivedDatum)) < 2) Then
        datum = datum & "0"
    End If
    datum = datum & DatePart("m", receivedDatum)
   
    'datum = datum & "-"
   
    If (Len(DatePart("d", receivedDatum)) <2> 0) And ((leerz < komma) Or (komma = 0)) And ((leerz <semik> 0) And (leer2 <semik> 0) Then
            Name = Left(Name, semik - 1)
        End If
        Name = Right(Name, Len(Name) - leerz)
    ' Der Name hat die Form "Nachname; ..." oder "name@firma.de; ..."
    ElseIf (semik > leerz) And ((komma = 0) Or (semik > komma)) Then
        Name = Left(Name, semik - 1)
        Name = Right(Name, Len(Name) - leerz)
    End If
    NameKuerzen = Name
End Function


Sub Speichern(path, item)
    ' MsgBox "Länge von path = " & Len(path)
    dateiSchonDa = Dir(path)
   
    If (dateiSchonDa <> "") Then
        path = InputBox("Die Datei " & path & " existiert bereits. Soll unter einem anderem Namen gespeichert werden?", "Speichern als", path)
        If (path = "") Then
            'MsgBox "Speichern abgebrochen"
        Else
            Speichern path, item
        End If
    Else
        'MsgBox "Speichere als " & path & " !"
        item.SaveAs path, olMSG
    End If
End Sub

Sub GewaehlteMailsSpeichern(zielVerzeichnis)
    'Achtung: ich gehe davon aus, dass das verzeichnis ohne Bachslash angegenen wird
    zielVerzeichnis = zielVerzeichnis & "\"
    verzeichnisSchonDa = Dir(zielVerzeichnis, vbDirectory)
    If (verzeichnisSchonDa = "") Then
        MsgBox "Fehler: Das Verzeichnis " & zielVerzeichnis & " existiert nicht"
    Else
        ' so kriegt man alle selektierten Mails (hoffentlich:-)
        Set myOlApp = CreateObject("Outlook.Application")
        Set myExplorer = myOlApp.ActiveExplorer
        Set mySelectedItems = myExplorer.Selection
   
        ' Jede Mail einzeln anfassen und speichern
        For Each item In mySelectedItems
            MailSpeichernUnter item, zielVerzeichnis
        Next
    End If
End Sub


Sub SpeichernUnter()
    Verzeichnis = Browse_Directory()
    'Verzeichnis = InputBox("Bitte Verzeichnis eingeben", "Mail Speichern unter", "C:\Localdata\")
    ' das Verzeichnis, in dem die Mails abgelegt werden
    If (Verzeichnis = "") Then
        MsgBox ("Abgebrochen")
    Else
        GewaehlteMailsSpeichern (Verzeichnis)
    End If
End Sub


ist sicherlich kein Highlight der VBA-Programmierung, aber es funktioniert...

Eine oder mehrere Emails markieren, die Funktion "Sub SpeichernUnter()" aufrufen und das gewünschte Verzeichnis aufrufen.

Gespreichert wird in der Form Datum_Absender_Betreff_Empfänger

Gruß,
Jochen
RTausD
Excel-Anwender mit ersten Makro-Erfahrungen


Verfasst am:
16. Feb 2012, 16:44
Rufname:

AW: eMail + Attachments per Makro ins Dateisystem speichern - AW: eMail + Attachments per Makro ins Dateisystem speichern

Nach oben
       Version: Office 2010

Hi Jochen,

ich habe Windows 7 mit 64 Bit und da haut es mir gleich am Anfang schon um die Ohren, dass ich die Declare-Anweisungen überarbeiten soll.

Hat jemand eine Idee, was damit gemeint ist (shell32 ist bestimmt nicht richtig) und wie ich das tun kann?

Vielen Dank

Rolf
Michael Bauer
MVP Outlook


Verfasst am:
20. Feb 2012, 11:02
Rufname:
Wohnort: Vollersode

AW: eMail + Attachments per Makro ins Dateisystem speichern - AW: eMail + Attachments per Makro ins Dateisystem speichern

Nach oben
       Version: Office 2010

Hallo,

das hat nichts mit Windows 64bit zu tun, sondern mit Office 64bit, das wohl nichts mit den 32bit APIs anfangen kann. Eine Lösung wurde hier noch nicht vorgestellt.

_________________
Michael Bauer
Tools für Microsoft Outlook
Michael Bauer
MVP Outlook


Verfasst am:
07. März 2012, 16:52
Rufname:
Wohnort: Vollersode

AW: eMail + Attachments per Makro ins Dateisystem speichern - AW: eMail + Attachments per Makro ins Dateisystem speichern

Nach oben
       Version: Office 2010

Hier ist eine gute Seite zu dem Thema.
_________________
Michael Bauer
Tools für Microsoft Outlook
almereyda
Gast


Verfasst am:
14. Sep 2012, 14:36
Rufname:


AW: eMail + Attachments per Makro ins Dateisystem speichern - AW: eMail + Attachments per Makro ins Dateisystem speichern

Nach oben
       Version: Office 2010

Ich habe gerade für Outlook 64 folgenden Code zusammengeschustert:

Code:


Attribute VB_Name = "ExportEmail"
'==========================================================================
'Export Outlook e-mail to drive
'--------------------------------------------------------------------------
'Author: Michael Wöhrer
'Editor: Jon Richter
'Version: 0.2, 2009-01-20
'Version: 0.3, 2012-09-14 (added Outlook 64 compatibility)
'==========================================================================
'Terms and conditions
'  You can use, redistribute and/or modify this code under the terms of
'  the SOFTWARE GUIDE LICENSE. This code is distributed in the hope that it
'  will be useful, but WITHOUT ANY WARRANTY; without even the implied
'  warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
'  See the SOFTWARE GUIDE LICENSE for more details.
'==========================================================================

Option Explicit

'-------------------------------------------------------------
' OPTIONS
'-------------------------------------------------------------
'Email format:
' MSG = Outlook msg format (incl. attachments, embedded objects etc.)., TXT = plain text
Private Const EXM_OPT_MAILFORMAT As String = "MSG"
'Date format of filename
Private Const EXM_OPT_FILENAME_DATEFORMAT As String = "yymmdd"
'Build filename; placeholders: <DATE> for date, <SENDER> for sender's name, <RECEIVER> for receiver, <SUBJECT> for subject
Private Const EXM_OPT_FILENAME_BUILD As String = "<DATE> <SUBJECT> <RECEIVER>"
'Use browse folder? Set to FALSE if you don't want to use browser for selecting target folder
Private Const EXM_OPT_USEBROWSER As Boolean = True
'Target folder (used if EXM_OPT_USEBROWSER is set to FALSE)
Private Const EXM_OPT_TARGETFOLDER As String = "D:\"
'Maximum number of emails to be selected & exported. Please don't use a huge number as this will cause
'performance and maybe other issues. Recommended is a value between 5 and 20.
Private Const EXM_OPT_MAX_NO As Integer = 200
'Email subject prefixes (such us "RE:", "FW:" etc.) to be removed. Please note that this is a
'RegEx expression, google for "regex" for further information. For instance "\s" means blank " ".
Private Const EXM_OPT_CLEANSUBJECT_REGEX As String = "RE:\s|Re:\s|AW:\s|FW:\s|WG:\s|SV:\s|Antwort:\s"
'-------------------------------------------------------------


'-------------------------------------------------------------
' TRANSLATIONS
'-------------------------------------------------------------
'-- English
'Const EXM_007 = "Script terminated"
'Const EXM_013 = "Selected Outlook item is not an e-mail"
'Const EXM_014 = "File already exists"
'-- German
Private Const EXM_001 As String = "Die E-Mail wurde erfolgreich abgelegt."
Private Const EXM_002 As String = "Die E-Mail konnte nicht abgelegt werden, Grund:"
Private Const EXM_003 As String = "Ausgewählter Pfad:"
Private Const EXM_004 As String = "E-Mail(s) ausgewählt und erfolgreich abgelegt."
Private Const EXM_005 As String = "<FREE>"
Private Const EXM_006 As String = "<FREE>"
Private Const EXM_007 As String = "Script abgebrochen"
Private Const EXM_008 As String = "Fehler aufgetreten: Sie haben mehr als [LIMIT_SELECTED_ITEMS] E-Mails ausgewählt. Die Aktion wurde beendet."
Private Const EXM_009 As String = "Es wurde keine E-Mail ausgewählt."
Private Const EXM_010 As String = "Es ist ein Fehler aufgetreten: es war keine Email im Fokus, so dass die Ablage nicht erfolgen konnte."
Private Const EXM_011 As String = "Es ist ein Fehler aufgetreten:"
Private Const EXM_012 As String = "Die Aktion wurde beendet."
Private Const EXM_013 As String = "Ausgewähltes Outlook-Dokument ist keine E-Mail"
Private Const EXM_014 As String = "Datei existiert bereits"
Private Const EXM_015 As String = "<FREE>"
Private Const EXM_016 As String = "Bitte wählen Sie den Ordner zum Exportieren:"
Private Const EXM_017 As String = "Fehler beim Exportieren aufgetreten"
Private Const EXM_018 As String = "Export erfolgreich"
Private Const EXM_019 As String = "Bei [NO_OF_FAILURES] E-Mail(s) ist ein Fehler aufgetreten:"
Private Const EXM_020 As String = "[NO_OF_SELECTED_ITEMS] E-Mail(s) wurden ausgewählt und [NO_OF_SUCCESS_ITEMS] E-Mail(s) erfolgreich abgelegt."
'-------------------------------------------------------------

' // http://www.ms-office-forum.net/forum/showthread.php?t=263854
#If VBA7 Then    ' VBA7
Declare PtrSafe Function SHBrowseForFolder Lib "shell32.dll" _
  Alias "SHBrowseForFolderA" (lpBrowseInfo As BROWSEINFO) As Long

Public Type BROWSEINFO
  hOwner As LongPtr
  pidlRoot As Long
  pszDisplayName As String
  lpszTitle As String
  ulFlags As Long
  lpFn As LongPtr
  lParam As LongPtr
  iImage As Long
End Type
 Public Declare PtrSafe Function SHGetPathFromIDList Lib "Shell32" _
   Alias "SHGetPathFromIDListA" _
   (ByVal pidl As Long, _
   ByVal pszPath As String) As Long

Public Declare PtrSafe Sub CoTaskMemFree Lib "ole32" (ByVal pv As LongPtr)

Public Declare PtrSafe Function SendMessage Lib "user32" _
   Alias "SendMessageA" _
   (ByVal hWnd As LongPtr, _
   ByVal wMsg As Long, _
   ByVal wParam As Long, _
   lParam As Any) As Long
   
Public Declare PtrSafe Sub CopyMemory Lib "kernel32" _
   Alias "RtlMoveMemory" _
   (pDest As Any, _
    pSource As Any, _
    ByVal dwLength As Long)
#Else    ' Downlevel when using previous version of VBA7

Declare Function SHBrowseForFolder Lib "shell32.dll" _
  Alias "SHBrowseForFolderA" (lpBrowseInfo As BROWSEINFO) As Long

Public Type BROWSEINFO
  hOwner As Long
  pidlRoot As Long
  pszDisplayName As String
  lpszTitle As String
  ulFlags As Long
  lpFn As Long
  lParam As Long
  iImage As Long
End Type
 
#End If



   
Public Const MAX_PATH As Long = 260
Public Const WM_USER = &H400
Public Const BFFM_INITIALIZED = 1

'Constants ending in 'A' are for Win95 ANSI
'calls; those ending in 'W' are the wide Unicode
'calls for NT.

'Sets the status text to the null-terminated
'string specified by the lParam parameter.
'wParam is ignored and should be set to 0.
Public Const BFFM_SETSTATUSTEXTA As Long = (WM_USER + 100)
Public Const BFFM_SETSTATUSTEXTW As Long = (WM_USER + 104)

'If the lParam  parameter is non-zero, enables the
'OK button, or disables it if lParam is zero.
'(docs erroneously said wParam!)
'wParam is ignored and should be set to 0.
Public Const BFFM_ENABLEOK As Long = (WM_USER + 101)

'Selects the specified folder. If the wParam
'parameter is FALSE, the lParam parameter is the
'PIDL of the folder to select , or it is the path
'of the folder if wParam is the C value TRUE (or 1).
'Note that after this message is sent, the browse
'dialog receives a subsequent BFFM_SELECTIONCHANGED
'message.
Public Const BFFM_SETSELECTIONA As Long = (WM_USER + 102)
Public Const BFFM_SETSELECTIONW As Long = (WM_USER + 103)
   

'specific to the PIDL method
'Undocumented call for the example. IShellFolder's
'ParseDisplayName member function should be used instead.
Public Declare PtrSafe Function SHSimpleIDListFromPath Lib _
   "Shell32" Alias "#162" _
   (ByVal szPath As String) As Long


'specific to the STRING method
Public Declare PtrSafe Function LocalAlloc Lib "kernel32" _
   (ByVal uFlags As Long, _
    ByVal uBytes As Long) As Long
   
Public Declare PtrSafe Function LocalFree Lib "kernel32" _
   (ByVal hMem As Long) As Long

Public Declare PtrSafe Function lstrcpyA Lib "kernel32" _
   (lpString1 As Any, lpString2 As Any) As Long

Public Declare PtrSafe Function lstrlenA Lib "kernel32" _
   (lpString As Any) As Long

Public Const LMEM_FIXED = &H0
Public Const LMEM_ZEROINIT = &H40
Public Const LPTR = (LMEM_FIXED Or LMEM_ZEROINIT)

'windows-defined type OSVERSIONINFO
Public Type OSVERSIONINFO
  OSVSize         As Long
  dwVerMajor      As Long
  dwVerMinor      As Long
  dwBuildNumber   As Long
  PlatformID      As Long
  szCSDVersion    As String * 128
End Type
       
Public Const VER_PLATFORM_WIN32_NT = 2

Public Declare PtrSafe Function GetVersionEx Lib "kernel32" _
   Alias "GetVersionExA" _
  (lpVersionInformation As OSVERSIONINFO) As Long
 
Public Declare PtrSafe Function GetLogicalDriveStrings Lib "kernel32" _
   Alias "GetLogicalDriveStringsA" _
  (ByVal nBufferLength As Long, _
   ByVal lpBuffer As String) As Long
' // http://www.ms-office-forum.net/forum/showthread.php?t=263854


'-------------------------------------
'For browse folder
'-------------------------------------
'
'Private Declare PtrSafe Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As String
'Private Declare PtrSafe Function SHBrowseForFolder Lib "Shell32" (lpbi As BROWSEINFO) As Long
'Private Declare PtrSafe Function SHGetPathFromIDList Lib "Shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
'Private Declare PtrSafe Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As LongPtr)



'Private Const BIF_RETURNONLYFSDIRS = 1
'Private Const MAX_PATH = 260
'Private Type BROWSEINFO
'    hwndOwner As LongPtr
'    pidlRoot As Long
'    pszDisplayName As String
'    lpszTitle As String
'    ulFlags As Long
'    lpfnCallback As LongPtr
'    lParam As LongPtr
'    iImage As Long
'End Type





Public Sub ExportEmailToDrive()
   
    Const PROCNAME As String = "ExportEmailToDrive"
   
    On Error GoTo ErrorHandler
   
    Dim myExplorer As Outlook.Explorer
    Dim myfolder As Outlook.MAPIFolder
    Dim myItem As Object
    Dim olSelection As Selection
    Dim strBackupPath As String
    Dim intCountAll As Integer
    Dim intCountFailures As Integer
    Dim strStatusMsg As String
    Dim vSuccess As Variant
    Dim strTemp1 As String
    Dim strTemp2 As String
    Dim strErrorMsg As String
 
    '-------------------------------------
    'Get target drive
    '-------------------------------------
    If (EXM_OPT_USEBROWSER = True) Then
        strBackupPath = GetFileDir
        If Left(strBackupPath, 15) = "ERROR_OCCURRED:" Then
            strErrorMsg = Mid(strBackupPath, 16, 9999)
            Error 5004
        End If
    Else
        strBackupPath = EXM_OPT_TARGETFOLDER
    End If
    If strBackupPath = "" Then GoTo ExitScript
    If (Not Right(strBackupPath, 1) = "\") Then strBackupPath = strBackupPath & "\"
   
   
 
    '-------------------------------------
    'Process according to what is in the focus: an opened e-mail or a folder with selected e-mails.
    'Case 2 would also work for opened e-mail, however it does not always work (for instance if
    ' an e-mail is saved on the file system and being opened from there).
    '-------------------------------------

    Set myExplorer = Application.ActiveExplorer
    Set myfolder = myExplorer.CurrentFolder
    If myfolder Is Nothing Then Error 5001
    If Not myfolder.DefaultItemType = olMailItem Then GoTo ExitScript
   
    'Stop if more than x emails selected
    If myExplorer.Selection.Count > EXM_OPT_MAX_NO Then Error 5002
     
    'No email selected at all?
    If myExplorer.Selection.Count = 0 Then Error 5003
     
    Set olSelection = myExplorer.Selection
    intCountAll = 0
    intCountFailures = 0
    For Each myItem In olSelection
        intCountAll = intCountAll + 1
        vSuccess = ProcessEmail(myItem, strBackupPath)
        If (Not vSuccess = True) Then
            Select Case intCountFailures
                Case 0: strStatusMsg = vSuccess
                Case 1: strStatusMsg = "1x " & strStatusMsg & Chr(10) & "1x " & vSuccess
                Case Else: strStatusMsg = strStatusMsg & Chr(10) & "1x " & vSuccess
            End Select
            intCountFailures = intCountFailures + 1
        End If
    Next
    If intCountFailures = 0 Then
        strStatusMsg = intCountAll & " " & EXM_004
    End If

       
    'Final Message
    If (intCountFailures = 0) Then  'No failure occurred
        MsgBox strStatusMsg & Chr(10) & Chr(10) & EXM_003 & " " & strBackupPath, 64, EXM_018
    ElseIf (intCountAll = 1) Then   'Only one email was selected and a failure occurred
        MsgBox EXM_002 & Chr(10) & vSuccess & Chr(10) & Chr(10) & EXM_003 & " " & strBackupPath, 48, EXM_017
    Else    'More than one email was selected and at least one failure occurred
        strTemp1 = Replace(EXM_020, "[NO_OF_SELECTED_ITEMS]", intCountAll)
        strTemp1 = Replace(strTemp1, "[NO_OF_SUCCESS_ITEMS]", intCountAll - intCountFailures)
        strTemp2 = Replace(EXM_019, "[NO_OF_FAILURES]", intCountFailures)
        MsgBox strTemp1 & Chr(10) & Chr(10) & strTemp2 & Chr(10) & Chr(10) & strStatusMsg _
        & Chr(10) & Chr(10) & EXM_003 & " " & strBackupPath, 48, EXM_017
    End If


ExitScript:
    Exit Sub
ErrorHandler:
    Select Case Err.Number
    Case 5001:  'Not an email
        MsgBox EXM_010, 64, EXM_007
    Case 5002:
        MsgBox Replace(EXM_008, "[LIMIT_SELECTED_ITEMS]", EXM_OPT_MAX_NO), 64, EXM_007
    Case 5003:
        MsgBox EXM_009, 64, EXM_007
    Case 5004:
        MsgBox EXM_011 & Chr(10) & Chr(10) & strErrorMsg, 48, EXM_007
    Case Else:
        MsgBox EXM_011 & Chr(10) & Chr(10) _
        & Err & " - " & Error$ & Chr(10) & Chr(10) & EXM_012, 48, EXM_007
    End Select
    Resume ExitScript
End Sub

Private Function ProcessEmail(myItem As Object, strBackupPath As String) As Variant
    'Saves the e-mail on the drive by using the provided path.
    'Returns TRUE if successful, and FALSE otherwise.

    Const PROCNAME As String = "ProcessEmail"

    On Error GoTo ErrorHandler

    Dim myMailItem As MailItem
    Dim strDate As String
    Dim strSender As String
    Dim strReceiver As String
    Dim strSubject As String
    Dim strFinalFileName As String
    Dim strFullPath As String
    Dim vExtConst As Variant
    Dim vTemp As String
    Dim strErrorMsg As String

    If TypeOf myItem Is MailItem Then
         Set myMailItem = myItem
    Else
        Error 1001
    End If

    'Set filename
    strDate = Format(myMailItem.SentOn, EXM_OPT_FILENAME_DATEFORMAT)
    strSender = myMailItem.SenderName
    strReceiver = myMailItem.To 'All receiver, semikolon separated string
    If InStr(strReceiver, ";") > 0 Then strReceiver = Left(strReceiver, InStr(strReceiver, ";") - 1)
    strSubject = myMailItem.Subject
    strFinalFileName = EXM_OPT_FILENAME_BUILD
    strFinalFileName = Replace(strFinalFileName, "<DATE>", strDate)
    strFinalFileName = Replace(strFinalFileName, "<SENDER>", strSender)
    strFinalFileName = Replace(strFinalFileName, "<RECEIVER>", strReceiver)
    strFinalFileName = Replace(strFinalFileName, "<SUBJECT>", strSubject)
    strFinalFileName = CleanString(strFinalFileName)
    If Left(strFinalFileName, 15) = "ERROR_OCCURRED:" Then
        strErrorMsg = Mid(strFinalFileName, 16, 9999)
        Error 1003
    End If
    strFinalFileName = IIf(Len(strFinalFileName) > 251, Left(strFinalFileName, 251), strFinalFileName)
    strFullPath = strBackupPath & strFinalFileName
   
    'Save as msg or txt?
    Select Case UCase(EXM_OPT_MAILFORMAT)
        Case "MSG":
            strFullPath = strFullPath & ".msg"
            vExtConst = olMSG
        Case Else:
            strFullPath = strFullPath & ".txt"
            vExtConst = olTXT
    End Select
    'File already exists?
    If CreateObject("Scripting.FileSystemObject").FileExists(strFullPath) = True Then
        Error 1002
    End If
   
    'Save file
    myMailItem.SaveAs strFullPath, vExtConst
   
 
    'Return true as everything was successful
    ProcessEmail = True

ExitScript:
    Exit Function
ErrorHandler:
    Select Case Err.Number
    Case 1001:  'Not an email
        ProcessEmail = EXM_013
    Case 1002:
        ProcessEmail = EXM_014
    Case 1003:
        ProcessEmail = strErrorMsg
    Case Else:
        ProcessEmail = "Error #" & Err & ": " & Error$ & " (Procedure: " & PROCNAME & ")"
    End Select
    Resume ExitScript
End Function


Private Function CleanString(strData As String) As String

    Const PROCNAME As String = "CleanString"

    On Error GoTo ErrorHandler

    'Instantiate RegEx
    Dim objRegExp As Object
    Set objRegExp = CreateObject("VBScript.RegExp")
    objRegExp.Global = True

    'Cut out strings we don't like
    objRegExp.Pattern = EXM_OPT_CLEANSUBJECT_REGEX
    strData = objRegExp.Replace(strData, "")

    'Replace and cut out invalid strings.
    strData = Replace(strData, Chr(9), "_")
    strData = Replace(strData, Chr(10), "_")
    strData = Replace(strData, Chr(13), "_")
    objRegExp.Pattern = "[/\\*]"
    strData = objRegExp.Replace(strData, "-")
    objRegExp.Pattern = "[""]"
    strData = objRegExp.Replace(strData, "'")
    objRegExp.Pattern = "[:?<>\|]"
    strData = objRegExp.Replace(strData, "")
   
    'Replace multiple chars by 1 char
    objRegExp.Pattern = "\s+"
    strData = objRegExp.Replace(strData, " ")
    objRegExp.Pattern = "_+"
    strData = objRegExp.Replace(strData, "_")
    objRegExp.Pattern = "-+"
    strData = objRegExp.Replace(strData, "-")
    objRegExp.Pattern = "'+"
    strData = objRegExp.Replace(strData, "'")
           
    'Trim
    strData = Trim(strData)
   
    'Return result
    CleanString = strData
 
 
ExitScript:
    Exit Function
ErrorHandler:
    CleanString = "ERROR_OCCURRED:" & "Error #" & Err & ": " & Error$ & " (Procedure: " & PROCNAME & ")"
    Resume ExitScript
End Function

Private Function GetFileDir() As String
   
    Const PROCNAME As String = "GetFileDir"

    On Error GoTo ErrorHandler

    Dim ret As String
    Dim lpIDList As Long
    Dim spath As String
    Dim udtBI As BROWSEINFO
    Dim RdStrings() As String
    Dim nNewFiles As Long

    'Show a browse-for-folder form:
    With udtBI
        .lpszTitle = lstrcpyA(EXM_016, "")
        .ulFlags = BFFM_INITIALIZED
    End With

    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList = 0 Then Exit Function
       
    'Get the selected folder.
    spath = String$(MAX_PATH, 0)
    SHGetPathFromIDList lpIDList, spath
    CoTaskMemFree lpIDList
   
    'Strip Nulls
    If (InStr(spath, Chr$(0)) > 0) Then spath = Left$(spath, InStr(spath, Chr(0)) - 1)

    'Return Dir
    GetFileDir = spath

ExitScript:
    Exit Function
ErrorHandler:
    GetFileDir = "ERROR_OCCURRED:" & "Error #" & Err & ": " & Error$ & " (Procedure: " & PROCNAME & ")"
    Resume ExitScript
End Function


Für Outlook 32 benutze ich:

Code:


Attribute VB_Name = "ExportEmail"
'==========================================================================
'Export Outlook e-mail to drive
'--------------------------------------------------------------------------
'Author: Michael Wöhrer
'Version: 0.2, 2009-01-20
'==========================================================================
'Terms and conditions
'  You can use, redistribute and/or modify this code under the terms of
'  the SOFTWARE GUIDE LICENSE. This code is distributed in the hope that it
'  will be useful, but WITHOUT ANY WARRANTY; without even the implied
'  warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
'  See the SOFTWARE GUIDE LICENSE for more details.
'==========================================================================

Option Explicit

'-------------------------------------------------------------
' OPTIONS
'-------------------------------------------------------------
'Email format:
' MSG = Outlook msg format (incl. attachments, embedded objects etc.)., TXT = plain text
Private Const EXM_OPT_MAILFORMAT As String = "MSG"
'Date format of filename
Private Const EXM_OPT_FILENAME_DATEFORMAT As String = "yymmdd"
'Build filename; placeholders: <DATE> for date, <SENDER> for sender's name, <RECEIVER> for receiver, <SUBJECT> for subject
Private Const EXM_OPT_FILENAME_BUILD As String = "<DATE> <SUBJECT> <RECEIVER>"
'Use browse folder? Set to FALSE if you don't want to use browser for selecting target folder
Private Const EXM_OPT_USEBROWSER As Boolean = True
'Target folder (used if EXM_OPT_USEBROWSER is set to FALSE)
Private Const EXM_OPT_TARGETFOLDER As String = "D:\"
'Maximum number of emails to be selected & exported. Please don't use a huge number as this will cause
'performance and maybe other issues. Recommended is a value between 5 and 20.
Private Const EXM_OPT_MAX_NO As Integer = 200
'Email subject prefixes (such us "RE:", "FW:" etc.) to be removed. Please note that this is a
'RegEx expression, google for "regex" for further information. For instance "\s" means blank " ".
Private Const EXM_OPT_CLEANSUBJECT_REGEX As String = "RE:\s|Re:\s|AW:\s|FW:\s|WG:\s|SV:\s|Antwort:\s"
'-------------------------------------------------------------


'-------------------------------------------------------------
' TRANSLATIONS
'-------------------------------------------------------------
'-- English
'Const EXM_007 = "Script terminated"
'Const EXM_013 = "Selected Outlook item is not an e-mail"
'Const EXM_014 = "File already exists"
'-- German
Private Const EXM_001 As String = "Die E-Mail wurde erfolgreich abgelegt."
Private Const EXM_002 As String = "Die E-Mail konnte nicht abgelegt werden, Grund:"
Private Const EXM_003 As String = "Ausgewählter Pfad:"
Private Const EXM_004 As String = "E-Mail(s) ausgewählt und erfolgreich abgelegt."
Private Const EXM_005 As String = "<FREE>"
Private Const EXM_006 As String = "<FREE>"
Private Const EXM_007 As String = "Script abgebrochen"
Private Const EXM_008 As String = "Fehler aufgetreten: Sie haben mehr als [LIMIT_SELECTED_ITEMS] E-Mails ausgewählt. Die Aktion wurde beendet."
Private Const EXM_009 As String = "Es wurde keine E-Mail ausgewählt."
Private Const EXM_010 As String = "Es ist ein Fehler aufgetreten: es war keine Email im Fokus, so dass die Ablage nicht erfolgen konnte."
Private Const EXM_011 As String = "Es ist ein Fehler aufgetreten:"
Private Const EXM_012 As String = "Die Aktion wurde beendet."
Private Const EXM_013 As String = "Ausgewähltes Outlook-Dokument ist keine E-Mail"
Private Const EXM_014 As String = "Datei existiert bereits"
Private Const EXM_015 As String = "<FREE>"
Private Const EXM_016 As String = "Bitte wählen Sie den Ordner zum Exportieren:"
Private Const EXM_017 As String = "Fehler beim Exportieren aufgetreten"
Private Const EXM_018 As String = "Export erfolgreich"
Private Const EXM_019 As String = "Bei [NO_OF_FAILURES] E-Mail(s) ist ein Fehler aufgetreten:"
Private Const EXM_020 As String = "[NO_OF_SELECTED_ITEMS] E-Mail(s) wurden ausgewählt und [NO_OF_SUCCESS_ITEMS] E-Mail(s) erfolgreich abgelegt."
'-------------------------------------------------------------


'-------------------------------------
'For browse folder
'-------------------------------------
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Const BIF_RETURNONLYFSDIRS = 1
Private Const MAX_PATH = 260
Private Type BrowseInfo

    hwndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type

Public Sub ExportEmailToDrive()
   
    Const PROCNAME As String = "ExportEmailToDrive"
   
    On Error GoTo ErrorHandler
   
    Dim myExplorer As Outlook.Explorer
    Dim myfolder As Outlook.MAPIFolder
    Dim myItem As Object
    Dim olSelection As Selection
    Dim strBackupPath As String
    Dim intCountAll As Integer
    Dim intCountFailures As Integer
    Dim strStatusMsg As String
    Dim vSuccess As Variant
    Dim strTemp1 As String
    Dim strTemp2 As String
    Dim strErrorMsg As String
 
    '-------------------------------------
    'Get target drive
    '-------------------------------------
    If (EXM_OPT_USEBROWSER = True) Then
        strBackupPath = GetFileDir
        If Left(strBackupPath, 15) = "ERROR_OCCURRED:" Then
            strErrorMsg = Mid(strBackupPath, 16, 9999)
            Error 5004
        End If
    Else
        strBackupPath = EXM_OPT_TARGETFOLDER
    End If
    If strBackupPath = "" Then GoTo ExitScript
    If (Not Right(strBackupPath, 1) = "\") Then strBackupPath = strBackupPath & "\"
   
   
 
    '-------------------------------------
    'Process according to what is in the focus: an opened e-mail or a folder with selected e-mails.
    'Case 2 would also work for opened e-mail, however it does not always work (for instance if
    ' an e-mail is saved on the file system and being opened from there).
    '-------------------------------------

    Set myExplorer = Application.ActiveExplorer
    Set myfolder = myExplorer.CurrentFolder
    If myfolder Is Nothing Then Error 5001
    If Not myfolder.DefaultItemType = olMailItem Then GoTo ExitScript
   
    'Stop if more than x emails selected
    If myExplorer.Selection.Count > EXM_OPT_MAX_NO Then Error 5002
     
    'No email selected at all?
    If myExplorer.Selection.Count = 0 Then Error 5003
     
    Set olSelection = myExplorer.Selection
    intCountAll = 0
    intCountFailures = 0
    For Each myItem In olSelection
        intCountAll = intCountAll + 1
        vSuccess = ProcessEmail(myItem, strBackupPath)
        If (Not vSuccess = True) Then
            Select Case intCountFailures
                Case 0: strStatusMsg = vSuccess
                Case 1: strStatusMsg = "1x " & strStatusMsg & Chr(10) & "1x " & vSuccess
                Case Else: strStatusMsg = strStatusMsg & Chr(10) & "1x " & vSuccess
            End Select
            intCountFailures = intCountFailures + 1
        End If
    Next
    If intCountFailures = 0 Then
        strStatusMsg = intCountAll & " " & EXM_004
    End If

       
    'Final Message
    If (intCountFailures = 0) Then  'No failure occurred
        MsgBox strStatusMsg & Chr(10) & Chr(10) & EXM_003 & " " & strBackupPath, 64, EXM_018
    ElseIf (intCountAll = 1) Then   'Only one email was selected and a failure occurred
        MsgBox EXM_002 & Chr(10) & vSuccess & Chr(10) & Chr(10) & EXM_003 & " " & strBackupPath, 48, EXM_017
    Else    'More than one email was selected and at least one failure occurred
        strTemp1 = Replace(EXM_020, "[NO_OF_SELECTED_ITEMS]", intCountAll)
        strTemp1 = Replace(strTemp1, "[NO_OF_SUCCESS_ITEMS]", intCountAll - intCountFailures)
        strTemp2 = Replace(EXM_019, "[NO_OF_FAILURES]", intCountFailures)
        MsgBox strTemp1 & Chr(10) & Chr(10) & strTemp2 & Chr(10) & Chr(10) & strStatusMsg _
        & Chr(10) & Chr(10) & EXM_003 & " " & strBackupPath, 48, EXM_017
    End If


ExitScript:
    Exit Sub
ErrorHandler:
    Select Case Err.Number
    Case 5001:  'Not an email
        MsgBox EXM_010, 64, EXM_007
    Case 5002:
        MsgBox Replace(EXM_008, "[LIMIT_SELECTED_ITEMS]", EXM_OPT_MAX_NO), 64, EXM_007
    Case 5003:
        MsgBox EXM_009, 64, EXM_007
    Case 5004:
        MsgBox EXM_011 & Chr(10) & Chr(10) & strErrorMsg, 48, EXM_007
    Case Else:
        MsgBox EXM_011 & Chr(10) & Chr(10) _
        & Err & " - " & Error$ & Chr(10) & Chr(10) & EXM_012, 48, EXM_007
    End Select
    Resume ExitScript
End Sub

Private Function ProcessEmail(myItem As Object, strBackupPath As String) As Variant
    'Saves the e-mail on the drive by using the provided path.
    'Returns TRUE if successful, and FALSE otherwise.

    Const PROCNAME As String = "ProcessEmail"

    On Error GoTo ErrorHandler

    Dim myMailItem As MailItem
    Dim strDate As String
    Dim strSender As String
    Dim strReceiver As String
    Dim strSubject As String
    Dim strFinalFileName As String
    Dim strFullPath As String
    Dim vExtConst As Variant
    Dim vTemp As String
    Dim strErrorMsg As String

    If TypeOf myItem Is MailItem Then
         Set myMailItem = myItem
    Else
        Error 1001
    End If

    'Set filename
    strDate = Format(myMailItem.SentOn, EXM_OPT_FILENAME_DATEFORMAT)
    strSender = myMailItem.SenderName
    strReceiver = myMailItem.To 'All receiver, semikolon separated string
    If InStr(strReceiver, ";") > 0 Then strReceiver = Left(strReceiver, InStr(strReceiver, ";") - 1)
    strSubject = myMailItem.Subject
    strFinalFileName = EXM_OPT_FILENAME_BUILD
    strFinalFileName = Replace(strFinalFileName, "<DATE>", strDate)
    strFinalFileName = Replace(strFinalFileName, "<SENDER>", strSender)
    strFinalFileName = Replace(strFinalFileName, "<RECEIVER>", strReceiver)
    strFinalFileName = Replace(strFinalFileName, "<SUBJECT>", strSubject)
    strFinalFileName = CleanString(strFinalFileName)
    If Left(strFinalFileName, 15) = "ERROR_OCCURRED:" Then
        strErrorMsg = Mid(strFinalFileName, 16, 9999)
        Error 1003
    End If
    strFinalFileName = IIf(Len(strFinalFileName) > 251, Left(strFinalFileName, 251), strFinalFileName)
    strFullPath = strBackupPath & strFinalFileName
   
    'Save as msg or txt?
    Select Case UCase(EXM_OPT_MAILFORMAT)
        Case "MSG":
            strFullPath = strFullPath & ".msg"
            vExtConst = olMSG
        Case Else:
            strFullPath = strFullPath & ".txt"
            vExtConst = olTXT
    End Select
    'File already exists?
    If CreateObject("Scripting.FileSystemObject").FileExists(strFullPath) = True Then
        Error 1002
    End If
   
    'Save file
    myMailItem.SaveAs strFullPath, vExtConst
   
 
    'Return true as everything was successful
    ProcessEmail = True

ExitScript:
    Exit Function
ErrorHandler:
    Select Case Err.Number
    Case 1001:  'Not an email
        ProcessEmail = EXM_013
    Case 1002:
        ProcessEmail = EXM_014
    Case 1003:
        ProcessEmail = strErrorMsg
    Case Else:
        ProcessEmail = "Error #" & Err & ": " & Error$ & " (Procedure: " & PROCNAME & ")"
    End Select
    Resume ExitScript
End Function


Private Function CleanString(strData As String) As String

    Const PROCNAME As String = "CleanString"

    On Error GoTo ErrorHandler

    'Instantiate RegEx
    Dim objRegExp As Object
    Set objRegExp = CreateObject("VBScript.RegExp")
    objRegExp.Global = True

    'Cut out strings we don't like
    objRegExp.Pattern = EXM_OPT_CLEANSUBJECT_REGEX
    strData = objRegExp.Replace(strData, "")

    'Replace and cut out invalid strings.
    strData = Replace(strData, Chr(9), "_")
    strData = Replace(strData, Chr(10), "_")
    strData = Replace(strData, Chr(13), "_")
    objRegExp.Pattern = "[/\\*]"
    strData = objRegExp.Replace(strData, "-")
    objRegExp.Pattern = "[""]"
    strData = objRegExp.Replace(strData, "'")
    objRegExp.Pattern = "[:?<>\|]"
    strData = objRegExp.Replace(strData, "")
   
    'Replace multiple chars by 1 char
    objRegExp.Pattern = "\s+"
    strData = objRegExp.Replace(strData, " ")
    objRegExp.Pattern = "_+"
    strData = objRegExp.Replace(strData, "_")
    objRegExp.Pattern = "-+"
    strData = objRegExp.Replace(strData, "-")
    objRegExp.Pattern = "'+"
    strData = objRegExp.Replace(strData, "'")
           
    'Trim
    strData = Trim(strData)
   
    'Return result
    CleanString = strData
 
 
ExitScript:
    Exit Function
ErrorHandler:
    CleanString = "ERROR_OCCURRED:" & "Error #" & Err & ": " & Error$ & " (Procedure: " & PROCNAME & ")"
    Resume ExitScript
End Function

Private Function GetFileDir() As String
   
    Const PROCNAME As String = "GetFileDir"

    On Error GoTo ErrorHandler

    Dim ret As String
    Dim lpIDList As Long
    Dim sPath As String
    Dim udtBI As BrowseInfo
    Dim RdStrings() As String
    Dim nNewFiles As Long

    'Show a browse-for-folder form:
    With udtBI
        .lpszTitle = lstrcat(EXM_016, "")
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With

    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList = 0 Then Exit Function
       
    'Get the selected folder.
    sPath = String$(MAX_PATH, 0)
    SHGetPathFromIDList lpIDList, sPath
    CoTaskMemFree lpIDList
   
    'Strip Nulls
    If (InStr(sPath, Chr$(0)) > 0) Then sPath = Left$(sPath, InStr(sPath, Chr(0)) - 1)

    'Return Dir
    GetFileDir = sPath

ExitScript:
    Exit Function
ErrorHandler:
    GetFileDir = "ERROR_OCCURRED:" & "Error #" & Err & ": " & Error$ & " (Procedure: " & PROCNAME & ")"
    Resume ExitScript
End Function
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Outlook Mail: E-Mail inkl. Anlagen speichern 2 crazydasy 1853 17. Feb 2005, 14:23
kraemer E-Mail inkl. Anlagen speichern
Keine neuen Beiträge Outlook Mail: Habe Probleme bei Email versenden mit Outlook 2003 3 Gast 1665 17. Feb 2005, 13:25
Amethyst Habe Probleme bei Email versenden mit Outlook 2003
Keine neuen Beiträge Outlook Mail: Standard Dateiendung bei Speichern von E-Mails ändern 5 S.Thielen 4414 02. Feb 2005, 12:04
kraemer Standard Dateiendung bei Speichern von E-Mails ändern
Keine neuen Beiträge Outlook Mail: OFFENER Briefumschlag/email mit 2x "SENDEN" bestät 2 Freddi 1720 29. Jan 2005, 15:51
Freddi OFFENER Briefumschlag/email mit 2x "SENDEN" bestät
Keine neuen Beiträge Outlook Mail: E-Mail nach 3Tagen weiterleiten 1 coriolanus 720 14. Jan 2005, 15:58
wolf-it E-Mail nach 3Tagen weiterleiten
Keine neuen Beiträge Outlook Mail: Standard E-Mail Konto beim Versenden 1 neosfahrer 1750 19. Dez 2004, 20:23
Gast Standard E-Mail Konto beim Versenden
Keine neuen Beiträge Outlook Mail: Sortierung bei Anzeige eigener Kontakte bei Email senden 6 Sushi 1412 08. Dez 2004, 15:04
wolf-it Sortierung bei Anzeige eigener Kontakte bei Email senden
Keine neuen Beiträge Outlook Mail: OutlookAntworten über eine andere E-Mail adresse verschicken 5 klient 5619 09. Nov 2004, 00:27
Amethyst OutlookAntworten über eine andere E-Mail adresse verschicken
Keine neuen Beiträge Outlook Mail: email mit lesebestätigung 5 gugenot 3088 04. Nov 2004, 16:04
gugenot email mit lesebestätigung
Keine neuen Beiträge Outlook Mail: Symantec E-Mail Proxy 0 andy1169 1920 04. Okt 2004, 19:23
andy1169 Symantec E-Mail Proxy
Keine neuen Beiträge Outlook Mail: senden von mails bei web.de - speichern bei outlook 2 Wuzz 1522 11. Sep 2004, 13:07
hasemann senden von mails bei web.de - speichern bei outlook
Keine neuen Beiträge Outlook Mail: Email in Xml umwandeln 0 Anderas 1209 17. Aug 2004, 15:04
Anderas Email in Xml umwandeln
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft Word Serienbriefe