Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Dateiname unter Speichern Unter vorgeben
Gehe zu Seite 1, 2  Weiter
zurück: Begriff durchsuchen, Zeile markieren, formatieren weiter: Makro Code an anderes Dokument übergeben Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Ferencz
VBA Mitschwimmer


Verfasst am:
01. Dez 2005, 15:20
Rufname:
Wohnort: München

Dateiname unter Speichern Unter vorgeben - Dateiname unter Speichern Unter vorgeben

Nach oben
       

Hallo Leute,

bräuchte dringend Eure Hilfe.
Durch eine Vorlage wird eine neue Word-Datei erstellt. Wenn man im Menü unter Datei -> Speichern unter... klickt und dieses Dialog aufpopt, sollte einen Namen für diese Datei vorgeschlagen werden. Die Konvention lautet <Bereich>_<Abteilung>_Version_ <Datum>.doc, wie z.B. IT_XP_Version_2005_12_01.doc
Den Namen kann ich mit dem folgenden Aufruf aus dem bereits vorhandenen Daten ohne weiteres zusammenbasteln:

Code:
With ActiveDocument
DocName = .CustomDocumentProperties("Bereich") & "_" & _
.CustomDocumentProperties("Abteilung") & "_Version_" & _
CStr(Format(.CustomDocumentProperties("Ausgabedatum"), _
"yyyy_mm_dd"))
End With


Mein Problem ist es nur, was muss ich tolles zaubern, damit dieser Vorschlag im Speichern unter erscheint?

Vielen Dank für die Tipps im Voraus!
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
01. Dez 2005, 18:22
Rufname:
Wohnort: Leipzig


Dateiname beim Speichern vorgeben - Dateiname beim Speichern vorgeben

Nach oben
       

Hallo Ferenc,

das geht so:
Code:
Sub FileSave()

    If ActiveDocument.Path = "" Then    'Falls Dokument noch nie gespeichert wurde
        FileSaveAs
        Exit Sub
    End If
    ActiveDocument.Save

End Sub
Sub FileSaveAs()

    Dim DocName As String

    With ActiveDocument
       DocName = .CustomDocumentProperties("Bereich") & "_" & _
       .CustomDocumentProperties("Abteilung") & "_Version_" & _
       CStr(Format(.CustomDocumentProperties("Ausgabedatum"), _
       "yyyy_mm_dd"))
    End With

    With Dialogs(wdDialogFileSaveAs)
        .Name = DocName
        .Show
    End With
   
End Sub

Das Makro speichert nichts automatisch, sondern zeigt den normalen Speicherdialog an mit dem Vorschlag, den du vorher in deine Variable DocName gefüllt hast. Dort kann man den Namen auch noch ändern oder auch den Pfad, je nach Wunsch.
Das Makro solltest du am besten in der Dokumentvorlage Brief (oder wie diese nun heißt) abspeichern. Die Prozedurnamen (FileSave und FileSaveAs) sollten nicht verändert werden. Dann springt das Makro einfach an, wenn du auf Datei - Speichern klickst oder auf Strg s.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!


Zuletzt bearbeitet von Lisa am 29. Mai 2009, 09:42, insgesamt einmal bearbeitet
Ferencz
VBA Mitschwimmer


Verfasst am:
01. Dez 2005, 19:02
Rufname:
Wohnort: München

Dateiname beim Speichern vorgeben - Dateiname beim Speichern vorgeben

Nach oben
       

Danke Lisa,

ich habe schon alle möglichen Sachen ausprobiert und bin nicht weitergekommen. Sad
Dein Code funktioniert wie gewünscht und kann jetzt beruhigt nach Hause gehen. Very Happy

Vielen-vielen Dank, Ferencz


Zuletzt bearbeitet von Ferencz am 02. Dez 2005, 12:39, insgesamt einmal bearbeitet
Ferencz
VBA Mitschwimmer


Verfasst am:
02. Dez 2005, 12:18
Rufname:
Wohnort: München

Dateiname beim Speichern vorgeben - Dateiname beim Speichern vorgeben

Nach oben
       

Hallo Lisa,

ich möchte den oben genannten Vorgang auch beim Schließen eines Dokuments anwenden können. Wenn das Dialog aufpopt, möchten Sie speichern -> Ja, dann soll der Dateiname genauso vorgeschlagen werden.

In einem anderem Beitrag von dir habe ich schon die Lösung gefunden, nur es funktioniert bei mir nicht. Hier mein Code, zusammengebaut von deinen Vorschlägen:

Code:

Sub FileClose()
    Dim UserAntwort As String
    If Not ActiveDocument.Saved Then
        UserAntwort = MsgBox(Prompt:="Möchten Sie Änderungen in " & _
        ActiveDocument.Name & " speichern?", Buttons:=vbYesNoCancel + vbExclamation)
        Select Case UserAntwort
            Case Is = "", vbCancel
                Exit Sub
            Case Is = vbNo
                ActiveDocument.Close (wdDoNotSaveChanges)
            Case Is = vbYes
                If ActiveDocument.Path = "" Then
                    Call FileSaveAs
                    ActiveDocument.Close (wdDoNotSaveChanges)
                Else                 
                    ActiveDocument.Close (wdSaveChanges)
                End If
        End Select
    Else
           ActiveDocument.Close (wdDoNotSaveChanges)
    End If
End Sub

Sub FileSave()
    If ActiveDocument.Path = "" Then
        FileSaveAs
        Exit Sub
    End If
    ActiveDocument.Save
End Sub

Sub FileSaveAs()
    Dim DocName As String
    With ActiveDocument
       DocName = .CustomDocumentProperties("Bereich") & "_" & _
       .CustomDocumentProperties("Abteilung") & "_Bericht_" & _
       CStr(Format(.CustomDocumentProperties("Ausgabedatum"), _
       "yyyy_mm_dd"))
    End With
    With Dialogs(wdDialogFileSaveAs)
        .Name = DocName
        .Show
    End With
End Sub


Kannst du mir irgendeine Literatur empfehlen, wo auch solche Sachen erwähnt werden, wie FileSaveAs, FileClose usw., damit ich weiss, welche Möglichkeite ich im VBA habe?

Vielen Dank, Ferencz
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
02. Dez 2005, 12:53
Rufname:
Wohnort: Leipzig


Empfehlungen zu VBA in Word - Empfehlungen zu VBA in Word

Nach oben
       

Hallo Ferencz,

bei mir ist der Code für FileClose so in Benutzung und läuft problemlos. Was funktioniert denn nicht? Wie äußert sich das?

Wenn du mal nachlesen willst: Hier gibt es ein spezielles Skript zur Technik des "Überschreibens" bzw. "Abfangens" von Word-Befehlen:
Pseudo-Events in Word

Dabei ist der Name der Prozedur von Bedeutung und darf nicht geändert werden, denn es werden die Namen der Word-eigenen Befehle verwendet und mit eigenem Inhalt gefüllt. Für die Namen der Word-Befehle gibt es hier eine Gegenüberstellung:
Gegenüberstellung Word-Befehle Deutsch-Englisch

Allgemein zum Erlernen von VBA empfehle ich dir dieses kostenlose Online-Buch (nach dem ich auch gerade VBA lerne):
VBA in 21 Tagen

Zu den Word-Spezialitäten in VBA gibt es von René Probst hier eine sehr gute Zusammenstellung seiner Skripten zu VBA (am Ende):
Word VBA-Zyklus

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Ferencz
VBA Mitschwimmer


Verfasst am:
02. Dez 2005, 13:06
Rufname:
Wohnort: München

Dateiname beim Speichern vorgeben - Dateiname beim Speichern vorgeben

Nach oben
       

Hallo Lisa,

von meine Vorlage erstelle ich ein neues Word Document. Bei der Erstellung werden paar Parameter, wie Bereich, Abteilung, Datum usw. übergeben. Diese brauch ich unter anderem für den Dateinamen. Wenn ich auf Datei -> Speichern oder Speichern unter... klicke, funktioniert die Vorgabe der Dateiname. Wenn ich aber die Datei schließe, ohne vorher gespeichert zu haben, und der Speichern unter Dialog auftaucht, wird der gewünschte Dateiname nicht vorgeschlagen. Was ich aber gern haben möchte.

Andere Frage, was ist der Unterschied zwischen
Code:
sub FileClose()
end sub

und
Code:
private sub Document_Close()
end sub


Vielen Dank, Ferencz
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
03. Dez 2005, 14:30
Rufname:
Wohnort: Leipzig

AW: Dateiname unter Speichern Unter vorgeben - AW: Dateiname unter Speichern Unter vorgeben

Nach oben
       

Hallo Ferencz,

das ist sonderbar, daß FileClose bei dir nicht funktionieren soll. Es überschreibt an sich den Wordbefehl FileClose, um deine Routine FileSaveAs aufzurufen, funktioniert bei mir wunderbar.
Verstehe ich das jetzt richtig? Wenn du FileSaveAs aufrufst (oder Strg s oder Datei - speichern), wird im Dialogfeld der Name vorgeschlagen.
FileClose springt normalerweise an, wenn man Strg w eingibt oder Datei - Schließen. Was passiert, wenn du Strg w eingibst?

Zu den DocumentClose-Ereignissen hast du ja schon den Link oben zum Skript. Was im Einzelfall geeigneter ist, muss man probieren. In dem Skript wird ja auch geschildert, dass DocumentClose (und AutoClose) anspringt und danach nochmal zum Speichern aufgefordert wird - wenn man das nicht ausschließt. Da gibt es keine Patentrezepte.
FileClose habe ich verwendet, damit es keinerlei Möglichkeit mehr gibt, das Dokument zu speichern, ohne dass der richtige Dateiname (bei mir auch Verzeichnis) vorgeschlagen wird.

Du könntest nochmal den Code im Einzelschritt durchlaufen, um zu sehen, wieso FileSaveAs nicht anspringt.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Ferencz
VBA Mitschwimmer


Verfasst am:
06. Dez 2005, 19:29
Rufname:
Wohnort: München

Dateiname beim Speichern vorgeben - Dateiname beim Speichern vorgeben

Nach oben
       

Hallo Lisa,

danke für deine Hilfe. Word eigene FileClose Methode zu überschreiben ist nicht ganz gesund für den Word. Mein Word ist auch paar mal abgestürtzt. Zu mien Word gibt es bereits verschiedene Arbeits-Vorlagen, die beim Booten des Rechneners immer aktualisiert werden. Ich vermute, dass es auch an diese liegen könnte, warum FileClose nicht funktioniert hat. Stattdessen habe ich den folgenden Code geschrieben, den ich für diejenige, die diese Funktion "Dateiname beim Speichern vorgeben" brauchen, hier reinposte:

Nachtrag am 21.12.2005:

Da es mit dem Quellcode nicht ganz richtig hingehauen hat, füge ich den letzten stand meiner Quellcode ein. Es ist immer noch nicht 100%-ig sauber. Unter bestimmten Umständen, z.B. wenn mehrere Word-Dateien offen sind, kann es sein, dass ein Speicher-Dialog öfters aufpopt (im Extremfall, wenn n Dateien offen sind, dann poppt es n+1 -mal auf). Warum, das ist eine sehr gute Frage. Wenn jemand da eine Lösung weisst, bitte melden.

Danke


Code:

' Mit Event-Handling
Private WithEvents wordApp As Application

Private Sub Document_New()
    Dim Section As String
       
    AllesAktualisieren.main
    frmInfo.Show
       
    DoEvents
    Set wordApp = Application
   
End Sub

Private Sub Document_Open()

    ActiveDocument.UpdateStylesOnOpen = False
   
    DoEvents
    Set wordApp = Application
End Sub

Private Sub wordApp_DocumentBeforeClose(ByVal Doc As Document, Cancel As Boolean)

'   Durch diesen Prozedurname springt die Subroutine an, wenn man auf Datei schließen
'   oder Strg w drückt.

    Dim UserAntwort As String
       
'    Debug.Assert False     '<- fürs debuggen
    With ActiveDocument
   
'       Wenn die Datei noch nicht gespeichert wurde und die Variable manSaved nicht gesetzt ist...
        If .Saved = False Then

'       ...dann erzeugt das Makro die gleiche MsgBox, die man sonst bei Datei schließen auch sieht.
'       Diese wird aber selbst erzeugt, so dass ihre Rückgabewerte abgefragt
'       werden können.

        UserAntwort = MsgBox(Prompt:="Möchten Sie die Änderungen in " & _
        .Name & " speichern?", Buttons:=vbYesNoCancel + vbExclamation)

        Select Case UserAntwort

'           Wenn man auf Abbrechen drückt passiert gar nichts.
            Case Is = vbCancel
'                Debug.Assert False
                Cancel = True
               
'           Bei Nein wird das Dokument ohne Speichern geschlossen.
            Case Is = vbNo
'                Debug.Assert False
                Cancel = True
                .Close (wbDoNotSaveChanges)

'           Bei Ja...
            Case Is = vbYes
'                Debug.Assert False

'               ...wenn die Datei noch keinen Pfad hat...
                If .Path = "" Then
'                    Debug.Assert False
'                   ...wird die Speicherprozedur FileSaveAs aufgerufen...
                    FileSaveAs
'                    Debug.Assert False
                   
'                   ...und anschließend geprüft, ob die Speicherung durchgeführt
'                   wurde.
                    If .Saved = True Then
'                        Debug.Assert False

                    Else
'                        Debug.Assert False
                        Cancel = True
                    End If
                   
                Else
'                ...wenn die Datei bereits einen Pfad hat, wird sie gespeichert...
                    FileSave
                   
'                   ...und wenn die Speicherung durchgeführt wurde...
                    If .Saved = True Then
'                        Debug.Assert False
                   
'                       ...wird die Datei geschlossen.
'                        .Close (wbDoNotSaveChanges)
                    Else
'                        Debug.Assert False
'                       ...sonst passiert gar nichts.
                        Cancel = True
                       
                    End If
                End If
            End Select
        End If
    End With

End Sub

Sub FileSave()
'    Debug.Assert False

    With ActiveDocument

'       Falls Dokument noch nie gespeichert wurde
        If .Path = "" Then
'            Debug.Assert False
'          Wird die FileSaveAs-Subroutine aufgerufen
            FileSaveAs
        Else
'            Debug.Assert False
            .Save
        End If
       
    End With
   
'Das Makro speichert nichts automatisch, sondern zeigt den normalen
'Speicherdialog an mit dem Vorschlag, den man vorher in den Variable
'DocName gefüllt hat. Die Prozedurnamen (FileSave und FileSaveAs)
'sollten nicht verändert werden. Das Makro springt an, wenn man auf
'Speichern oder Speichern unter klickt oder wenn man Strg + s drückt.

End Sub

Sub FileSaveAs()
'    Debug.Assert False
    Dim DocName As String
    Dim Button As Integer

    With ActiveDocument
   
'      Hier wird der komplette Dateiname nach der Konvention
'      <Bereich>_<Abteilung>_Name_<jjjj>_<mm>_<tt>
'      zusammengebaut
       DocName = .CustomDocumentProperties("Bereich") & "_" & _
       .CustomDocumentProperties("Abteilung") & "_Name_" & _
       CStr(Format(.CustomDocumentProperties("Ausgabedatum"), _
       "yyyy_mm_dd"))
   
    End With
    With Dialogs(wdDialogFileSaveAs)
   
'       Hier wird das Dialog Speichern unter... aufgerufen und der Dateiname
'       übergeben, so dass der gebastelte Name...
        .Name = DocName
       
'       ...als Vorschlag erscheint.
        Button = .Show
        .Update
   
    End With
    With ActiveDocument

'       Wenn im Dialog auf OK Button geklickt...
        If Button = -1 Then
'            Debug.Assert False
            .Save
       
'       ...oder das Dialog ohne Speichern geschlossen oder abgebrochen wurde...
        ElseIf Button = -2 Or Button = 0 Then
'            Debug.Assert False
            Cancel = True
           
        End If
    End With
End Sub

Falls jemand irgendein Fehler findet, lasst mich wissen.

Vielen Dank, vor allem an dich Lisa!
(@)}~'~,~'~,~~~

Ferencz
broetchen_4711
Gast


Verfasst am:
27. Apr 2006, 09:22
Rufname:

AW: Dateiname unter Speichern Unter vorgeben - AW: Dateiname unter Speichern Unter vorgeben

Nach oben
       

Very Happy
Hallo liebe Forenmitglieder,
habe soeben den äußerst hilfreichen Code für den Dateinamen in WORD 2003 implementiert und er funzt. Very Happy
Kennt irgendjemand einen ähnlichen Code, den ich für das gesamte MS-Office 2003 Paket nutzen kann?
Oder muss ich den Code in jeder Apllication einzeln implementieren?
Danke für Eure Hilfe.
Lars
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
27. Apr 2006, 23:30
Rufname:
Wohnort: Leipzig

AW: Dateiname unter Speichern Unter vorgeben - AW: Dateiname unter Speichern Unter vorgeben

Nach oben
       

Hallo Lars,

kurz und schmerzlich: nein!
Du wirst nicht umhin kommen, das für jede einzelne Office-Anwendung zu machen. Am besten in den entsprechenden anderen Foren mal danach umsehen.
In Word haben wir ja gerade die Technik benutzt, die Wordbefehle mit eigenen Prozeduren "abzufangen" und zu "überschreiben". Das geht in anderen Office-Anwendungen vermutlich nicht.

Gruß, Lisa
Luzius
Gast


Verfasst am:
23. Apr 2008, 17:52
Rufname:

AW: Dateiname unter Speichern Unter vorgeben - AW: Dateiname unter Speichern Unter vorgeben

Nach oben
       Version: Office 2003

Hallo zusammen

ich versuche die funktion das ein dateiname beim speichern vorgegeben wird zu implementieren, stosse aber auf probleme. mit hilfe dieses forums hab ich es zumindest schon mal hingekriegt, dass der speicherpfad von vorlage zu vorlage anders ist und das dokument beim klick auf 'speichern' jeweils am richtigen ort landet.

nun würde ich gerne wie gesagt noch den dateinamen automatisieren. in den dokumenten hat es verschiedene formularfelder welche die benötigte information enthalten.

Beispiel: Name Vorname Geburtsdatum Berichtart Schreibedatum

das ziel wäre jetzt, dass beim klick auf 'speichern' diese informationen automatisch aus diesen feldern gezogen und als dateiname vorgeschlagen wird.

geht das überhaupt? wie müsste ich die formularfelder definieren und dann im makro integrieren?

Schon jetzt hezlichen Dank für die Hilfe!

ps: es handelt sich um word 2003 professional für win xp
Luzius
Gast


Verfasst am:
23. Apr 2008, 21:19
Rufname:

AW: Dateiname unter Speichern Unter vorgeben - AW: Dateiname unter Speichern Unter vorgeben

Nach oben
       Version: Office 2003

okay, ich habe ein wenig rumgespielt. hier sind meine einstellungen

in der vorlage unter datei -> eigenschaften -> anpassen habe ich einen neuen eintrag definiert für test1, quelle = text1 (das ensprechende formularfeld in der vorlage) und analog für test2

das makro siehr so aus:
Code:

Sub AutoNew()
'
' ChangeFileOpenDirectory ("K:\testumgebung")
MsgBox ("Der eingestellte Pfad für das Speichern dieses Dokumentes ist: " & "K:\testumgebung")
End Sub
Sub FileSave()

    If ActiveDocument.Path = "" Then    'Falls Dokument noch nie gespeichert wurde
        FileSaveAs
        Exit Sub
    End If
    ActiveDocument.Save
End Sub
Sub FileSaveAs()

    Dim DocName As String

    With ActiveDocument
       DocName = .CustomDocumentProperties("test1") & _
        .CustomDocumentProperties("test2")
    End With

    With Dialogs(wdDialogFileSaveAs)
        .Name = DocName
        .Show
    End With
   
End Sub


der erste teil mit dem speicherpfad funktioniert prächtig, aber ein dateiname wird mir nicht vorgeschlagen...was ist da falsch?
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
26. Apr 2008, 13:39
Rufname:
Wohnort: Leipzig

AW: Dateiname unter Speichern Unter vorgeben - AW: Dateiname unter Speichern Unter vorgeben

Nach oben
       

Hallo Luzius,

der Code sieht eigentlich richtig aus Mr. Green Mit den Dokument Properties habe ich bisher noch nicht gearbeitet, deswegen ist mir nicht klar, warum das nicht funktionieren sollte. Wenn ein Default-Wert drin steht, sollte das gehen.

Alternativ kannst Du natürlich auch direkt den Inhalt der Formularfelder in eine Variable füllen und dann vorschlagen. Das geht sogar ziemlich gut, weil die Formularfelder einen Textmarkennamen haben, den man abgreifen kann, z. B.:
Code:
    Dim strName As String
   
    If ActiveDocument.FormFields.Count > 0 Then
        strName = ActiveDocument.FormFields("Text1").Result
        MsgBox strName
    End If

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Luzius
Gast


Verfasst am:
28. Apr 2008, 15:15
Rufname:

AW: Dateiname unter Speichern Unter vorgeben - AW: Dateiname unter Speichern Unter vorgeben

Nach oben
       

Hallo Lisa

Vielen Dank für die Antwort. ich werde es mal auf Deine Art versuchen und mich auf jeden Fall wieder melden

merci und gruss
Luzius
Luzius
Gast


Verfasst am:
28. Apr 2008, 15:35
Rufname:


AW: Dateiname unter Speichern Unter vorgeben - AW: Dateiname unter Speichern Unter vorgeben

Nach oben
       

ok, ich konnte das gerade eben ausprobieren. leider funktioniert das nicht so recht.
wenn ich in der textmarke keinen default-text drinhabe gaht es gar nicht, und wenn ich einen default text drinhabe, wird mir dieser in einer messagebox aufgeführt, aber das dokument kann nicht gespeichert werden.

es dürfte so oder so kein default wert drinstehen, da dieser von dokument zu dokument variiert.

das ziel wäre eben, einige solche formuarfelder zu haben die ausgefüllt werden und deren inhalt dann beim speichern automatisch als dateiname vorgeschlagen wird.

vielleicht geht das ja aber gar nicht?
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Word Serienbriefe: Serienbrief einzeln Speichern, benötige Marko 9 DannyD 226 05. Dez 2013, 20:08
nicki2 Serienbrief einzeln Speichern, benötige Marko
Keine neuen Beiträge Word Serienbriefe: Serienbrief einzeln speichern 14 Beda2603 6375 23. Sep 2013, 13:25
Gast_HS_AD Serienbrief einzeln speichern
Keine neuen Beiträge Word Serienbriefe: Serienbrief -> Speichern der einzelnen Dokumente pro Reco 14 Gaston 19871 11. Nov 2010, 10:49
Ryba Serienbrief -> Speichern der einzelnen Dokumente pro Reco
Keine neuen Beiträge Word Formate: Textfelder auf Format Zahl = 0 beim Speichern zurückgesetzt 0 wgs 709 22. Aug 2010, 16:35
wgs Textfelder auf Format Zahl = 0 beim Speichern zurückgesetzt
Keine neuen Beiträge Word Formate: Word 2007: Dokument als PDF speichern macht Probleme 1 Scanda 5188 17. Aug 2010, 11:10
G.O.Tuhls Word 2007: Dokument als PDF speichern macht Probleme
Keine neuen Beiträge Word Formate: Änderungen in Briefvorlage.dot speichern 1 MiLie 2128 21. März 2010, 12:45
MiLie Änderungen in Briefvorlage.dot speichern
Keine neuen Beiträge Word Formate: Word - Datei mit Datum und Uhrzeit im Dateiname abspeichern 7 Berzelmeier 13627 22. Jan 2009, 23:14
andruschs Word - Datei mit Datum und Uhrzeit im Dateiname abspeichern
Keine neuen Beiträge Word Formate: Spalten-Teilung des Textes in Formatvorlage speichern 2 poki 2151 25. Apr 2008, 13:54
poki Spalten-Teilung des Textes in Formatvorlage speichern
Keine neuen Beiträge Word Serienbriefe: Problem beim speichern mit INCLUDEPICTURE 7 häschen 3447 28. März 2008, 09:50
häschen Problem beim speichern mit INCLUDEPICTURE
Keine neuen Beiträge Word Formate: Referenz Querverweis nach Speichern nciht mehr vorhanden 0 Harry2300 1311 28. Aug 2007, 11:30
Harry2300 Referenz Querverweis nach Speichern nciht mehr vorhanden
Keine neuen Beiträge Word Serienbriefe: Dateiname für Bild in Serienbrief zusammensetzen 1 Gast 714 17. Jul 2007, 17:21
Betty2004 Dateiname für Bild in Serienbrief zusammensetzen
Keine neuen Beiträge Word Formate: Meta Schrift im Dok. speichern 1 Manu12 3036 27. Jun 2007, 20:42
Hübi Meta Schrift im Dok. speichern
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: HTML CSS