Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Daten mit VBA aktualisieren doppelte Schleife?
zurück: Kürzere Variante um Zellenwert in Tabelle zu ändern weiter: Combobox, Listindex verschiebt sich Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Baudi
Im Profil kannst Du frei den Rang ändern


Verfasst am:
28. Okt 2013, 20:37
Rufname:

Daten mit VBA aktualisieren doppelte Schleife? - Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Hallo Zusammen,

ich habe ein kleines Problem ich möchte Daten im meiner Excel Tabelle aktualisieren bzw. neu Hinzufügen falls der Auftrag noch nicht vorhanden ist. Leider komme ich da nicht weiter, ich hoffe es kann mir jemand Weiterhelfen. Bin leider noch nicht so Fit in VBA und für jede Hilfe Dankbar.

Das Makro soll folgendes tun:

Wenn der Wert (ab der Zeile4) in derTabelle2.Range(„D“ & Zeile_der_Tabelle2) = Tabelle4.Range(„D“ & Zeile_der_Tabelle4) ist dann soll die Zeile ab der Spalte „I“ bis „BM“ von der Tabelle4 in der Tabelle2 ersetzt werden. Außer in der Tabelle4.Range(„A“ & Zeile_der_Tabelle4) ist der Wert = „**“, dann sollen nur die Werte von „J“ bis „BM“ ersetzt werden.

Sonst soll die Koppelte Zeile aus Tabelle4 am Ende der Tabelle2 eingefügt werden.


Muss ich hier eine Schleife in einer Schleife programmieren?
Wenn ich zweimal den Befehl „For“ verwende bekomme ich immer einen Fehler?

Gruß
Baudi
Phelan XLPH
Fortgeschritten


Verfasst am:
28. Okt 2013, 21:29
Rufname: Phelan


AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Hallo,

eine Möglichkeit...

Option Explicit

Code:
Sub xlph()
    Dim cvarItem As Variant
    Dim lngIndex As Long
    Dim objUnique As Object
    Dim lngIndexSource As Long
   
    Dim wksSource As Worksheet
    Dim wksTarget As Worksheet
   
    Set wksSource = Tabelle4
    Set wksTarget = Tabelle2
   
    Set objUnique = CreateObject("scripting.dictionary")
   
    With wksSource
        With Intersect(.UsedRange.Offset(1), .Range("D4:D" & .Rows.Count))
            lngIndex = .Row - 1
            For Each cvarItem In .Value
                lngIndex = lngIndex + 1
                If Not IsEmpty(cvarItem) Then
                    objUnique(cvarItem) = lngIndex
                End If
            Next
        End With
    End With
   
    With wksTarget
        With Intersect(.UsedRange.Offset(1), .Range("D4:D" & .Rows.Count))
            lngIndex = .Row - 1
            For Each cvarItem In .Value
                lngIndex = lngIndex + 1
                If Not IsEmpty(cvarItem) Then
                    If objUnique.Exists(cvarItem) Then
                        lngIndexSource = objUnique(cvarItem)
                        If wksSource.Range("A" & lngIndexSource) = "**" Then
                            wksTarget.Range("J" & lngIndex & ":BM" & lngIndex).Value = _
                            wksSource.Range("J" & lngIndexSource & ":BM" & lngIndexSource).Value
                        Else
                            wksTarget.Range("I" & lngIndex & ":BM" & lngIndex).Value = _
                            wksSource.Range("I" & lngIndexSource & ":BM" & lngIndexSource).Value
                        End If
                    End If
                End If
            Next
        End With
    End With
   
    Set wksSource = Nothing
    Set wksTarget = Nothing
   
    Set objUnique = Nothing
   
End Sub

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
Baudi
Im Profil kannst Du frei den Rang ändern


Verfasst am:
28. Okt 2013, 21:36
Rufname:

AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Hallo Phelan,
vielen Dank für Deine schnelle Hilfe.

Leide bekomme ich immer einen Fehler beim Ausführen :
„Objektvariable oder With-blockvariable nicht festgelegt“
In der Zeile:
lngIndex = .Row - 1

Nach dem:
With wksTarget
With Intersect(.UsedRange.Offset(1), .Range("D4:D" & .Rows.Count))
Phelan XLPH
Fortgeschritten


Verfasst am:
29. Okt 2013, 00:17
Rufname: Phelan

AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Code:
Sub xlph()
    Dim cvarItem As Variant
    Dim lngIndex As Long
    Dim objUnique As Object
    Dim lngIndexSource As Long
   
    Dim wksSource As Worksheet
    Dim wksTarget As Worksheet
   
    Dim rngVektor As Range
   
    Set wksSource = Tabelle4
    Set wksTarget = Tabelle2
   
    Set objUnique = CreateObject("scripting.dictionary")
   
    With wksSource
        Set rngVektor = Intersect(Range(.Cells(1), .UsedRange.Offset(1).EntireRow), .Range("D4:D" & .Rows.Count))
        If rngVektor Is Nothing Then
            MsgBox "Keine Daten in Quelle: " & vbLf & vbLf & "  >>  " & _
                    .Range("D:D").Address(, , , 1), , "Abbruch!"
            Exit Sub
        End If
        With rngVektor
            lngIndex = .Row - 1
            For Each cvarItem In .Value
                lngIndex = lngIndex + 1
                If Not IsEmpty(cvarItem) Then
                    objUnique(cvarItem) = lngIndex
                End If
            Next
        End With
    End With
   
    With wksTarget
        Set rngVektor = Intersect(Range(.Cells(1), .UsedRange.Offset(1).EntireRow), .Range("D4:D" & .Rows.Count))
        If rngVektor Is Nothing Then
            MsgBox "Keine Daten in Ziel: " & vbLf & vbLf & "  >>  " & _
                    .Range("D:D").Address(, , , 1), , "Abbruch!"
            Exit Sub
        End If
        With rngVektor
            lngIndex = .Row - 1
            For Each cvarItem In .Value
                lngIndex = lngIndex + 1
                If Not IsEmpty(cvarItem) Then
                    If objUnique.Exists(cvarItem) Then
                        lngIndexSource = objUnique(cvarItem)
                        If wksSource.Range("A" & lngIndexSource).Value = "**" Then
                            wksTarget.Range("J" & lngIndex & ":BM" & lngIndex).Value = _
                            wksSource.Range("J" & lngIndexSource & ":BM" & lngIndexSource).Value
                        Else
                            wksTarget.Range("I" & lngIndex & ":BM" & lngIndex).Value = _
                            wksSource.Range("I" & lngIndexSource & ":BM" & lngIndexSource).Value
                        End If
                    End If
                End If
            Next
        End With
    End With
   
    Set wksSource = Nothing
    Set wksTarget = Nothing
   
    Set objUnique = Nothing
   
End Sub

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
Baudi
Im Profil kannst Du frei den Rang ändern


Verfasst am:
29. Okt 2013, 04:26
Rufname:


AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Hallo Phelan,

vielen Dank, jetzt habe ich auch verstanden warum das gerade nicht ging.
Leider habe ein meine Probleme den Code zu verstehen.
Mir ist gerade noch ein Fehler aufgefallen, da es die Auftrags Nr. in der Spalte „D“ mehrfacht gibt wirft das Makro mir alles durcheinander. Es müsste zusätzlich zur Spalte „D“ auch die Spalte „E“ (Auftrags POS.) abgeglichen werden.

Muss ich die Erweiterung dann in die Zeile schreiben?
Set rngVektor = Intersect(Range(.Cells(1), .UsedRange.Offset(1).EntireRow), .Range("D4:D" & .Rows.Count))

Kann man das Makro noch um die Funktion Erweitern:
Wenn der Auftrag in der Tabelle2 nicht vorhanden ist, dann soll er den komplett aus der Tabelle 4 übernehmen.

Bitte Entschuldige das ich so viel Frage, aber ich bin zurzeit noch ein blutiger Anfänger und muss erstmal nachvollziehen wie das Makro funktioniert.
Phelan XLPH
Fortgeschritten


Verfasst am:
29. Okt 2013, 10:44
Rufname: Phelan

AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Hallo,

hier eine einfachere Variante mit Beschreibung und Datei.

Code:
Option Explicit

Sub xlph()
   
    Dim lngIndex As Long
    Dim strID As String
   
    Dim objUnique As Object
    Dim lngIndexSource As Long
   
    Dim wksSource As Worksheet
    Dim wksTarget As Worksheet
   
    ' Objektvariablen füllen
    Set wksSource = Tabelle4
    Set wksTarget = Tabelle2
   
    ' Das Dictionary-Objekt speichert Elementen-Paare
    ' Ein Paar besteht aus einem Schlüssel (Key) und einem,
    ' dem Schlüssel zugewiesenen Wert (Item)
    ' Syntax allgemein: Dictionary(Schlüssel) = Wert
    ' Syntax hier: objUnique('ID') = Zeilennummer
    Set objUnique = CreateObject("scripting.dictionary")
   
    ' Quell-Arbeitsblatt
    With wksSource
       
        ' Spalte D durchlaufen ab Zeile 4 bis letzte ermittelte Zeile in Spalte D
        For lngIndex = 4 To .Cells(.Rows.Count, 4).End(xlUp).Row
            ' Wert in Spalte D mit Wert in Spalte E und einem Tab zur 'ID' verketten
            strID = .Cells(lngIndex, 4).Value & vbTab & .Cells(lngIndex, 5).Value
            ' Prüfen ob 'ID' einen Wert enthält
            If strID <> vbNullString Then
                ' 'ID' als Schlüssel speichern mit dem Wert des Zeilen-Indizes
                objUnique(strID) = lngIndex
            End If
        Next
                       
    End With
   
   
    ' Ziel-Arbeitsblatt
    With wksTarget
       
        ' Spalte D durchlaufen ab Zeile 4 bis letzte ermittelte Zeile in Spalte D
        For lngIndex = 4 To .Cells(.Rows.Count, 4).End(xlUp).Row
            ' Wert in Spalte D mit Wert in Spalte E und einem Tab zur 'ID' verketten
            strID = .Cells(lngIndex, 4).Value & vbTab & .Cells(lngIndex, 5).Value
            ' Prüfen ob 'ID' einen Wert enthält
            If strID <> vbNullString Then
                ' Prüfen ob 'ID' (Schlüssel) vorhanden ist
                If objUnique.Exists(strID) Then
                    ' Auslesen der Zeilennummer für Werte-Übertragung
                    lngIndexSource = objUnique(strID)
                    ' Prüfen ob in Spalte A in Quell-Arbeitsblatt '**' steht
                    If wksSource.Range("A" & lngIndexSource).Value = "**" Then
                        ' Werte von Spalte J-BM von Quell-Arbeitsblatt
                        ' in Spalte J-BM in Ziel-Arbeitsblatt übertragen
                        .Range("J" & lngIndex).Resize(1, 56).Value = _
                        wksSource.Range("J" & lngIndexSource).Resize(1, 56).Value
                    Else
                        ' Werte von Spalte I-BM von Quell-Arbeitsblatt
                        ' in Spalte I-BM in Ziel-Arbeitsblatt übertragen
                        .Range("I" & lngIndex).Resize(1, 57).Value = _
                        wksSource.Range("I" & lngIndexSource).Resize(1, 57).Value
                    End If
                End If
            End If
        Next
       
    End With
   
    ' Objekt-Variblen zerstören
    Set wksSource = Nothing
    Set wksTarget = Nothing
    Set objUnique = Nothing
   
End Sub

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein



Baudi Abgleich.xlsm
 Beschreibung:

Download
 Dateiname:  Baudi Abgleich.xlsm
 Dateigröße:  24.68 KB
 Heruntergeladen:  23 mal

Baudi
Im Profil kannst Du frei den Rang ändern


Verfasst am:
29. Okt 2013, 20:04
Rufname:

AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Hallo,
vielen Dank, für Deine Hilfe weiß gar nicht wie ich das wieder gut machen kann, bei der Mühe die du dir gemacht hast.
Baudi
Im Profil kannst Du frei den Rang ändern


Verfasst am:
01. Nov 2013, 16:26
Rufname:

AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Hallo,

ich versuche jetzt schon seit längerem dein Makro noch so umzuschreiben, dass er prüft ob die Auftrags Nr. in Tabelle4 Spalte „D“ und die Pos. Nr. in Tabelle4 Spalte „E“ schon in der Tabelle 2 Spalte „D“ und „E“ vorhanden ist. Wenn nicht kopiere die Zeile aus Tabelle4 (von „A“ – „BM“) am Ende von Tabelle2.

Ich habe das so versucht leider ohne Erfolg.

Ich hoffe du kannst mir noch ein letztes Mal helfen ;)

Code:

Sub aktualisieren2()

   
    Dim lngIndex As Long
    Dim strID As String
   
    Dim objUnique As Object
    Dim lngIndexSource As Long
   
    Dim wksSource As Worksheet
    Dim wksTarget As Worksheet
   
    Dim ZeileMax As Long
   
    ' Objektvariablen füllen
    Set wksSource = Tabelle4
    Set wksTarget = Tabelle2
   
    ' Das Dictionary-Objekt speichert Elementen-Paare
    ' Ein Paar besteht aus einem Schlüssel (Key) und einem,
    ' dem Schlüssel zugewiesenen Wert (Item)
    ' Syntax allgemein: Dictionary(Schlüssel) = Wert
    ' Syntax hier: objUnique('ID') = Zeilennummer
    Set objUnique = CreateObject("scripting.dictionary")
   
    ' Quell-Arbeitsblatt
    With wksSource
       
        ' Spalte D durchlaufen ab Zeile 4 bis letzte ermittelte Zeile in Spalte D
        For lngIndex = 4 To .Cells(.Rows.Count, 4).End(xlUp).Row
            ' Wert in Spalte D mit Wert in Spalte E und einem Tab zur 'ID' verketten
            strID = .Cells(lngIndex, 4).Value & vbTab & .Cells(lngIndex, 5).Value
            ' Prüfen ob 'ID' einen Wert enthält
            If strID <> vbNullString Then
                ' 'ID' als Schlüssel speichern mit dem Wert des Zeilen-Indizes
                objUnique(strID) = lngIndex
            End If
        Next
                       
    End With
   
   
    ' Ziel-Arbeitsblatt
    With wksTarget
       
       ZeileMax = .UsedRange.Rows.Count
       
        ' Spalte D durchlaufen ab Zeile 4 bis letzte ermittelte Zeile in Spalte D
        For lngIndex = 4 To .Cells(.Rows.Count, 4).End(xlUp).Row
            ' Wert in Spalte D mit Wert in Spalte E und einem Tab zur 'ID' verketten
            strID = .Cells(lngIndex, 4).Value & vbTab & .Cells(lngIndex, 5).Value
            ' Prüfen ob 'ID' einen Wert enthält
            If strID <> vbNullString Then
                ' Prüfen ob 'ID' (Schlüssel) vorhanden ist
                If objUnique.Exists(strID) Then
                    ' Auslesen der Zeilennummer für Werte-Übertragung
                    lngIndexSource = objUnique(strID)
                    Else
                        .Range("A" & lngIndex).Resize(1, 66).Value = _
                        wksSource.Range("A" & ZeileMax + 1).Resize(1, 66).Value
                   
                    End If
                End If
           
        Next
       
    End With
   
    ' Objekt-Variblen zerstören
    Set wksSource = Nothing
    Set wksTarget = Nothing
    Set objUnique = Nothing
   
End Sub


Phelan XLPH
Fortgeschritten


Verfasst am:
01. Nov 2013, 20:27
Rufname: Phelan

AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Ganz einfach:

Code:
Sub xlph()
   
    Dim lngIndex As Long
    Dim strID As String
    Dim lngUniqueIndex As Long
   
    Dim objUnique As Object
    Dim cvarUnique As Variant
    Dim lngIndexSource As Long
   
    Dim wksSource As Worksheet
    Dim wksTarget As Worksheet
   
    ' Objektvariablen füllen
    Set wksSource = Tabelle4
    Set wksTarget = Tabelle2
   
    ' Das Dictionary-Objekt speichert Elementen-Paare
    ' Ein Paar besteht aus einem Schlüssel (Key) und einem,
    ' dem Schlüssel zugewiesenen Wert (Item)
    ' Syntax allgemein: Dictionary(Schlüssel) = Wert
    ' Syntax hier: objUnique('ID') = Zeilennummer
    Set objUnique = CreateObject("scripting.dictionary")
   
    ' Quell-Arbeitsblatt
    With wksSource
       
        ' Spalte D durchlaufen ab Zeile 4 bis letzte ermittelte Zeile in Spalte D
        For lngIndex = 4 To .Cells(.Rows.Count, 4).End(xlUp).Row
            ' Wert in Spalte D mit Wert in Spalte E und einem Tab zur 'ID' verketten
            strID = .Cells(lngIndex, 4).Value & vbTab & .Cells(lngIndex, 5).Value
            ' Prüfen ob 'ID' einen Wert enthält
            If strID <> vbNullString Then
                ' 'ID' als Schlüssel speichern mit dem Wert des Zeilen-Indizes
                objUnique(strID) = lngIndex
            End If
        Next
                       
    End With
   
   
    ' Ziel-Arbeitsblatt
    With wksTarget
       
        ' Spalte D durchlaufen ab Zeile 4 bis letzte ermittelte Zeile in Spalte D
        For lngIndex = 4 To .Cells(.Rows.Count, 4).End(xlUp).Row
            ' Wert in Spalte D mit Wert in Spalte E und einem Tab zur 'ID' verketten
            strID = .Cells(lngIndex, 4).Value & vbTab & .Cells(lngIndex, 5).Value
            ' Prüfen ob 'ID' einen Wert enthält
            If strID <> vbNullString Then
                ' Prüfen ob 'ID' (Schlüssel) vorhanden ist
                If objUnique.Exists(strID) Then
                    ' Auslesen der Zeilennummer für Werte-Übertragung
                    lngIndexSource = objUnique(strID)
                    ' Prüfen ob in Spalte A in Quell-Arbeitsblatt '**' steht
                    If wksSource.Range("A" & lngIndexSource).Value = "**" Then
                        ' Werte von Spalte J-BM von Quell-Arbeitsblatt
                        ' in Spalte J-BM in Ziel-Arbeitsblatt übertragen
                        .Range("J" & lngIndex).Resize(1, 56).Value = _
                        wksSource.Range("J" & lngIndexSource).Resize(1, 56).Value
                    Else
                        ' Werte von Spalte I-BM von Quell-Arbeitsblatt
                        ' in Spalte I-BM in Ziel-Arbeitsblatt übertragen
                        .Range("I" & lngIndex).Resize(1, 57).Value = _
                        wksSource.Range("I" & lngIndexSource).Resize(1, 57).Value
                    End If
                    ' Entferne Elementen-Paar
                    objUnique.Remove (strID)
                End If
            End If
        Next
       
        ' Letzte gefüllte Zeile in Spalte D von Ziel-Blatt ermitteln
        lngIndex = .Cells(.Rows.Count, 4).End(xlUp).Row
       
        ' Verbleibende Elementen-Paare durchlaufen und in Ziel-Tabelle eintragen
        For Each cvarUnique In objUnique.Keys
            ' Ziel-Zeile um 1 erhöhen
            lngIndex = lngIndex + 1
            ' Auslesen der Zeilennummer für Werte-Übertragung
            lngIndexSource = objUnique(cvarUnique)
            ' Werte von Spalte A-BM von Quell-Arbeitsblatt
            ' in Spalte A-BM in Ziel-Arbeitsblatt übertragen
            .Range("A" & lngIndex).Resize(1, 65).Value = _
            wksSource.Range("A" & lngIndexSource).Resize(1, 65).Value
        Next
       
    End With
   
    ' Objekt-Variblen zerstören
    Set wksSource = Nothing
    Set wksTarget = Nothing
    Set objUnique = Nothing
   
End Sub

_________________
Was vorstellbar ist, ist auch machbar. - Albert Einstein
Baudi
Im Profil kannst Du frei den Rang ändern


Verfasst am:
02. Nov 2013, 19:28
Rufname:


AW: Daten mit VBA aktualisieren doppelte Schleife? - AW: Daten mit VBA aktualisieren doppelte Schleife?

Nach oben
       Version: Office 2010

Vielen Dank für Deine Hilfe, einfach ist das für mich noch nicht.
Ich muss da noch viel üben.
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Datumseinträge zählen ohne doppelte Vorkommen 15 User003 1793 11. Aug 2005, 12:19
Gast Datumseinträge zählen ohne doppelte Vorkommen
Keine neuen Beiträge Excel Formeln: Daten aus Tabelle durch key herausholen 11 User003 1309 26. Jul 2005, 11:20
Gast Daten aus Tabelle durch key herausholen
Keine neuen Beiträge Excel Formeln: Excel: Daten aus Spalte A in B übernehmen 2 cabot 1312 24. Mai 2005, 13:47
cabot Excel: Daten aus Spalte A in B übernehmen
Keine neuen Beiträge Excel Formeln: Daten aus anderem Tabellenblatt übernehmen 5 Grubi 2120 05. Mai 2005, 21:52
Grubi Daten aus anderem Tabellenblatt übernehmen
Keine neuen Beiträge Excel Formeln: daten in EINER zelle zusammenführen 1 thompson 807 23. Apr 2005, 18:13
fl618 daten in EINER zelle zusammenführen
Keine neuen Beiträge Excel Formeln: Abfrage Daten nach Zeitintervall 9 katz 1097 21. Apr 2005, 08:52
katz Abfrage Daten nach Zeitintervall
Keine neuen Beiträge Excel Formeln: Muß Daten kopieren mit Bezug auf mehrer Zeilen 3 Anke 1487 07. Apr 2005, 10:54
Anke Muß Daten kopieren mit Bezug auf mehrer Zeilen
Keine neuen Beiträge Excel Formeln: Doppelte Daten entfernen 1 Sabine1980 2206 08. Feb 2005, 18:19
Thomas Ramel Doppelte Daten entfernen
Keine neuen Beiträge Excel Formeln: Daten in einer Zelle trennen 2 bsailer 7161 07. Jan 2005, 13:39
bsailer Daten in einer Zelle trennen
Keine neuen Beiträge Excel Formeln: Daten aus Liste übernehmen und selektieren 1 Maggi 1695 06. Jan 2005, 02:21
Gast1 Daten aus Liste übernehmen und selektieren
Keine neuen Beiträge Excel Formeln: Nur Daten, die einen Betrag haben, sollen angezeigt werden 4 Kannu 691 21. Dez 2004, 15:57
Arnim Nur Daten, die einen Betrag haben, sollen angezeigt werden
Keine neuen Beiträge Excel Formeln: daten suchen 18 excelfinki 2799 17. Dez 2004, 11:34
excelfinki daten suchen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: PHP Forum