Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Einzelne Daten aus MS Project in Excel nach Abgleich
Gehe zu Seite 1, 2  Weiter
zurück: Inputbox, Do loop, LeereZelle weiter: per Hyperlink eine Präsentation starten Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Klabauterfrau
Gast


Verfasst am:
23. Feb 2012, 16:30
Rufname:

Einzelne Daten aus MS Project in Excel nach Abgleich - Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hallo gebündeltes Fachwissen in Sachen "Dinge die mit Excel Spaß machen und solche, die es nicht machen, aber trotzdem nützlich sind",

ich habe folgendes Problem:

In meiner Firma wird für jedes Produkt in einer MS Project Datenbank ein Task angelegt. Eindeutig zu identifizieren sind die Tasks durch eine zugewiesene ID. Diese Datenbank bzw. das Projekt wird fortlaufend geführt und gepflegt.
Gleichzeitig werden in der Versandabteilung ExcelTabellen getrennt nach Geschäftsjahren zur Planung geführt, also nichts fortlaufendes.

Ziel ist es nun, da in dem Projekt die einzelnen Tasks ständig aktualisiert werden, bestimmte Daten aus dem Projekt in Excel unter Abgleich der eindeutigen ID einzufügen bzw. aktuell zu halten.

Ein Beispiel wäre ein Produkt mit der ID xy bekommt im Projekt eine Aktualisierung von Daten, die für die Versandplanung relevant sind. Öffnet man nun die Exceldatei soll das Produkt mit der ID xy hinsichtlich der Änderung im Projekt auch aktualisiert werden. Wichtig dabei ist, dass nur bestimmte Daten quasi exportiert werden sollen und nicht das komplette Projekt.

Wie man das zw. 2Excelsheets realisiert, weiß ich, aber bei Project zu Excel bin ich auch nach längerem Suchen via einschlägiger Suchmaschinen überfordert.

Vlt. findet sich ja wer, der sich meiner annimmt.
Bis dahin, mfg
Phelan XLPH
Fortgeschritten


Verfasst am:
23. Feb 2012, 16:38
Rufname: Phelan


AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Mit MS Project kenn ich mich auch nicht aus, aber wie kommen denn die Daten
ins Excel?

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
Klabauterfrau
Gast


Verfasst am:
24. Feb 2012, 08:06
Rufname:

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Die Daten in der Exceldatei werden händisch eingetragen. Es handelt sich dabei lediglich um ein paar Grunddaten.

Hintergrund dessen ist, dass die Versandplanung immer schon vor Fertigstellung der Produkte realisiert wird, und während der Fertigung weitere Eintragungen im MS Project getätigt werden, die dann auch wieder (mühsam) händisch übertragen werden müssten.

Die Grundfrage ist deshalb, ob ein Abgleich ala 'Vergleiche Zelle A1 im Excel mit Zelle A1 im Project' möglich ist oder nicht.

Falls nicht, muss man wohl beim alten Verfahren des händischen Übertragens bleiben ;)

mfg
Case
Coder


Verfasst am:
24. Feb 2012, 09:32
Rufname: Case
Wohnort: Schwäbisch Hall

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hallo, Razz

prinzipiell kannst Du so auf eine MS-Project Datei zugreifen:

Code:
Option Explicit
Public Sub Main()
    Dim objMSProject As Object
    Dim intCount As Integer
    Set objMSProject = GetObject(PathName:="C:\Temp\Test.mpp")
    For intCount = 1 To objMSProject.Resources.Count
        Debug.Print objMSProject.Resources.Item(intCount).Name
        Debug.Print objMSProject.Resources.Item(intCount).BaselineWork
        Debug.Print objMSProject.Resources.Item(intCount).BaselineCost
    Next intCount
    Set objMSProject = Nothing
End Sub


Wenn Du Dir in dieser Codezeile...
Code:
Debug.Print objMSProject.Resources.Item(intCount).Name

... einen Haltepunkt (F9) setzt, dann kannst Du im Lokalfenster alle nötigen Informationen sehen - inklusive der Infos die Du brauchst. Wink

Servus
Case
Klabauterfrau
Gast


Verfasst am:
24. Feb 2012, 14:29
Rufname:


AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Das hat mir auf jeden Fall schonmal, was den Zugriff auf Project von Excel aus angeht, weitergeholfen.

Hab das ganze zum Testen erstmal auf nen Button gelegt, und sieht momentan so aus:

Code:
Private Sub CommandButton1_Click()
    Dim objMSProject As Object
    Dim projectCount As Integer
    Dim cell As Range
   
    Set objMSProject = GetObject(PathName:="C:\Temp\Test.mpp")
   
    For projectCount = 1 To objMSProject.Application.ActiveProject.Tasks.Count
   
        For Each cell In ActiveSheet.Range("B2", ActiveSheet.Range("B" & ActiveSheet.Rows.Count).End(xlUp))
       
            If UCase(cell) = objMSProject.Application.ActiveProject.Tasks(projectCount).Name Then
            Range("M5") = objMSProject.Application.ActiveProject.Tasks(projectCount).Start
            Else
            End If
           
        Next
       
    Next projectCount
   
    Set objMSProject = Nothing
End Sub


Das Makro vergleicht alle Einträge in der Spalte B (ID) mit der entsprechenden "Spalte" im Project und holt mir bei Übereinstimmung den Wert der "Spalte" Start aus Project nach Excel in die Zelle M5.

Und da wäre dann mein aktuelles Problem. Ich möchte dass, wenn z.B. in der Zelle B7 eine Übereinstimmung mit Project gefunden wird, in Zelle M7 der gewünschte Wert eingetragen wird.
Irgendwie muss das über einen Zähler machbar sein, wie aktuell "projectCount" in obigem Makro, aber ich komm einfach nicht drauf wie - und das am besten ohne das bisherige Makro wieder komplett umzuwerfen.

Da vlt. noch einer ne Idee?

mfg

PS: Besten Dank an Case für den Denkanstoß!
Case
Coder


Verfasst am:
24. Feb 2012, 15:18
Rufname: Case
Wohnort: Schwäbisch Hall

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hallo, Razz

so:

Code:
Option Explicit
Public Sub Main()
    Dim objMSProject As Object
    Dim intCount As Integer
    Dim lngLastRow As Long
    On Error GoTo Fin
    With Tabelle1
        lngLastRow = IIf(IsEmpty(.Cells(.Rows.Count, 2)), _
            .Cells(.Rows.Count, 2).End(xlUp).Row, .Rows.Count)
    End With
    Set objMSProject = GetObject("C:\Temp\Test.mpp")
    For intCount = 1 To objMSProject.Tasks.Count
        With objMSProject.Tasks.Item(intCount)
            For lngLastRow = 2 To lngLastRow
                If Tabelle1.Cells(lngLastRow, 2).Value = .Name Then
                    Tabelle1.Cells(lngLastRow, 13).Value = .Start
                End If
            Next lngLastRow
        End With
    Next intCount
Fin:
    If Err.Number <> 0 Then MsgBox "Error: " & _
        Err.Number & " " & Err.Description
    Set objMSProject = Nothing
End Sub


Du mußt alle Tabelle1 (CodeName des Tabellenblattes) durch Deinen CodeNamen ersetzen bzw. durch ActiveSheet - wobei ich ActiveSheet als "Wackelkandidat" ansehe.

Alternativ kannst Du auch "ThisworkBook.WorkSheets("DeinTabellenblattname")" schreiben.

Servus
Case
Phelan XLPH
Fortgeschritten


Verfasst am:
24. Feb 2012, 15:30
Rufname: Phelan

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

@Case

Langt das aus?: Set objMSProject = Nothing

Muss MsProject nicht noch geschlossen werden?

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
Case
Coder


Verfasst am:
25. Feb 2012, 00:15
Rufname: Case
Wohnort: Schwäbisch Hall

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hallo, Razz

Zitat:
Muss MsProject nicht noch geschlossen werden?

Eigentlich nicht, denn Du erhältst mit der GetObject-Funktion (FileName) nur einen Verweis auf ein von einer COM-Komponente bereitgestelltes Objekt zurück.
Somit wird mit Set Objktvariable = Nothing die COM-Komponente wieder entfernt.

Niemand hindert dich allerdings daran die Objektvariable auf Nothing abzufragen und gegebenenfalls ein Objektvariable.Application.Quit einzufügen. Wink

Anders verhält es sich m. E. n., wenn Du mit CreateObject... arbeitest und über Objektvariablen Dateizuweisungen und ähnliche Dinge machst.

Servus
Case
Phelan XLPH
Fortgeschritten


Verfasst am:
25. Feb 2012, 08:47
Rufname: Phelan

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hallo Case,

Zitat:
Somit wird mit Set Objktvariable = Nothing die COM-Komponente wieder entfernt.


Das wird sie auch ohne das Setzen von Nothing.

M.E. müssen die Objektvariable nicht auf Nothing gesetzt werden da sie lediglich innerhalb der Prozedur ihre Gültigkeit hat, wie alle andern Variablen auch.

Schau dir folgendes Beispiel an.

Durch GetObject wird die Datei im Hintergrund geöffnet.
Lasse ich das wb.Close False weg, so bleibt sie weiterhin im Hintergrund offen.

Ich denke nicht dass sich die .mpp-Datei da anders verhält.
Leider kann ich es nicht testen ohne MS Project.

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein



Datei Offen.jpg
 Beschreibung:
 Dateigröße:  44.2 KB
 Angeschaut:  475 mal

Datei Offen.jpg


Case
Coder


Verfasst am:
25. Feb 2012, 20:29
Rufname: Case
Wohnort: Schwäbisch Hall

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hallo, Razz

na ja - Du machst das, was einem Makrokopierer eben übrig bleibt - Du kochst im eigenen Saft, sprich - Du schreibst ein paar Zeilen in Excel, die Excel aufrufen - um was zu beweisen? Wink

Eventuell hast Du noch Word installiert? Dann probiere es mal von Excel nach Word (oder eine andere Anwendung die eine Typebibliothek zur Verfügung stellt). Rolling Eyes

Mein Code geht über GetObject(FileName) von Excel --> MSProject und da ist ein Quit nach einem Nothing unnötig. Rolling Eyes

Puuhh... ich hoffe nicht, dass wir Klabautermann (eine Frau ist das glaube ich nicht Wink ) vertreiben. Wäre doch schade. Frage beantwortet Klabauterfrau/mann? Und Entschuldigung - normalerweise ignoriere ich solche Einwürfe.

Servus
Case
Phelan XLPH
Fortgeschritten


Verfasst am:
25. Feb 2012, 21:20
Rufname: Phelan

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hallo Case Razz ,

verzeihe, ich dachte ich bin hier in einem Forum.

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
Klabauterfreu
Gast


Verfasst am:
27. Feb 2012, 07:59
Rufname:

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hu,

so schnell lass ich mich ne vertreiben. War nur WE und da der Spaß hier mit meiner Arbeit zusammenhängt, bleibt sowas übers WE auch unberührt.

Werd gleich mal deinen obigen Code testen und mich zur Funktionstüchtigkeit äußern ;)

mfg
Klabauterfrau
Gast


Verfasst am:
27. Feb 2012, 07:59
Rufname:

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hu,

so schnell lass ich mich ne vertreiben. War nur WE und da der Spaß hier mit meiner Arbeit zusammenhängt, bleibt sowas übers WE auch unberührt.

Werd gleich mal deinen obigen Code testen und mich zur Funktionstüchtigkeit äußern ;)

mfg
Klabauterfrau
Gast


Verfasst am:
27. Feb 2012, 08:47
Rufname:

AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Ui Doppelpost :O

Also hab den Code von Case nun getestet. Funktioniert soweit gut - schreibt in die Zeilen und entsprechenden Spalten, was es soll.

Ein Problem stellt sich jedoch noch dar. Und zwar schreibt er mir in ca 330 leere Zeilen unter der letzten Eintragung noch Werte.
Für mich sieht das ganze so aus, als gleicht das Makro auch leere Zeilen in Spalte B (2) mit Project ab, da es vorkommt, dass in der Spalte im Project, die verglichen wird, eben auch mal nichts steht.
Komisch finde ich dabei nur, dass er eben nach ca 330 Zeilen einfach aufhört, anstatt bis Zeile 65000+ durchzujuckeln, worüber ich natürlich froh bin, es aber für mich unlogischer macht.

Die Frage ist nun, kann ich in der Zeile

Code:
If ActiveSheet.Cells(lngLastRow, 2).Value = .Name Then


ausschließen, dass Leerzeilen abgeglichen werden - also quasi OHNE " " ?

mfg
Case
Coder


Verfasst am:
27. Feb 2012, 09:08
Rufname: Case
Wohnort: Schwäbisch Hall


AW: Einzelne Daten aus MS Project in Excel nach Abgleich - AW: Einzelne Daten aus MS Project in Excel nach Abgleich

Nach oben
       Version: Office 2003

Hallo, Razz

wenn wir die For-Schleifen vertauschen müsste es passen: Wink

Code:
Option Explicit
Public Sub Main()
    Dim objMSProject As Object
    Dim intCount As Integer
    Dim lngLastRow As Long
    On Error GoTo Fin
    With Tabelle1
        lngLastRow = IIf(IsEmpty(.Cells(.Rows.Count, 2)), _
            .Cells(.Rows.Count, 2).End(xlUp).Row, .Rows.Count)
    End With
    Set objMSProject = GetObject("C:\Temp\Test.mpp")
    For lngLastRow = 2 To lngLastRow
        For intCount = 1 To objMSProject.Tasks.Count
            With objMSProject.Tasks.Item(intCount)
                If Tabelle1.Cells(lngLastRow, 2).Value = .Name Then
                    Tabelle1.Cells(lngLastRow, 13).Value = .Start
                End If
            End With
        Next intCount
    Next lngLastRow
Fin:
    If Err.Number <> 0 Then MsgBox "Error: " & _
        Err.Number & " " & Err.Description
    Set objMSProject = Nothing
End Sub


Servus
Case
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: WENN Daten dann Datum der Eingabe 7 Placebo 1711 28. März 2007, 09:47
Auch Gast WENN Daten dann Datum der Eingabe
Keine neuen Beiträge Excel Formeln: Daten in einer Übersicht zusammenfassen 8 totaler anfänger 1517 26. Aug 2005, 20:50
fl618 Daten in einer Übersicht zusammenfassen
Keine neuen Beiträge Excel Formeln: doppelte daten suchen 2 chrispx 1428 26. Aug 2005, 09:27
chrispx doppelte daten suchen
Keine neuen Beiträge Excel Formeln: Daten zusammenf�hren 2 Gast 708 16. Jun 2005, 15:44
Gast Daten zusammenf�hren
Keine neuen Beiträge Excel Formeln: bei monatswechsel daten automatisch in andere spalte 2 poison30 1333 08. Jun 2005, 22:28
poison30 bei monatswechsel daten automatisch in andere spalte
Keine neuen Beiträge Excel Formeln: Verkn�pfung Daten aktualisieren 0 Steffi1976 1039 30. Mai 2005, 16:22
Steffi1976 Verkn�pfung Daten aktualisieren
Keine neuen Beiträge Excel Formeln: Daten in Spalte: Reihenfolge umkehren 4 ggaribaldi 8901 09. Mai 2005, 16:32
ggaribaldi Daten in Spalte: Reihenfolge umkehren
Keine neuen Beiträge Excel Formeln: daten in EINER zelle zusammenführen 1 thompson 807 23. Apr 2005, 18:13
fl618 daten in EINER zelle zusammenführen
Keine neuen Beiträge Excel Formeln: Beim Import von Daten automatisch zusammenzählen 8 Schoki 1146 20. Apr 2005, 09:52
Schoki Beim Import von Daten automatisch zusammenzählen
Keine neuen Beiträge Excel Formeln: Liste nach Daten aus einem Feld sortieren 5 thomas34 1221 05. Apr 2005, 10:44
thomas34 Liste nach Daten aus einem Feld sortieren
Keine neuen Beiträge Excel Formeln: Excel Daten in Word an eine bestimmte stelle einfügen 7 Anne 2260 04. März 2005, 13:10
The BOO-M-AN Excel Daten in Word an eine bestimmte stelle einfügen
Keine neuen Beiträge Excel Formeln: daten sortieren 8 Gast 2141 10. Feb 2005, 15:00
Andy Knecht daten sortieren
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft Excel Tricks