Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Text ein.- bzw wieder ausblenden
Gehe zu Seite 1, 2  Weiter
zurück: Alle nicht angekreuzten Kontrollkästchen ausblenden weiter: Anlegung von Sicherheitskopien Word 2003 Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Gast



Verfasst am:
19. Mai 2006, 10:35
Rufname:

Text ein.- bzw wieder ausblenden - Text ein.- bzw wieder ausblenden

Nach oben
       

hallo an alle,

ich habe es geschafft, anhand eines kleinen makro eine Bankverbindung auf meinem briefpapier einzublenden. problem ist, habe ich sie einmal eingefügt, bekomme ich sie nicht mehr weg (außer durch schließen und erneutes öffnen der datei) ich würde also gerne einen button programieren, bei dem ich ein.- UND ausblenden kann. (sprich einmal klichen = einblenden … zweites mal klicken = wieder ausblenden. mein bisheriger code lautet so:


Sub Bankverbindung()

ActiveDocument.Unprotect Password:="password"

If ActiveDocument.Bookmarks.Exists("Bankverbindung") = True Then
Selection.GoTo What:=wdGoToBookmark, Name:="Bankverbindung"
Selection.TypeText Text:="Bankverbindung"
End If

ActiveDocument.Protect Password:="password", NoReset:=False, Type:= _
wdAllowOnlyFormFields

End Sub


bin über jeden lösungsvorschlag dankbar, denn solangsam treibt word mich in den wahnsinn. Smile

mfg andreas
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
19. Mai 2006, 10:44
Rufname:
Wohnort: Leipzig


AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo Andreas,

das geht besser anders: Du fügst die Bankverbindung an der entsprechenden Stelle ein und versiehst sie mit der Textmarke "Bankverbindung". Es sollte kein Formularfeld sein, sondern eine normale Textmarke. Dann wird mit diesem Makro die Bankverbindung entweder eingeblendet oder ausgeblendet. Dazu wird die Funktion "Ausblendeter Text" verwendet.
Code:
Sub Bankverbindung()

    If ActiveDocument.ProtectionType = wdAllowOnlyFormFields Then
        ActiveDocument.Unprotect Password:="password"
    End If

    If ActiveDocument.Bookmarks.Exists("Bankverbindung") Then
        If ActiveDocument.Bookmarks("Bankverbindung").Range.Font.Hidden = True Then
            ActiveDocument.Bookmarks("Bankverbindung").Range.Font.Hidden = False
        Else
            ActiveDocument.Bookmarks("Bankverbindung").Range.Font.Hidden = True
        End If
    End If

    ActiveDocument.Protect Password:="password", NoReset:=True, Type:= _
    wdAllowOnlyFormFields

End Sub

Noch darauf achten, dass unter Extras - Optionen - Ansicht die Option "Ausgeblendeter Text" deaktiviert ist.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Gast



Verfasst am:
19. Mai 2006, 11:11
Rufname:

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

juhu ... das ist genau die lösung die ich wollte. jetzt ist mein wochenende gerettet ;) wenn du mir jetzt noch sagen kannst wie ich dasselbe mit einem bild machen kann, dann hebe ich vor freude ab.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
19. Mai 2006, 11:18
Rufname:
Wohnort: Leipzig

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo Andreas,

das geht genauso. Füge das Bild ein. Markiere es und gib ihm einen Textmarkennamen über Einfügen - Textmarke. Nun sprichst du es genauso an wie deine Textmarke Bankverbindung - nur dass diese eben jetzt ein Bild enthält.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
Gast



Verfasst am:
19. Mai 2006, 11:36
Rufname:


AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

danke dir lisa, es läuft alles wie gewünscht. danke für die schnelle hilfe.
Gast



Verfasst am:
19. Mai 2006, 13:12
Rufname:

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

hallo lisa,

ein kleines problem gibt es jetzt doch. das bild rutscht immer mit auf seite zwei, sobald der text auf seite zwei geht. ich glaub das liegt daran, dass ich das bild im falschen abschnit liegen habe. habe leider keine ahnung wie ich das bild in ein anderen abschnit bekommen?!
Amtmann
Gast


Verfasst am:
03. Aug 2009, 11:45
Rufname:

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo noch einmal - und noch einmal danke für die Hilfe hier.

Das obige Makro habe ich für meine Zwecke ein wenig angepasst. Ich poste meine Variante mal, da sie etwas anders aufgebaut ist.

Es fehlt die Abfrage, ob bestimmte Textmarken überhaupt existieren. Das führt zu wilden Fehlermeldungen, wenn man Textmarken anspricht, die man nicht gesetzt hat, aber das finde ich eher positiv, da man so auf Fehler bspw. in der Benennung deutlich aufmerksam gemacht wird.

Das Dokument blendet abhängig von der ersten Checkbox
- zwei Textbereiche (EG_Vergabe_1 und _2) aus
- und einen anderen Textbereich (Nationale_Vergabe_1) ein.

Code:
Sub EG_Fragen_löschen()
'
' EG_Fragen_löschen Makro
' Makro erstellt am 03.08.2009 von mir
'
    If ActiveDocument.ProtectionType = wdAllowOnlyFormFields Then                   ' Dokument schreibgeschützt (Formular)?
        FormSchutz = True                                                           ' Falls ja:
        ActiveDocument.Unprotect                                                    ' Schreibschutz aufheben!
    End If

' Ein- und Ausblenden von Fragen für nationale und EG-Vergaben

    If ActiveDocument.FormFields("EG_Vergabe").CheckBox.Value = True Then           ' Ist der Haken in der Checkbox gesetzt?
          ActiveDocument.Bookmarks("EG_Vergabe_1").Range.Font.Hidden = False        ' Falls ja: Text anzeigen!
          ActiveDocument.Bookmarks("EG_Vergabe_2").Range.Font.Hidden = False        ' Falls ja: Text anzeigen!
          ActiveDocument.Bookmarks("Nationale_Vergabe_1").Range.Font.Hidden = True  ' Falls ja: Text verstecken!
    Else
          ActiveDocument.Bookmarks("EG_Vergabe_1").Range.Font.Hidden = True         ' Falls nein: Text verstecken!
          ActiveDocument.Bookmarks("EG_Vergabe_2").Range.Font.Hidden = True         ' Falls nein: Text verstecken!
          ActiveDocument.Bookmarks("Nationale_Vergabe_1").Range.Font.Hidden = False ' Falls ja: Text verstecken!
    End If

    If FormSchutz Then                                                              ' Schreibschutz wiederherstellen
        ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True           ' Schreibschutz wiederherstellen
    End If
End Sub
Amtmann
Gast


Verfasst am:
03. Aug 2009, 11:46
Rufname:

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

P. S.: Viel Spaß und Erfolg etwaigen Benutzern/Kopierern!
Gast



Verfasst am:
09. Jun 2010, 14:45
Rufname:

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo,

ich verstehe nur überhaupt nicht wie ich diese Textmarken zu einem Bild hinzufügen kann. Überall steht immer nur, wie man Textmarken aufruft, aber ich muss sie doch auch setzen um auf sie zugreifen zu können.

ich setze so ein bild in den briefkopf:
Code:



ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageHeader
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    Set image = Selection.InlineShapes.AddPicture(FileName:= _
        "\\dateipfad\small.bmp", LinkToFile:= _
        False, SaveWithDocument:=True)


wie kann ich mit dem gleichen buttonklick (also klick aufs gleiche makro) das bild ausblenden? ich bin schon seit stunden am suchen, aber komme einfach nicht weiter! Das kann doch nicht so schwer sein, oder?
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
09. Jun 2010, 15:36
Rufname:
Wohnort: Leipzig

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo Gast,

füge diese Zeile hinzu:
Code:
    image.Range.Font.Hidden = True

Das Bild wird dann zu "Ausgeblendetem Text", ob man den auf dem Bildschirm sieht, hängt von der Einstellung in Extras - Optionen - Ansicht ab: Ausgeblendeter Text darf kein Häkchen haben, damit er nicht zu sehen ist.

Ob er gedruckt wird, hängt von den Einstellungen in Extras - Optionen - Drucken ab: Auch hier darf bei "Ausgeblendeter Text" kein Häkchen sein, damit er nicht mit gedruckt wird.

Gruß
Lisa
Gast



Verfasst am:
09. Jun 2010, 17:43
Rufname:

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo Lisa,

vielen Dank für deine promte Antwort. Es ist wirklich unglaublich wie viele Beiträge du hier in diesem Forum schon gepostet hast. Respekt!

Leider habe ich meine Frage nicht ganz richtig formuliert. Mein Problem ist nicht ein Element ein- oder auszublenden, sondern zu wissen, ob es bereits auf dem dokument existiert und es anhand dessen hinzuzufügen oder zu entfernen.

Ich kann nicht die Hidden-Eigenschaft abfragen, weil ich die Information schon vorher im Code brauche. Ich versuche es noch mal mit etwas Pseudocode zu visualisieren.

Code:

//if bild exisitiert nicht
ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageHeader
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    Set image = Selection.InlineShapes.AddPicture(FileName:= _
        "\\dateipfad\small.bmp", LinkToFile:= _
        False, SaveWithDocument:=True)
//else
//bild entfernen


Vielen Dank!
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
09. Jun 2010, 18:14
Rufname:
Wohnort: Leipzig

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo Gast,

wird das Bild grundsätzlich nur per VBA eingefügt oder könnte es auch sonst schon vorhanden sein?

Also der springende Punkt ist: Ich kann mit VBA nicht "sehen", ob das Bild (wenn ja, welches) schon da ist. Man könnte etwa eine Textmarke zu Hilfe nehmen, die man um das Bild legt.

Dann könnte man per VBA fragen, ob die Textmarke namens BildXY im Dokument existiert. Wenn das der Fall ist, löschen wir einfach die Textmarke samt Bild. Wenn es nicht der Fall ist, fügen wir das Bild samt Textmarke ein? Oder wird dann was anderes gemacht.

Die Textmarke kann man auch "von Hand" um das Bild legen, dazu das eingefügte Bild markieren (so dass die rechteckigen Anfasser sichtbar ind) und über Menü Einfügen - Textmarke eine Textmarke einfügen.

Per VBA würde man einfach beim Einfügen des Bildes die Textmarke mit einfügen. Das könnte so aussehen:
Code:
Sub Makro1()
   
    Dim Image As Word.InlineShape
    Dim bmk As Word.Bookmark
    Dim strTM As String
   
    strTM = "Bildmarke"
   
    If ActiveDocument.Bookmarks.Exists(strTM) Then
        ActiveDocument.Bookmarks(strTM).Range.Delete
    Else
        ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageHeader
        Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
        Set Image = Selection.InlineShapes.AddPicture(FileName:= _
            "\\dateipfad\small.bmp", LinkToFile:= _
            False, SaveWithDocument:=True)
        Set bmk = Selection.Bookmarks.Add(Name:=strTM, Range:=Image.Range)
    End If
       
End Sub

Gruß
Lisa
Gast



Verfasst am:
10. Jun 2010, 16:46
Rufname:

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Perfekt! Vielen Dank! Eine letzte Frage noch: Wie schaffe ich eine solche ein- und ausblendfunktionalität mit Shapes. Das Shape-Objekt hat kein "Range"-Property. Ein roter Balken muss ein Shape sein und darf kein InlineShape sein, weil InlineShapes nicht die Methode.AddLine haben.

Hier mein Code:

Code:

Dim strBALK As String
strBALK = "Balkenmarke"
Dim myshapeBalken As Shape

   
     If ActiveDocument.Bookmarks.Exists(strBALK) Then
        ActiveDocument.Bookmarks(strBALK).Range.Delete
    Else
        Set myshapeBalken = Selection.HeaderFooter.Shapes.AddLine(ActiveDocument.PageSetup.PageWidth, 0, ActiveDocument.PageSetup.PageWidth, ActiveDocument.PageSetup.PageHeight)
        myshapeBalken.Line.Weight = 42.5
        myshapeBalken.Line.ForeColor.RGB = &HFF
        Set bmk = Selection.Bookmarks.Add(Name:=strBALK, Range:=[b]myshapeBalken.Range[/b])
    End If



Die Fettgedruckte Zeile bereitet die probleme, da Shapes keine Range haben, sie aber für Bookmarks benötigt wird.

Danke.
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
10. Jun 2010, 19:27
Rufname:
Wohnort: Leipzig

AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo namensloser Gast,

nein, das geht so nicht. Shapes werden ganz anders behandelt. Shapes haben eine Name-Eigenschaft, an denen man sie erkennen kann, man kann ihnen also direkt einen Namen geben, nachdem man sie erzeugt hat! Das machen wir natürlich, dann braucht man keine Bookmark (die braucht man nur bei InlineShapes, weil die keinen Namen haben!). Außerdem haben Shapes eine Visible-Eigenschaft (die InlineShapes nicht haben), man kann sie also direkt ein- oder ausblenden, in Deinem Fall etwa so:
Code:
Sub Neu()

    Dim strBALK As String
    Dim myshapeBalken As Shape
    Dim shp As Word.Shape
    Dim bDone As Boolean
   
    strBALK = "Balkenmarke"
   
    If Selection.HeaderFooter.Shapes.Count > 0 Then
        For Each shp In Selection.HeaderFooter.Shapes
            If shp.Name = strBALK Then
                shp.Visible = msoFalse
'                shp.Delete
                bDone = True
                Exit For
            End If
        Next shp
    End If
    If Not bDone Then
        Set myshapeBalken = Selection.HeaderFooter.Shapes.AddLine(ActiveDocument.PageSetup.PageWidth, 0, ActiveDocument.PageSetup.PageWidth, ActiveDocument.PageSetup.PageHeight)
        myshapeBalken.Line.Weight = 42.5
        myshapeBalken.Line.ForeColor.RGB = &HFF
        myshapeBalken.Name = strBALK
    End If

End Sub

Und bitte: Erst alle Variablen deklarieren, dann befüllen.

Ich habe jetzt hier einfach die Shape unsichtbar gemacht, man kann sie (mit der jetzt auskommentierten Zeile) auch löschen, ganz nach Geschmack.

Gruß
Lisa
Gast



Verfasst am:
11. Jun 2010, 08:48
Rufname:


AW: Text ein.- bzw wieder ausblenden - AW: Text ein.- bzw wieder ausblenden

Nach oben
       

Hallo,

du bist soo gut! Vielen Dank! Endlich kann ich mich wieder vernünftigen Dingen (wie C#) widmen und habe dieses Makro fertig. Nicht zuletzt natürlich auch durch deine Hilfe. Eine allerletzte Frage habe ich allerdings noch: Wieso tust du dir sowas wie Makroprogrammierung eigentlich an? Ist das Leben nicht viel zu schön dafür? Wink

Viele Grüße
der glückliche Namenlose
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Word Serienbriefe: Probleme mit mergefield (text und zahl) 2 djeses 341 27. Jan 2014, 17:40
Flipper7 Probleme mit mergefield (text und zahl)
Keine neuen Beiträge Word Serienbriefe: Word Seriendruckfeld: Zahl bzw. Betrag formatieren 7 JoeM 13092 31. Jul 2013, 15:27
Schwabenfischer Word Seriendruckfeld: Zahl bzw. Betrag formatieren
Keine neuen Beiträge Word Serienbriefe: Hilfe, Link anstatt Verlinkter Text 1 Geograph123 84 18. Feb 2013, 15:31
Geograph123 Hilfe, Link anstatt Verlinkter Text
Keine neuen Beiträge Word Serienbriefe: in Word kopiertes Formular mit HTMLControl Forms.HTML:Text.1 0 unwissend24 393 12. Aug 2012, 14:08
unwissend24 in Word kopiertes Formular mit HTMLControl Forms.HTML:Text.1
Keine neuen Beiträge Word Serienbriefe: Probleme mit Serien EMail als Text 2 Thomas Kirsch 602 13. Apr 2012, 13:01
Thomas Kirsch Probleme mit Serien EMail als Text
Keine neuen Beiträge Word Serienbriefe: Zeile ausblenden wenn Seriendruckfeld den Wert 0 hat 3 peter007 3053 14. Okt 2011, 13:44
charlybrown Zeile ausblenden wenn Seriendruckfeld den Wert 0 hat
Keine neuen Beiträge Word Serienbriefe: 0.-€ ausblenden 4 denizno1 482 24. Jul 2010, 16:10
denizno1 0.-€ ausblenden
Keine neuen Beiträge Word Serienbriefe: Seriendruck in E-Mail (per Anlage) - E-Mail mit Text 1 Gast 2513 16. Jun 2010, 13:44
Gast Seriendruck in E-Mail (per Anlage) - E-Mail mit Text
Keine neuen Beiträge Word Serienbriefe: Text von Seite 1 auf Seite 2 übernehmen 7 Chrissan79 1402 09. Apr 2010, 11:53
Chrissan79 Text von Seite 1 auf Seite 2 übernehmen
Keine neuen Beiträge Word Serienbriefe: Nullwerte im Mergefield ausblenden 9 Br@thering 2343 20. Nov 2009, 15:12
Schneewittchen Nullwerte im Mergefield ausblenden
Keine neuen Beiträge Word Serienbriefe: Text im Serienbrief nach Anrede auswählen (wenn/dann) 4 Iris26 4158 06. Aug 2009, 12:38
Gast Text im Serienbrief nach Anrede auswählen (wenn/dann)
Keine neuen Beiträge Word Serienbriefe: Tabellenzeile mit IF ausblenden? 1 rp2008 1192 21. Dez 2008, 19:26
charlybrown Tabellenzeile mit IF ausblenden?
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: JavaScript