Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Mehrfachauswahl bei Dropdown
zurück: bed. Formatierung bei Multiplikation mit wenn Verchachtelung weiter: Markieren von Zahlenpaaren Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Julia2503
Gast


Verfasst am:
22. Feb 2012, 14:55
Rufname:

Mehrfachauswahl bei Dropdown - Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo,

hoffe es kann mir jemand helfen. Ich versuche ein Dropdown mit Mehrfachauswahl über Gültigkeit-Liste zu erstellen. Irgendwie funktionierts aber nicht...Habe des öfteren gelesen, dass man einfach Mehrfachauwahl wählen soll, aber wo steht das?

Bitte um Hilfe...

Lg Julia
Rudi4
Excel-Hobbyist


Verfasst am:
23. Feb 2012, 05:16
Rufname: Rudi
Wohnort: ganz oben rechts


AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo Julia,
da hast du dich des öfteren verlesen.
Dat gibbet nämlich nich!

Dropdowns gibt es,
Mehrfachauswahl gibt es,
Gültigkeit-Liste gibt es.

Aber was suchst du?
Vielleicht im Dialog Datenüberprüfung
Zulassen : Liste
Dann trage unter Quelle
deine Werte ein (semikolon getrennt)
oder den Bereich oder den Namen unter dem du die Liste definiert hast.

Zellendropdown ist automatisch aktiviert.

_________________
MfG Rudi
gandalf149
Im Profil kannst Du frei den Rang ändern


Verfasst am:
23. Feb 2012, 16:16
Rufname:
Wohnort: Fiersbach

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo Julia,

hier zwei Möglichkeiten

für Zellendropdown in Spalte C

der erste Code schreibt die jeweilige Auswahl kommagetrennt in die Zelle

beim zweiten Code kann zusätzlich durch normalige Auswahl gelöscht und sortiert werden.

Code gehört in die Tabelle

Code:
Const TargetColumn As Long = 3  ' Ziele in Spalte 3.

Dim blockedEvent As Boolean
Dim TargetOldText As String

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Column = TargetColumn Then
        If Not blockedEvent Then
            blockedEvent = True
            If Not TargetOldText = "" And Not Target.Value = "" Then
                Target.Value = TargetOldText & ", " & Target.Value
            Else
                Target.Value = Target.Value
            End If
            TargetOldText = Target.Value
        Else
            blockedEvent = False
        End If
    Else
        TargetOldText = ""
    End If
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    On Error Resume Next
    If Target.Column = TargetColumn Then
        TargetOldText = Target.Value
    End If
End Sub


zweite Möglichkeit

Code:
Const TargetColumn As Long = 3          ' Ziele in Spalte 3.
Const bolSorted As Boolean = True       ' Legt fest, ob die Werte noch sortiert werden.

Dim blockedEvent As Boolean
Dim TargetOldText As String

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim strResult As String
    Dim strTarget As String
    Dim arrSorted As Variant
    Dim i As Long
    If Target.Column = TargetColumn Then
        strTarget = Trim$(Target.Value)
        If Not blockedEvent Then
            blockedEvent = True
            If Not TargetOldText = "" And Not Target.Value = "" Then
                If InStr(1, TargetOldText, Target.Value) > 0 Then
                    strResult = Replace(TargetOldText, ", " & strTarget, "")
                    strResult = Replace(strResult, strTarget & ", ", "")
                    strResult = Replace(strResult, strTarget, "")
                Else
                    strResult = TargetOldText & ", " & Target.Value
                End If
                If bolSorted Then
                    arrSorted = Split(strResult, ", ")
                    strResult = ""
                    Call Selectionsort(arrSorted)
                    For i = 0 To UBound(arrSorted)
                        strResult = strResult & arrSorted(i) & ", "
                    Next i
                    If Len(strResult) > 1 Then _
                    strResult = Left$(strResult, Len(strResult) - 2)
                End If
                Target.Value = strResult
            Else
                Target.Value = Target.Value
            End If
            TargetOldText = Target.Value
        Else
            blockedEvent = False
        End If
    Else
        TargetOldText = ""
    End If
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    On Error Resume Next
    If Target.Column = TargetColumn Then
        TargetOldText = Target.Value
    End If
End Sub

Private Sub Selectionsort(ByRef data As Variant)

    Dim OG&, i&, j&, k&, h As Variant

    OG = UBound(data)

    For i = 0 To OG - 1
        h = data(i)
        k = i
        For j = i + 1 To OG
            If data(j) < h Then
                h = data(j)
                k = j
            End If
        Next j
        data(k) = data(i)
        data(i) = h
    Next i

End Sub


Gruß Gandalf149

_________________
Jedes Kind ist ein Künstler. Das Problem ist nur, wie man einer bleibt, wenn man erwachsen wird.
Pablo Picasso
Excel_Rainer
Gast


Verfasst am:
24. Feb 2012, 09:56
Rufname:

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo Julia,

wie Rudi geschrieben hat, gibt es alles.
Eine Mehrfachauswahl gibt es aber nicht bei Daten > Gültigkeit.
Da wird immer nur ein Eintrag angezeigt.

Verwende ein Listenfeld aus der Gruppe Steuerelemente (ActiveX Steuerelemente), dann brauchst Du aber VBA um die Markierung auszuwerten.

Gruß Rainer
gandalf149
Im Profil kannst Du frei den Rang ändern


Verfasst am:
24. Feb 2012, 17:05
Rufname:
Wohnort: Fiersbach


AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo

hier ein Bild eines Zellendropdowns (Daten,Gültigkeit) mit Listenquelle und Mehrfachauswahl.

Verwendet wurde Code 2 mit Sortierung und der Löschmöglichkeit durch erneute Auswahl des Wertes

Gruß Gandalf149

_________________
Jedes Kind ist ein Künstler. Das Problem ist nur, wie man einer bleibt, wenn man erwachsen wird.
Pablo Picasso



Dropdown_Mehrfachauswahl - Kopie.png
 Beschreibung:
 Dateigröße:  1.72 KB
 Angeschaut:  2338 mal

Dropdown_Mehrfachauswahl - Kopie.png


fg83
Neuling


Verfasst am:
24. Okt 2013, 09:31
Rufname:

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2010

Der oben genannte Code ist wirklich mal eine tolle Hilfe!

Hier meine Fragen bzgl. einer kleinen Erweiterung:

- Kann man den Code (Version 2) auch auf 2 oder mehrere Spalten anwenden? (Im gleichen Tabellenblatt)
- Und würde es auch funktionieren, die Werte untereinander anzeigen zu lassen (anstatt mit Komma-Trennung)

Danke!
gandalf149
Im Profil kannst Du frei den Rang ändern


Verfasst am:
25. Okt 2013, 01:04
Rufname:
Wohnort: Fiersbach

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo,

das geht auch für mehrere Spalten

dies entfällt

Code:
Const TargetColumn As Long = 3


dies muß geändert werden

Code:
 If Target.Column = TargetColumn Then


in
Code:

 If Target.Column = 3 or Target.Column = 4 Then


es würde dann für die Spalte C und D gelten.

Untereinander geht nicht, ein Zellendropdown gilt für eine Zelle

Gruß Gandalf149

_________________
Jedes Kind ist ein Künstler. Das Problem ist nur, wie man einer bleibt, wenn man erwachsen wird.
Pablo Picasso
fg83
Neuling


Verfasst am:
25. Okt 2013, 08:45
Rufname:

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Vielen Dank für die schnelle Hilfe! Funktioniert einwandfrei.

Kurzer Tipp für Andere mit der selben Frage: Die Anpassung muss, zumindest bei Version 2 des Codes, an zwei Stellen erfolgen.)

Danke udn Grüsse
fg83
Tom1181
Neuling


Verfasst am:
15. Apr 2014, 11:30
Rufname:
Wohnort: Karlsruhe

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2010

Hallo,

da ich genau das auch brauche, greife ich dieses Topic nochmal auf.

Nun ist es so, dass ich die Mehrfachauswahl ebenfalls in verschiedenen Spalten benötige, habe also den Code 2 entsprechend umgeändert. Dies funktioniert auch theoretisch... Praktisch jedoch sieht es so aus, dass es in der ersten Spalte einwandfrei funktioniert, in den darauf folgenden aber, der Inhalt der vorigen Auswahl mit übernommen wird. Und das obwohl die Datenüberprüfung auf verschiedene Listen zugreift...

Als Beispiel habe ich eine Tabelle erstellt, in der man zu erst Namen auswählen soll (Frida, Gerd,...) und später Zutaten (Salz, Mehl,...) und anschließend Nachtisch (Banane, Eis,...). Wenn ich jetzt bspw. in der ersten Spalte Frida auswähle und dann die Zutaten auswählen möchte, übernimmt er erst mal den Wert Frida aus der vorigen Spalte...??? Die Reihenfolge spielt dabei keine Rolle, er übernimmt immer die zuvor ausgewählten Werte. So steht dann in der letzten Spalte Nachtisch dann etwas wie "Frida, Salz, Mehl, Banane, Eis " (natürlich alphabetisch sortiert).

Woran könnte das liegen? Habe nur VBA-Grundkenntnisse aus dem Studium und kann leider keinen Fehler finden. Bräuchte diese Funktion für eine etwas komplexere Liste und dieses Problem wäre schon sehr ärgerlich.

Kann leider noch keine Dateien anhängen und hoffe, ich habe mich einigermaßen verständlich ausgedrückt.

Vielen Dank im Voraus Smile
gandalf149
Im Profil kannst Du frei den Rang ändern


Verfasst am:
15. Apr 2014, 12:00
Rufname:
Wohnort: Fiersbach

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo Tom,

dann schau mal in Tabelle1

Gruß Gandalf149

_________________
Jedes Kind ist ein Künstler. Das Problem ist nur, wie man einer bleibt, wenn man erwachsen wird.
Pablo Picasso



Zellendropdown_Mehrfachauswahl_sortiert.xlsm
 Beschreibung:

Download
 Dateiname:  Zellendropdown_Mehrfachauswahl_sortiert.xlsm
 Dateigröße:  25.76 KB
 Heruntergeladen:  22 mal

Gast



Verfasst am:
15. Apr 2014, 12:46
Rufname:

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo Gandalf,

vielen Dank, für deine unglaublich schnelle Antwort!

Super! Jetzt klappt es. Hatte es ähnlich probiert, aber nicht hin bekommen...

Vielen Dank dafür! Smile
Dankbar
Gast


Verfasst am:
17. Apr 2014, 09:32
Rufname:

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2010

Hallo Gandalf,

vielen Dank für das tolle Script.

Bei der Variante in Tabellenblatt 2, wäre es toll wenn möglich ist, dass nur zwischen 2 Werten ein Komma erscheint, jedoch nicht nach dem letzten Wert.

Soll:
Ball, Handschuh, Torwart

Ist:
Ball, Handschuh, Torwart,

Kann man das realisieren?
Dankbar
Gast


Verfasst am:
17. Apr 2014, 11:57
Rufname:

AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2010

Jemand anders hat mir den Code entsprechend angepasst.
Falls noch jemand Bedarf dafür hat:

Private Sub ListBox1_Change()
Dim i As Integer
Dim myzub
Dim c As Integer

With Me.ListBox1
For i = 0 To Me.ListBox1.ListCount - 1 'Listbox wird durchlaufen
If Me.ListBox1.Selected(i) Then 'falls ausgewählt
c = i
End If
Next
For i = 0 To c
If Me.ListBox1.Selected(i) Then
myzub = myzub & .List(i, 0)
If i <> c Then
myzub = myzub & ", " 'Bezeichnung in Variable
End If
End If
Next
End With
gandalf149
Im Profil kannst Du frei den Rang ändern


Verfasst am:
17. Apr 2014, 14:05
Rufname:
Wohnort: Fiersbach


AW: Mehrfachauswahl bei Dropdown - AW: Mehrfachauswahl bei Dropdown

Nach oben
       Version: Office 2007

Hallo,

oder so

Code:
Private Sub ListBox1_Change()
Dim i As Integer
Dim myzub
 With Me.ListBox1
     For i = 0 To Me.ListBox1.ListCount - 1  'Listbox wird durchlaufen
        If Me.ListBox1.Selected(i) Then   'falls ausgewählt
             myzub = myzub & .List(i, 0) & "," 'Bezeichnung in Variable
        End If
    Next
End With
If Len(myzub) > 1 Then
ziel.Value = Left(myzub, Len(myzub) - 1)
Else
ziel.Value = myzub
End If
myzub = ""
End Sub


Gruß Gandalf149

_________________
Jedes Kind ist ein Künstler. Das Problem ist nur, wie man einer bleibt, wenn man erwachsen wird.
Pablo Picasso
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Dropdown Bedingungen 2 doubleyou 499 22. Jun 2008, 13:13
doubleyou Dropdown Bedingungen
Keine neuen Beiträge Excel Formeln: DropDown + Bereich zuweisen 13 Peter0606 1115 15. Mai 2008, 13:07
Peter0606 DropDown + Bereich zuweisen
Keine neuen Beiträge Excel Formeln: Dropdown liste in Berechnung einfügen 3 Gast 505 10. Apr 2008, 16:45
Gast Dropdown liste in Berechnung einfügen
Keine neuen Beiträge Excel Formeln: Kombinationsfelder (drop-down) miteinander kombinieren 1 Zeradum 2325 12. März 2008, 13:06
Zeradum Kombinationsfelder (drop-down) miteinander kombinieren
Keine neuen Beiträge Excel Formeln: Leere Felder in Dropdown auswahl ausblenden 10 Muradin Feuerbart 6416 24. Feb 2008, 15:30
Muradin Feuerbart Leere Felder in Dropdown auswahl ausblenden
Keine neuen Beiträge Excel Formeln: Sortieren nach Auswahl in Drop-Down Liste 5 martin_kl 2239 29. Dez 2007, 16:45
martin_kl Sortieren nach Auswahl in Drop-Down Liste
Keine neuen Beiträge Excel Formeln: Liste mit Mehrfachauswahl und wenn-dann Verknüpfung 0 rotezoraa 3549 25. Okt 2007, 15:29
rotezoraa Liste mit Mehrfachauswahl und wenn-dann Verknüpfung
Keine neuen Beiträge Excel Formeln: DropDown Verknüpfungen 7 stm79 1419 22. Sep 2007, 12:22
stm79 DropDown Verknüpfungen
Keine neuen Beiträge Excel Formeln: wo befindet sich im excel 07 das dropdown feld 4 guest 20312 05. Jun 2007, 08:47
ae wo befindet sich im excel 07 das dropdown feld
Keine neuen Beiträge Excel Formeln: Abfrage mit Dropdown 2 Gast 712 22. Mai 2007, 12:51
urs Abfrage mit Dropdown
Keine neuen Beiträge Excel Formeln: DropDown wenn.... 2 dagrumus 930 14. März 2007, 23:26
etron795 DropDown wenn....
Keine neuen Beiträge Excel Formeln: Sortieren mit DropDown Menü 0 rbuehler 806 09. Nov 2006, 17:39
rbuehler Sortieren mit DropDown Menü
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Excel Tipps