Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Bilder einfügen
Gehe zu Seite 1, 2  Weiter
zurück: Radiobuttons auswerten weiter: Problem mit Autotexte Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
brucki
Gast


Verfasst am:
04. Sep 2006, 22:50
Rufname:

Bilder einfügen - Bilder einfügen

Nach oben
       

Hallo alle zusammen

Habe folgendes Problem
Ich muss Bilder in eine Word Datei einfügen, dazu darf ich aber keinen festen Pfad angeben wo diese Datei ist sondern ich muss immer wieder dazu aufgefordert werden das verzeichnis + bild auszuwählen!
Weiters muss dann dieses Foto verkleinert werden auf die zweite Seite kopiert werden und dann noch einmal verkleinert werden!

Ich habe echt keinen Plan wie das funktioniert!

kann mir bitte wer helfen

danke

Brucki
bobmalaria
Von allem ein bisschen Ahnung, kein Experte


Verfasst am:
04. Sep 2006, 23:07
Rufname:


AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

hi,
also sobald du eine grafik in word einfügst über einfügen -->grafik-->aus datei und dannach speicherst, ist die grafik im doc enthalten. um dateibezüge musst du dir nur bei hyperlinks sorgen machen, nicht bei grafiken.

ist die grafik im doc eingefügt kannst du sie mit einem linksklick makieren und in den ecken ist dann ein kleines viereck auf das du gehst und dann mit gedrückter linker maustaste die größe änderst.

wenn du in die symbolleiste gehst und dort einen rechtsklick machst bekommst du eine liste mit dingen die du einblenden kannst.
klicke dort auf den eintrag "grafik" jetzt erscheint ein kleines fenster mit ein paar einfachen werkuegen zur bearbeitung der grafik.

unter anderem gibt es da ein tool "zuschneiden" 7. von links mit dem du die grafik zuschneiden kannst.

die position im dokument kannst du einstellen. rechtsklick auf die grafik -->grafik formatieren-->layout.

was du ganz genau machen willst hab ich leider nicht ganz verstanden Rolling Eyes

ich hoffe das hilft dir.

gruss
brucki
Gast


Verfasst am:
04. Sep 2006, 23:29
Rufname:

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

danke für deine rasche antwort!

manuell schaff ich das ohne probleme! will das ganze nur automatisch machen. will nur einen knopf drücken und dann macht word das ganze quasi von selber!
das verkleinern und einfügen muss automtisch gehen!!!

danke brucki
nitro_storm
VB / VBA / .NET Programmierer


Verfasst am:
05. Sep 2006, 10:27
Rufname: Nitro
Wohnort: FFM

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

Hi !

Hier mal ein Bsp.:
Code:
Sub InsertPicture()
   
   Dim sPath As String
   Dim sBildPfad As String
   Dim lRes As Long
   
   'Hier den StandardPfad eingeben welcher immer zuerst geöffnet werden soll
   sBildPfad = "C:\temp"
   
   'aktuellen PicturePfad merken
   sPath = Options.DefaultFilePath(Path:=wdPicturesPath)
   
   'Bildpfad ändern
   Options.DefaultFilePath(Path:=wdPicturesPath) = sBildPfad
     
   'Dialog öffnen
   lRes = Application.Dialogs(wdDialogInsertPicture).Show
   
   'Pfad zurücksetzten
   Options.DefaultFilePath(Path:=wdPicturesPath) = sPath
   
   If lRes <> 0 And ActiveDocument.InlineShapes.Count > 0 Then
      'wenn bild eingefügt wurde, dann Bildgrösse anpassen
      Call BildGroesse(ActiveDocument.InlineShapes(ActiveDocument.InlineShapes.Count))
   End If
   
End Sub

Sub BildGroesse(oPic As InlineShape)
   Dim iScale As Single
   Dim iBreite As Single

    iBreite = 200 'Pixel
   
    oPic.LockAspectRatio = msoTrue
    ' Skalierungsfaktor in Pixel für Breite festlegen
    iScale = (iBreite / oPic.Width) * 100
    oPic.ScaleWidth = iScale
    oPic.ScaleHeight = iScale
End Sub


Das Bild wird auf 200 Pixel verkleinert. Kannst du ja noch anpassen.
Wie man es aber auf Seite 2 kopiert, weiss ich leider nicht !

_________________
Gruss
Nitro

-=Schon die Piste, geh FREERIDEN=-
Gast



Verfasst am:
06. Sep 2006, 13:20
Rufname:


AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

ich weiß nicht, ob es bei dir paßt, aber schön ist sonst auch

Application.Dialogs(wdDialogInsertPicture).Show

falls du möchtest, dass ein Benutzer mit einem Klick auf einen Button ein Bild einfügen soll. Damit geht dann das ganz normale Fenster auf, um eine Datei zu öffnen (Default immer auf "Eigene Bilder")

gruß,
merry
bobmalaria
Von allem ein bisschen Ahnung, kein Experte


Verfasst am:
06. Sep 2006, 14:53
Rufname:

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

hi,

sorry fuer meine erste antwort Smile hab nicht auf die kategorie geachtet Embarassed

gruss
brucki
Gast


Verfasst am:
07. Sep 2006, 11:19
Rufname:

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

danke für eure großartige hilfe

der code funktioniert einwandfrei jetzt muss ich es nur noch herausfinden wie ich das foto auf die zweite seite kopieren kann!

hat do noch wer eine ahnung??

danke

brucki
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
07. Sep 2006, 22:57
Rufname:
Wohnort: Leipzig

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

Hallo Brucki,

am einfachsten wäre es vermutlich, wenn vor dem Einfügen des Bildes zuerst die Seite 2 aufgesucht wird. Dann wird das Bild eingefügt und steht gleich an der richtigen Stelle. Oder wird das Bild tatsächlich zweimal benötigt?
Dazu diese Zeile an erster Stelle einfügen:
Code:
Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
brucki
Gast


Verfasst am:
08. Sep 2006, 13:22
Rufname:

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

hallo!

also das Bild wird tatsächlich zweimal benötigt einmal in einem großen format und einmal in einem kleinen format!

auf der ersten seite soll es für A4 sein auf der zweite seiten für A5!

ich habe deinen code nach

Sub InsertPicture()

Dim sPath As String
Dim sBildPfad As String
Dim lRes As Long

eingefügt und es gibt keinen unterschied, jedenfalls finde ich keinen!

Vielleicht weißt du noch was anderes lisa!

danke

gruß brucki
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
08. Sep 2006, 20:46
Rufname:
Wohnort: Leipzig

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

Hallo Brucki,

ok, das könnte man so machen:
Code:
Sub BildKopieren()

    ActiveDocument.InlineShapes(1).Select
    With Selection
        .Copy
        .GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
        .Paste
        .MoveLeft Unit:=wdCharacter, Extend:=True
        Call BildGroesse(oPic:=.InlineShapes(1), iBreite:=100)
    End With

End Sub
Sub BildGroesse(ByRef oPic As InlineShape, ByVal iBreite As Single)
   
    Dim iScale As Single
 
    oPic.LockAspectRatio = msoTrue
    ' Skalierungsfaktor in Pixel für Breite festlegen
    iScale = (iBreite / oPic.Width) * 100
    oPic.ScaleWidth = iScale
    oPic.ScaleHeight = iScale
   
End Sub

Du siehst, dass ich die Prozedur BildGroesse verändert habe, so dass man ihr den Wert der Skalierung übergeben muss. Im Bsp. habe ich 100 übergeben.
Im Code von NitroStorm für das Einfügen des Bildes müsste dementsprechend der Aufruf der Prozedur BildGroesse auch geändert werden:
Code:
Call BildGroesse(oPic:=ActiveDocument.InlineShapes(ActiveDocument.InlineShapes.Count), iBreite:=200)

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
brucki
Gast


Verfasst am:
08. Sep 2006, 22:06
Rufname:

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

Hey lisa ok das funktioniert schon mal ganz toll! noch ein problem kann man das auch automatisch machen, also wenn ich das bild auf der ersten seite einfüge das es dann automatisch auch auf der zweiten seite ist nur um einiges kleiner?
und zweite frage, wenn ich jetzt auf die zweite seite ein zweites foto einfügen will dann mach er mir das zweite foto nebeneinander nicht untereinander wie ich das möchte!
es sind auf der A4 seite zwei fotos untereinander und auch auf der A5 Seite! das was auf der A5 Seite oben ist, ist nur die verkleinerung der A4 Seite!

Danke für eure tolle unterstützung!!!!!! Laughing
brucki

Code:

Sub InsertPicture()
   
   Dim sPath As String
   Dim sBildPfad As String
   Dim lRes As Long
   
   'Hier den StandardPfad eingeben welcher immer zuerst geöffnet werden soll
   sBildPfad = "P:\Fotos\"
   
   'aktuellen PicturePfad merken
   sPath = Options.DefaultFilePath(Path:=wdPicturesPath)
   
   'Bildpfad ändern
   Options.DefaultFilePath(Path:=wdPicturesPath) = sBildPfad
     
   'Dialog öffnen
   lRes = Application.Dialogs(wdDialogInsertPicture).Show
   
   'Pfad zurücksetzten
   Options.DefaultFilePath(Path:=wdPicturesPath) = sPath
   
   If lRes <> 0 And ActiveDocument.InlineShapes.Count > 0 Then
      'wenn bild eingefügt wurde, dann Bildgrösse anpassen
      Call BildGroesse(oPic:=ActiveDocument.InlineShapes(ActiveDocument.InlineShapes.Count), iBreite:=150)
   End If
   

   
End Sub

Sub BildKopieren()

    ActiveDocument.InlineShapes(1).Select
    With Selection
        .copy
        .GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
        .Paste
        .MoveLeft Unit:=wdCharacter, Extend:=True
        Call BildGroesse(oPic:=.InlineShapes(1), iBreite:=150)
    End With

End Sub

Sub BildGroesse(ByRef oPic As InlineShape, ByVal iBreite As Single)
   
    Dim iScale As Single
 
    oPic.LockAspectRatio = msoTrue
    ' Skalierungsfaktor in Pixel für Breite festlegen
    iScale = (iBreite / oPic.Width) * 100
    oPic.ScaleWidth = iScale
    oPic.ScaleHeight = iScale
   
End Sub
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
10. Sep 2006, 17:39
Rufname:
Wohnort: Leipzig

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

Hallo Brucki,

es würde erstmal reichen, wenn nach dem auf Seite 2 kopierten Bild eine Absatzmarke eingefügt wird:
Code:
Sub BildKopieren()

    ActiveDocument.InlineShapes(1).Select
    With Selection
        .copy
        .GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
        .Paste
        .MoveLeft Unit:=wdCharacter, Extend:=True
        Call BildGroesse(oPic:=.InlineShapes(1), iBreite:=150)
        .Collapse wdCollapseEnd
        .TypeParagraph

    End With

End Sub

Aber prinzpiell ist mir noch nicht klar, was da ablaufen soll. Das Ganze funktioniert bis jetzt nur einmal. Denn eine Angabe Seite 2 ist nicht fest in Word. Wenn man auf Seite 1 noch was einfügt, verschiebt sich der Inhalt der zweiten Seite.
Deswegen wäre es schön, wenn Du nochmal erklärst, was genau ablaufen soll und wie oft:
  • Werden stets 2 Bilder eingefügt und dann auf Seite verkleinert? Oder manchmal auch noch mehr?
  • Existiert die Seite 2 bereits oder soll sie erst vom Makro erzeugt werden?
  • Könnte man statt Seite 2 lieber einen Abschnittswechsel vom Makro einfügen lassen, das würde die Platzierung erleichtern?
  • Wenn nicht, könnte man einen harten Seitenwechsel vom Makro einfügen lassen? Oder ist evtl. bereits einer im Dokument vorhanden?
  • Sind vorher bereits Bilder in dem Dokument vorhanden? Dann müsste das Makro auch geändert werden.
  • Am besten, Du schreibst mal genau, was in welcher Reihenfolge ablaufen soll.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
brucki
Gast


Verfasst am:
11. Sep 2006, 11:04
Rufname:

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       Version: Office 2003

hey lisa!

also das ganze dient eigentlich nur zum foto verkleinern und ausdrucken!

ganz am anfang muss in der kopfzeile eine nummer eingegeben werden, das war dann auch schon der ganze text!
und dann müssen zwei fotos auf die a4 seite rein. (das dokument ist am anfang immer leer bis auf die kopfzeile).
die gleichen zwei fotos müssen dann noch auf die zwei a4 seite dich ich im querformat mache, damit simuliere ich ein A5 blatt! die fotos werden dementsprechend weiter verkleinert. Dann drucke ich die zwei seiten aus das querformat wird zurecht geschnitten auf A5 und das wars schon.

1.) Es werden immer nur zwei bilder eingefügt auf der A4 und auf der A5 Seite immer die selben.
2.) Seite zwei ist genauso ein leeres blatt wie seite eins, kann also auch als makro generiert werden. völlig egal wie
3.) klar kann man einen Abschnittswechsel machen
4.) nein keine biler vorhanden
5.) dokumentvorlage öffnen und eine nummer in der kopfzeile eingeben bzw. ergänzen
dann beide bilder einfügen (untereinander) diese dann verkleinern
das gleiche auf der zweiten seite machen nur diese werden noch weiter verkleinert A5

danke brucki
Lisa
Moderator; Word seit Word 5.0 (für DOS)


Verfasst am:
11. Sep 2006, 18:43
Rufname:
Wohnort: Leipzig

AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

Hallo Brucki,

OK, das ist ja sogar einfacher. Probier es mal hiermit:
Code:
Sub BildEinfuegen()
   
    Dim sPath As String
    Dim sBildPfad As String
    Dim lRes As Long
    Dim sBildname As String
    Dim s2Bildname As String
   
    'Hier den StandardPfad eingeben welcher immer zuerst geöffnet werden soll
    sBildPfad = "C:\Dokumente und Einstellungen\Administrator\Eigene Dateien\Eigene Bilder\"
   
    'aktuellen PicturePfad merken
    sPath = Options.DefaultFilePath(Path:=wdPicturesPath)
   
    'Bildpfad ändern
    Options.DefaultFilePath(Path:=wdPicturesPath) = sBildPfad
       
    'Dialog öffnen
    With Dialogs(wdDialogInsertPicture)
        .Display
        sBildname = .Name
    End With
   
    With Selection
        .HomeKey Unit:=wdStory
        .InlineShapes.AddPicture FileName:=sBildname
        .MoveLeft Unit:=wdCharacter, Extend:=True
        Call BildGroesse(oPic:=.InlineShapes(1), iBreite:=150)
        .Collapse wdCollapseEnd
        .TypeParagraph
    End With
   
    With Dialogs(wdDialogInsertPicture)
        .Display
        s2Bildname = .Name
    End With
   
    With Selection
        .InlineShapes.AddPicture FileName:=s2Bildname
        .MoveLeft Unit:=wdCharacter, Extend:=True
        Call BildGroesse(oPic:=.InlineShapes(1), iBreite:=150)
        .Collapse wdCollapseEnd
        .TypeParagraph
        .InsertBreak wdSectionBreakNextPage
    End With
   
    ActiveDocument.Sections(2).PageSetup.Orientation = wdOrientLandscape
   
    With Selection
        .GoTo What:=wdGoToSection, Count:=2
        .InlineShapes.AddPicture FileName:=sBildname
        .MoveLeft Unit:=wdCharacter, Extend:=True
        Call BildGroesse(oPic:=.InlineShapes(1), iBreite:=100)
        .Collapse wdCollapseEnd
        .TypeParagraph
        .InlineShapes.AddPicture FileName:=s2Bildname
        .MoveLeft Unit:=wdCharacter, Extend:=True
        Call BildGroesse(oPic:=.InlineShapes(1), iBreite:=100)
        .Collapse wdCollapseEnd
    End With
   
    'Pfad zurücksetzten
    Options.DefaultFilePath(Path:=wdPicturesPath) = sPath
   
End Sub
Sub BildGroesse(ByRef oPic As InlineShape, ByVal iBreite As Single)
   
    Dim iScale As Single
 
    oPic.LockAspectRatio = msoTrue
    ' Skalierungsfaktor in Pixel für Breite festlegen
    iScale = (iBreite / oPic.Width) * 100
    oPic.ScaleWidth = iScale
    oPic.ScaleHeight = iScale
   
End Sub

Die Bildgrößen müssen natürlich noch angepasst werden.

_________________
Sei doch so nett und gib eine Rückmeldung, ob es klappt!
Gruß, Lisa

Guter Rat ist teuer!
brucki
Gast


Verfasst am:
11. Sep 2006, 22:43
Rufname:


AW: Bilder einfügen - AW: Bilder einfügen

Nach oben
       

hallo

das passt perfekt nur eines noch!

ich brauche zwei bis drei absätze auf jeder seite zwischen den bilder kann man das auch machen?

danke

brucki
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Word Serienbriefe: Word-Serienbrief: jpg automatisert einfügen 4 JOE_NDS 5017 01. Okt 2010, 17:56
Gast Word-Serienbrief: jpg automatisert einfügen
Keine neuen Beiträge Word Serienbriefe: Bilder aus Ordner in Serienbrief einfügen 3 alioli1 2046 29. Nov 2009, 11:45
Gast Bilder aus Ordner in Serienbrief einfügen
Keine neuen Beiträge Word Serienbriefe: Adressen aus Office tabellen dokument in dokument einfügen 1 Anna-L. 1218 15. Nov 2009, 21:42
charlybrown Adressen aus Office tabellen dokument in dokument einfügen
Keine neuen Beiträge Word Serienbriefe: Einfügen versch. Adressen aus einer Datenqu. in ein Dokument 9 Gast 921 04. Nov 2009, 15:02
charlybrown Einfügen versch. Adressen aus einer Datenqu. in ein Dokument
Keine neuen Beiträge Word Serienbriefe: Bilder in Serienbrief einfügen 4 Konte 10454 05. Aug 2009, 15:28
charlybrown Bilder in Serienbrief einfügen
Keine neuen Beiträge Word Serienbriefe: Serienbrief mit Bilder aus Access 0 Regi22 1398 26. Jun 2009, 21:13
Regi22 Serienbrief mit Bilder aus Access
Keine neuen Beiträge Word Serienbriefe: Absender für alle Etiketten einfügen 1 Gast 6018 11. Feb 2009, 13:16
Maulende Myrte Absender für alle Etiketten einfügen
Keine neuen Beiträge Word Serienbriefe: Serienbrief: Vollständige Empfängerliste als Feld einfügen 2 Gast2008 2861 23. Okt 2008, 10:37
Auch Gast Serienbrief: Vollständige Empfängerliste als Feld einfügen
Keine neuen Beiträge Word Serienbriefe: Anrede einfügen 0 ArianeH 911 27. Aug 2008, 11:47
ArianeH Anrede einfügen
Keine neuen Beiträge Word Serienbriefe: Bilder bei Serienmails nicht mitgeschickt: Word + Outlook 0 Matthias_1234 1530 31. Jul 2008, 12:13
Matthias_1234 Bilder bei Serienmails nicht mitgeschickt: Word + Outlook
Keine neuen Beiträge Word Serienbriefe: Wenn dann Textbaustein / Autotext einfügen 0 miricoleo 4174 01. Dez 2007, 21:04
miricoleo Wenn dann Textbaustein / Autotext einfügen
Keine neuen Beiträge Word Serienbriefe: Datenbank einfügen klappt nicht mehr! 2 Schwertfeger 1322 24. März 2007, 21:32
Schwertfeger Datenbank einfügen klappt nicht mehr!
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: CSS Forum