Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende
Gehe zu Seite 1, 2  Weiter
zurück: Werte in anderem Tabellenblatt in Formel verknüpfen weiter: Bitweise Verknüpfung in bedingter Formatierung ohne BITUND() Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Andy749
Im Profil kannst Du frei den Rang ändern


Verfasst am:
02. Jul 2013, 10:29
Rufname:

Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Hallo liebes Forum,

habt Ihr evtl. eine Lösung für mein Problem?

In Zelle A2 habe ich das Startdatum in dem Format: 12.02.2013 15:36:25.
In Zelle B2 habe ich das Enddatum in dem Format: 22.04.2013 11:57:34

In Zelle C2 bräuchte ich nun das Ergebnis. Wie lange dauerte der Prozess? Unter Berücksichtigung von: Wochenende (Samstag, Sonntag, hier wird gar nicht gearbeitet); Feiertagen und Arbeitszeiten von (6:00 Uhr bis 18:00 Uhr)

Weiß jemand von euch Rat? LG
lupo1
Tüftler und {}-Sympathisant


Verfasst am:
02. Jul 2013, 10:52
Rufname:


AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

 ABCDEFGHI
1StartEndeTag 1Tag Ndazwischen WTWT FeiertageAbzug FTErgebnisin einer Formel
212.02.2013 15:3622.04.2013 11:5702:23:3505:57:34576:00:0001.01.201336:00:00548:21:09548:21:09
3     27.03.2013   
4     04.04.2013   
5     05.04.2013   

ZelleFormel
C2="18:"-REST(A2;1)
D2=REST(B2;1)-"6:"
E2=SUMMENPRODUKT(--(REST(ZEILE(INDIREKT(KÜRZEN(B2-1)&":"&AUFRUNDEN(A2;0)));7)>1))/2
G2=SUMMENPRODUKT((A2<$F$2:$F$5)*(B2-1>$F$2:$F$5))/2
H2=C2+D2+E2-G2
I2="18:"-REST(A2;1)+REST(B2;1)-"6:"+SUMMENPRODUKT(--(REST(ZEILE(INDIREKT(KÜRZEN(B2-1)&":"&AUFRUNDEN(A2;0)));7)>1))/2-SUMMENPRODUKT((A2<$F$2:$F$5)*(B2-1>$F$2:$F$5))/2

Bei den Feiertagen sorgst Du selbst dafür, dass nur Werktags-Feiertage aufgenommen sind (hier: Fantasie-Feiertage-Liste)

Achtung: In G2 und I2 muss es "KÜRZEN(B2)>" statt "B2-1>" heißen - wollte den Code nicht noch mal posten.

_________________
MfG Lupo - 11.10.2012-> {MSO 2000 SP3;Win 7} - 28.02.2013-> {MSO 2010;Win 8.1} (beide vorhanden)
Andy749
Im Profil kannst Du frei den Rang ändern


Verfasst am:
02. Jul 2013, 16:15
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Hallo lupo1,

zunächst einmal vielen Dank für die schnelle Antwort. Sehr elegant die Formel! Die Ergebniszelle habe ich mit [hh]:mm:ss formatiert und es funktioniert.

Allerdings funktioniert das jetzt nur mit dem Beispiel von heute Morgen.
Ein anderes Beispiel funktioniert nicht!
23.05.2013 14:43:28
23.05.2013 15:59:44

Als Netto-Bearbeitungszeit erhalte ich mit Deiner Formel allerdings 49:16:16.
lupo1
Tüftler und {}-Sympathisant


Verfasst am:
02. Jul 2013, 16:34
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Erst mal vielen Dank fürs Testen!

Der Grund für den Fehler liegt darin,

a) dass das erste SUMMENPRODUKT für Dein Beispiel von 22 bis 24 rechnet, statt gar nicht, ergibt 36: von den 48: falschen Stunden.

b) Und auch der erste und zweite Term wird gerechnet, obwohl er es nicht dürfte: ergibt die fehlenden 12: zu den 48: falschen Stunden.

Nachstehend die Korrektur für die Formel in I2 (die anderen kannst Du entsprechend selbst anpassen). Weitere Fehler nicht ausgeschlossen!

I2: =MIN(B2-A2;1/2-REST(A2;1)+REST(B2;1))+(B2-2>A2)*SUMMENPRODUKT(--(REST(ZEILE(INDIREKT(KÜRZEN(B2-1)&":"&AUFRUNDEN(A2;0)));7)>1))/2-SUMMENPRODUKT((A2<$F$2:$F$5)*(B2-1>$F$2:$F$5))/2

_________________
MfG Lupo - 11.10.2012-> {MSO 2000 SP3;Win 7} - 28.02.2013-> {MSO 2010;Win 8.1} (beide vorhanden)
Zero
Formeln, Diagramme und ein bisschen VBA


Verfasst am:
02. Jul 2013, 16:35
Rufname: Dennis
Wohnort: NDS


AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Hallo

Hier noch mal ne andere Formel..

 ABCDE
1SEDauer FT
212.02.2013 15:3622.04.2013 11:57548:21:00 01.01.2013
323.05.2013 14:4323.05.2013 15:5901:16:16 27.03.2013
4    04.04.2013
5    05.04.2013

ZelleFormel
C2=(NETTOARBEITSTAGE(A2;B2;E$2:E$5)-2)*1/2+MAX(;REST(B2;1)-1/4)+MAX(;3/4-REST(A2;1))
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

_________________
Gruß zero
lupo1
Tüftler und {}-Sympathisant


Verfasst am:
02. Jul 2013, 16:40
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Stimmt, NETTOARBEITSTAGE war für mich alten xl2000-User immer Add-In-verdächtig, aber mittlerweile darf man so was wohl verwenden, wo wir nun die 3. Excel-Version nach dem Ende des xl4-Mdells haben (2007, 2010, 365) Very Happy Bestimmt hat auch WF nichts mehr dagegen ...
_________________
MfG Lupo - 11.10.2012-> {MSO 2000 SP3;Win 7} - 28.02.2013-> {MSO 2010;Win 8.1} (beide vorhanden)
Andy749
Im Profil kannst Du frei den Rang ändern


Verfasst am:
02. Jul 2013, 16:44
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

16.01.2013 06:22:27
16.01.2013 15:31:58

Für diese Werte schmeißt er mit WAHR aus.
lupo1
Tüftler und {}-Sympathisant


Verfasst am:
02. Jul 2013, 16:46
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

 ABCD
1StartEndeWT Feiertagein einer Formel
216.01.2013 06:2216.01.2013 15:3101.01.20139:09:31
3  27.03.2013 
4  04.04.2013 
5  05.04.2013 

ZelleFormel
D2=MIN(B2-A2;1/2-REST(A2;1)+REST(B2;1))+(B2-2>A2)*SUMMENPRODUKT(--(REST(ZEILE(INDIREKT(KÜRZEN(B2-1)&":"&AUFRUNDEN(A2;0)));7)>1))/2-SUMMENPRODUKT((A2<$C$2:$C$5)*(B2-1>$C$2:$C$5))/2

_________________
MfG Lupo - 11.10.2012-> {MSO 2000 SP3;Win 7} - 28.02.2013-> {MSO 2010;Win 8.1} (beide vorhanden)
Zero
Formeln, Diagramme und ein bisschen VBA


Verfasst am:
02. Jul 2013, 16:47
Rufname: Dennis
Wohnort: NDS

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

..willst dich nicht von trennen, wa? Very Happy
_________________
Gruß zero
lupo1
Tüftler und {}-Sympathisant


Verfasst am:
02. Jul 2013, 16:49
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Wusste ja nicht, ob er mich meint, oder Dich Smile Daher wenigstens mal getestet - und da funktionierend, eben gepostet.
_________________
MfG Lupo - 11.10.2012-> {MSO 2000 SP3;Win 7} - 28.02.2013-> {MSO 2010;Win 8.1} (beide vorhanden)
Andy749
Im Profil kannst Du frei den Rang ändern


Verfasst am:
10. Jul 2013, 08:58
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Super, vielen lieben Dank erstmal hierfür! Alles funktioniert einfach super!

Wäre es denn auch möglich, bei bestehendem Format folgende Kriterien zu berücksichtigen?

Es sind weiterhin Start und Enddatum in dem anfangs beschriebenen Format vorhanden. Allerdings sollten nun nur die Wochenenden und Feiertage berücksichtigt werden und die Zeit zwischen Start und Ende sollte in Stunden und Minuten erfolgen.

Für eure Hilfe wäre ich sehr dankbar!

Viele Grüße!
lupo1
Tüftler und {}-Sympathisant


Verfasst am:
10. Jul 2013, 09:59
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

WE und FT 6:-18: oder 0:-24:? Du solltest schon genau sagen, was Du willst.
_________________
MfG Lupo - 11.10.2012-> {MSO 2000 SP3;Win 7} - 28.02.2013-> {MSO 2010;Win 8.1} (beide vorhanden)
Andy749
Im Profil kannst Du frei den Rang ändern


Verfasst am:
10. Jul 2013, 10:07
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Alle Wochenenden und Feiertage raus und Montags bis Freitags 0 - 24.
lupo1
Tüftler und {}-Sympathisant


Verfasst am:
10. Jul 2013, 10:12
Rufname:

AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Noch einmal zu meiner Formel:

=MIN(B2-A2;1/2-REST(A2;1)+REST(B2;1)) zählt ersten und letzten Tag

+(B2-2>A2)*SUMMENPRODUKT(--(REST(ZEILE(INDIREKT(KÜRZEN(B2-1)&":"&AUFRUNDEN(A2;0)));7)>1))/2 zählt die Tage dazwischen ohne Wochenenden (>1) (hier: addiert sie dazu). Entsprechend zählt (<2) nur die Wochenenden (Komplement)!

-SUMMENPRODUKT((A2<$C$2:$C$5)*(B2-1>$C$2:$C$5))/2 zählt die Feiertage (hier: zieht sie ab)

Die Stunden- und Minutenausgabe erledigst Du bitte selbst mittels Multiplikation oder mit Formatierung oder mit TEXT().

_________________
MfG Lupo - 11.10.2012-> {MSO 2000 SP3;Win 7} - 28.02.2013-> {MSO 2010;Win 8.1} (beide vorhanden)
Gast



Verfasst am:
10. Jul 2013, 11:00
Rufname:


AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende - AW: Nettoarbeitszeit mit festen Arbeitszeiten und Wochenende

Nach oben
       Version: Office 2010

Für die Daten

von: 19.03.2013 14:53:02
bis: 20.03.2013 15:14:34

erhalte ich mit der Formel

=MIN(B2-A2;1/2-REST(A2;1)+REST(B2;1))+(B2-2>A2)*SUMMENPRODUKT(--(REST(ZEILE(INDIREKT(KÜRZEN(B2-1)&":"&AUFRUNDEN(A2;0)));7)>1))/2-SUMMENPRODUKT((A2<$C$2:$C$5)*(B2-1>$C$2:$C$5))/2

eine Differenz von:

12:21:32
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Formel ändern Arbeitszeiten 1 Wichtelwichtig 180 28. Apr 2010, 23:26
wichtelwichtig Formel ändern Arbeitszeiten
Keine neuen Beiträge Excel Formeln: Arbeitszeiten Nachtschicht... ein Neuer braucht Hilfe 1 BeeEmWee 927 25. Feb 2010, 13:31
neopa Arbeitszeiten Nachtschicht... ein Neuer braucht Hilfe
Keine neuen Beiträge Excel Formeln: WENN Fkt. bzgl Wochenende/Wochentage 1 Bianca80 307 02. Nov 2009, 14:59
Smartie256 WENN Fkt. bzgl Wochenende/Wochentage
Keine neuen Beiträge Excel Formeln: Formel kopieren mit 1 festen und 1 variablen Wert 1 Steffi_1st 1108 15. Apr 2009, 14:56
silex1 Formel kopieren mit 1 festen und 1 variablen Wert
Keine neuen Beiträge Excel Formeln: Unterschied von Arbeitszeiten 0 Franz_ST 305 27. Jan 2009, 00:35
Franz_ST Unterschied von Arbeitszeiten
Keine neuen Beiträge Excel Formeln: Arbeitszeiten addieren 2 matthias_123 1603 26. Nov 2008, 14:33
matthias_123 Arbeitszeiten addieren
Keine neuen Beiträge Excel Formeln: Von allen Zellen einer Spalte einen festen Wert subtrahieren 7 silver_and_gold 6720 10. Nov 2008, 15:19
silver_and_gold Von allen Zellen einer Spalte einen festen Wert subtrahieren
Keine neuen Beiträge Excel Formeln: Nettoarbeitszeit Ausgangsdatum+Arbeitstage 6 Dirk1810 1007 29. Jul 2008, 20:29
Dirk1810 Nettoarbeitszeit Ausgangsdatum+Arbeitstage
Keine neuen Beiträge Excel Formeln: kurzzeichen für Arbeitszeiten 2 calle 495 24. Apr 2008, 13:52
Gast kurzzeichen für Arbeitszeiten
Keine neuen Beiträge Excel Formeln: Datumsberechnung ohne Wochenende und evtl. ohne Feiertage! 1 Rookie25 5479 13. März 2008, 12:43
ae Datumsberechnung ohne Wochenende und evtl. ohne Feiertage!
Keine neuen Beiträge Excel Formeln: Arbeitszeiten erfassen für serienbrief 4 Bernd43 512 15. Dez 2007, 13:54
Burny66 Arbeitszeiten erfassen für serienbrief
Keine neuen Beiträge Excel Formeln: Excel - Ausrechnen Datum ohne Wochenende! 1 Debbi69 4380 29. Nov 2007, 12:03
< Peter > Excel - Ausrechnen Datum ohne Wochenende!
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Frontpage Forum