Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Makro - Gleiche Zahlenwerte durch dicken Unterstrich trennen
zurück: *T*AutoSumme??? weiter: Dropdown -> Anzeige anders als Wert Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Offen Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Devil024
Im Profil kannst Du frei den Rang ändern


Verfasst am:
16. Apr 2014, 17:24
Rufname:

Makro - Gleiche Zahlenwerte durch dicken Unterstrich trennen - Makro - Gleiche Zahlenwerte durch dicken Unterstrich trennen

Nach oben
       Version: Office 2013

Hey Community,


ich bräuchte mal die Hilfe von jemanden der sich mit VBA einigermaßen auskennt.
Ich habe folgendes Problem.
Ich habe eine Liste vorliegen in der unter anderem Nummern aufsteigend sortiert sind. Viele Nummern kommen doppelt vor, stehen durch das sortieren natürlich untereinander.
Nun möchte ich dass jeweils bei der "letzten" doppelten Nummer ein dicker Unterstrich gezogen wird, so dass am Ende alle Nummern durch einen Strich getrennt sind.
RPP63
ambitionierter Spätanfänger


Verfasst am:
17. Apr 2014, 08:59
Rufname:
Wohnort: mitten im Pott

AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre - AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre

Nach oben
       Version: Office 2013

Hallo!
Wenn die Linie nicht unbedingt dick sein muss, bietet sich natürlich die bedingte Formatierung an:

Arbeitsblatt mit dem Namen 'Tabelle1'
 A
11
21
31
41
52
62
73
83
93
103
113
124
135
145
155
166
177
187
197
208
218

Zellebedingte Formatierung...Format
A11: =A2>A1abc
A21: =A3>A2abc


(leider werden die Rahmen hier nicht angezeigt, deshalb ein Bildchen)



Da Excel leider immer noch nicht die Rahmendicke per bed.Form. einstellen kann, geht es tatsächlich nur per VBA!
Hier mal ein Beispiel:

Modul1
Option Explicit 
 
Sub DickeLinie() 
Dim Letzte As Long, Zeile As Long 
Dim Zelle As Range 
With Tabelle1 
    Letzte = .Cells(Rows.Count, 1).End(xlUp).Row 
    Application.ScreenUpdating = False 
    '"alte" Rahmen löschen 
    For Each Zelle In Intersect(.UsedRange, .Columns(1)) 
        Zelle.Borders(xlEdgeBottom).LineStyle = xlNone 
    Next 
    '"neue" Rahmen setzen 
    For Zeile = Letzte To 2 Step -1 
        If .Cells(Zeile, 1) <> .Cells(Zeile - 1, 1) Then 
            With .Cells(Zeile - 1, 1).Borders(xlEdgeBottom) 
                .LineStyle = xlContinuous 
                .Weight = xlThick 
            End With 
        End If 
    Next 
    Application.ScreenUpdating = True 
End With 
End Sub 


Ergibt:



Gruß, Ralf

_________________
besser spät als nie ...
Devil024
Im Profil kannst Du frei den Rang ändern


Verfasst am:
17. Apr 2014, 13:01
Rufname:

AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre - AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre

Nach oben
       Version: Office 2013

Genau das habe ich gesucht.
Um das Ganze zu verfeinern sollte der Strich einen bestimmten Bereich decken.
Das soll heißen:
In Spalte E (5) befindet sich die Nummer welche sortiert und mit unterstrich versehen wird. Der Unterstrich soll aber in der kompletten Zeile gezogen werden, von A bis K.
Wenn du das noch ergänzen könntest, das wäre super.
RPP63
ambitionierter Spätanfänger


Verfasst am:
18. Apr 2014, 08:26
Rufname:
Wohnort: mitten im Pott

AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre - AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre

Nach oben
       Version: Office 2013

Hallo!
Ich hatte gehofft, dass Du dies selbst kannst.
Ich habe noch eine Überschriftenzeile eingefügt, dadurch ändern sich einige Zahlen im Code.
Vorher:



Makro:
Modul1
Option Explicit 
 
Sub DickeLinie() 
Dim Letzte As Long, Zeile As Long 
Dim Zelle As Range 
With Tabelle1 
    Letzte = .Cells(Rows.Count, 5).End(xlUp).Row 
    Application.ScreenUpdating = False 
    '"alte" Rahmen löschen 
    For Each Zelle In Intersect(.UsedRange, .Range("A2:K" & Letzte)) 
        Zelle.Borders(xlEdgeBottom).LineStyle = xlNone 
    Next 
    '"neue" Rahmen setzen 
    For Zeile = Letzte + 1 To 3 Step -1 
        If .Cells(Zeile, 5) <> .Cells(Zeile - 1, 5) Then 
            With .Range("A" & Zeile - 1 & ":K" & Zeile - 1).Borders(xlEdgeBottom) 
                .LineStyle = xlContinuous 
                .Weight = xlThick 
            End With 
        End If 
    Next 
    Application.ScreenUpdating = True 
End With 
End Sub 


Nachher:



Gruß, Ralf

_________________
besser spät als nie ...
RPP63
ambitionierter Spätanfänger


Verfasst am:
18. Apr 2014, 08:48
Rufname:
Wohnort: mitten im Pott

AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre - AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre

Nach oben
       Version: Office 2013

... und wenn Du das Sortieren integrieren willst, erweitere das (nochmal überarbeitete) Makro wie folgt:
Modul1
Option Explicit 
 
Sub SortierenUndRahmenDickeLinie() 
Dim Letzte As Long, Zeile As Long 
Dim Zelle As Range 
Application.ScreenUpdating = False 
With Tabelle1 
    Letzte = .Cells(Rows.Count, 5).End(xlUp).Row 
    'sortieren nach Spalte E 
    .UsedRange.Sort Key1:=.Columns(5), Order1:=xlAscending, Header:=xlYes 
    With .Range("A2:K" & Letzte) 
        '"alte" Rahmen löschen 
        .Borders(xlEdgeBottom).LineStyle = xlNone 
        .Borders(xlInsideHorizontal).LineStyle = xlNone 
        '"neue" Rahmen setzen 
        .Borders(xlEdgeLeft).LineStyle = xlContinuous 
        .Borders(xlEdgeRight).LineStyle = xlContinuous 
        .Borders(xlInsideVertical).LineStyle = xlContinuous 
    End With 
    For Zeile = Letzte + 1 To 3 Step -1 
        If .Cells(Zeile, 5) <> .Cells(Zeile - 1, 5) Then 
            With .Range("A" & Zeile - 1 & ":K" & Zeile - 1).Borders(xlEdgeBottom) 
                .LineStyle = xlContinuous 
                .Weight = xlThick 
            End With 
        End If 
    Next 
End With 
Application.ScreenUpdating = True 
End Sub 


Dann könntest Du das Ganze per Schaltfläche aufrufen:
Microsoft Excel Objekt Tabelle1
Option Explicit 
 
Private Sub CommandButton1_Click() 
Call SortierenUndRahmenDickeLinie 
End Sub 


Gruß, Ralf

_________________
besser spät als nie ...
Devil024
Im Profil kannst Du frei den Rang ändern


Verfasst am:
28. Apr 2014, 10:52
Rufname:

AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre - AW: Makro - Gleiche Zahlenwerte durch dicken Unterstrich tre

Nach oben
       Version: Office 2013

Danke, das klappt super.
Ein letztes Anliegen hätte ich noch.
In Spalte I stehen Zahlen untereinander, diese sollen bis zum jeweiligen Unterstrich addiert werden und in Spalte K über dem Unterstrich ausgegeben werden.

Wenn du mir dabei noch helfen könntest wäre dies super!
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Datum von Zeit trennen 14 iceview 1403 09. Nov 2006, 22:53
iceview Datum von Zeit trennen
Keine neuen Beiträge Excel Formeln: Postfach von Strasse trennen und in neue Zelle verschieben 2 danilabi 1400 08. Nov 2006, 20:30
danilabi Postfach von Strasse trennen und in neue Zelle verschieben
Keine neuen Beiträge Excel Formeln: Werte in Zellen trennen 37 ggaribaldi 27108 30. Okt 2006, 18:38
Gast Werte in Zellen trennen
Keine neuen Beiträge Excel Formeln: Gleiche Zeilen kennzeichnen 12 Creator 577 26. Okt 2006, 06:53
< Peter > Gleiche Zeilen kennzeichnen
Keine neuen Beiträge Excel Formeln: Buchstaben und Zahlen trennen 6 ggaribaldi 13307 25. Okt 2006, 14:27
< Peter > Buchstaben und Zahlen trennen
Keine neuen Beiträge Excel Formeln: Makro mit Selection.AutoFill 2 GastAlex 3911 18. Okt 2006, 15:25
GastAlex Makro mit Selection.AutoFill
Keine neuen Beiträge Excel Formeln: Makro entfernen 4 Holger 996 979 07. Sep 2006, 09:29
brans Makro entfernen
Keine neuen Beiträge Excel Formeln: Bedingte Formatierung nicht drucken? (oder Makro?) 1 Gast 1223 23. Aug 2006, 13:46
Cabation Bedingte Formatierung nicht drucken? (oder Makro?)
Keine neuen Beiträge Excel Formeln: EXCEL - Vor- und Nachnamen trennen - edit <Peter> 5 Gast 11038 13. Jun 2006, 14:00
Tommy82 EXCEL - Vor- und Nachnamen trennen - edit <Peter>
Keine neuen Beiträge Excel Formeln: Aufeinanderfolgende gleiche Werte zählen 8 Katastrophenkarl 6387 30. Apr 2006, 08:22
RippleN Aufeinanderfolgende gleiche Werte zählen
Keine neuen Beiträge Excel Formeln: Makro durch Funktion starten 11 Borsty22 12858 01. Apr 2006, 18:35
Hübi Makro durch Funktion starten
Keine neuen Beiträge Excel Formeln: Verschiedene Tabellen, gleiche Zelle 3 schwingler 1813 29. März 2006, 07:26
schwingler Verschiedene Tabellen, gleiche Zelle
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: PHP Forum