Erstes UND letztes Zeichen löschen wenn...

Moderator: ModerationP

Erstes UND letztes Zeichen löschen wenn...

Beitragvon Schnubbelpups » 07. Okt 2017, 08:47

Moin zusammen,

die Überschrift sagt eigentlich schon alles.
Ich möchte das erste und letzte zeichen einer Zelle löschen WENN es ein "%" ist.

Ist das möglich? Bis jetzt habe ich nur Einträge gefunden die das erste oder letzte Zeichen löschen und auch nicht nach bestimmten zeichen suchen.

Danke schonmal im voraus...

Gruß Matthias
Schnubbelpups
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 87
Registriert: 28. Feb 2015, 12:37

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon shift-del » 07. Okt 2017, 08:50

Matthias,

Code: Alles auswählen
=WECHSELN(A1;"%";"")
Wir sehen uns!
... shift-del
Eine Mustertabelle hilft beim Helfen.
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
Benutzeravatar
shift-del
Moderator
 
Beiträge: 19359
Registriert: 25. Jan 2009, 22:54
Wohnort: Ehemaliges Fabrikgelände

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon Hajo_Zi » 07. Okt 2017, 08:53

Hallo Matthias,

=WENN(RECHTS(WENN(LINKS(E29;1)="%";TEIL(E29;2;LÄNGE(E29));E29);1)="%";LINKS(WENN(LINKS(E29;1)="%";TEIL(E29;2;LÄNGE(E29));E29);LÄNGE(WENN(LINKS(E29;1)="%";TEIL(E29;2;LÄNGE(E29));E29))-1);WENN(LINKS(E29;1)="%";TEIL(E29;2;LÄNGE(E29));E29))

Gruß hajo
Signatur
Bitte Version angeben. Bei keiner Angabe gehe ich von meinen Angaben aus.
Office 2016 Plus - 32 Bit.
Da die Mailbenachrichtigung bei mir nicht geht. Weitere Antworten dem Zufall überlassen.
Falls lange keine Antwort kommt, PN.
Benutzeravatar
Hajo_Zi
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 2984
Registriert: 31. Jan 2004, 18:26
Wohnort: Straubing

Andere als erste/letzte % bleiben erhalten

Beitragvon ehem. lupo1 » 07. Okt 2017, 10:22

=GLÄTTEN(WECHSELN(WECHSELN(" "&A1&" ";" %";"");"% ";""))
ehem. lupo1
 

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon Schnubbelpups » 07. Okt 2017, 10:42

Super, vielen Dank. So einfach wenn mann's weiß...
Schnubbelpups
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 87
Registriert: 28. Feb 2015, 12:37

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon Lorntephis1987 » 09. Okt 2017, 00:37

Super. Sowas in der Art habe ich auch gerade gebraucht. :) Auch von mir Danke
"Sei dir selbst immer einen Schritt voraus!"
Benutzeravatar
Lorntephis1987
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 10
Registriert: 06. Okt 2017, 21:54
Wohnort: Lauenburg

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon HKindler » 09. Okt 2017, 12:51

Hi,

mein Vorschlag:
Code: Alles auswählen
=WECHSELN(LINKS(A1;1);"%";"")&TEIL(A1;2;LÄNGE(A1)-2)&WECHSELN(RECHTS(A1;1);"%";"")


Die Formel von shift-del löscht ALLE %-Zeichen.
Die Formel von ehem.lupo1 löscht auch Prozentzeichen in der Wortmitte, wenn ein Leerzeichen davor oder dahinter steht (auch das Leerzeichen wird dann gelöscht).
Die Formel von Hajo_Zi macht das selbe wie meine, ist aber deutlich länger.
Gruß,
Helmut

----------------------------
Windows 8.1 (64 Bit) / Office 2013 (32 Bit)
HKindler
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 1579
Registriert: 04. Jul 2013, 09:02

nun denn ... ich vermute, dass ein ° genehm ist, oge.

Beitragvon ehem. lupo1 » 09. Okt 2017, 13:07

=WECHSELN(GLÄTTEN(WECHSELN(WECHSELN("°"&A1&"°";"°%";);"%°";));"°";)
ehem. lupo1
 

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon slowboarder » 09. Okt 2017, 13:18

HI

hier nochmal zwei Formelvarianten, welche nur die "%" am Anfang oder Ende entfernen und den Text ansonsten unverändert lassen:

Code: Alles auswählen
=TEIL(A1;1+(LINKS(A1;1)="%");LÄNGE(A1)-(LINKS(A1;1)="%")-(RECHTS(A1;1)="%"))
=WECHSELN(WECHSELN(WECHSELN("|"&A1&"|";"|%";"");"%|";"");"|";"")


das Zeichen "|" darf im Text nicht vorkommen. Falls doch, einfach ein anderes Zeichen oder Zeichenfolge in der Formel verwenden.

Wenn die "%" nur entfernt werden sollen, wenn am Anfang UND Ende eins steht; dann auch so:
Code: Alles auswählen
=WENN(ZÄHLENWENN(A1;"%*%");TEIL(A1;2;LÄNGE(A1)-2);A1)



Gruß Daniel
slowboarder
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 23689
Registriert: 18. Apr 2009, 13:33

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon Gast » 09. Okt 2017, 13:28

Moin slowboarder,

die letzte Idee mit dem Zählenwenn(.., "%*%") ist wirklich chic.
Das gefällt mir gut UND ich verstehe auch noch nach 2 Monaten, was in der Formel passiert.
Bei der Formel darüber müsste ich nach 2 Monaten bestimmt das Publikum fragen oder jemanden anrufen...

Grüße
Biber
Gast
 

da hatte ich wohl den Betreff nicht gelesen ...

Beitragvon ehem. lupo1 » 09. Okt 2017, 14:34

... mit dem UND.
ehem. lupo1
 

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon snb » 09. Okt 2017, 16:52

Oder ?

Code: Alles auswählen
Sub M_snb()
  [A1:K100] = [index(substitute(substitute(substitute("|"&A1:K100&"|","%|",""),"|%",""),"|",""),)]
End Sub
snb
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 5275
Registriert: 25. Sep 2014, 16:37

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon GMG-CC » 09. Okt 2017, 17:00

Na gut, dann präsentiere ich doch noch meine Lösung. Ohne eine (sichtbare) Formel. Und was den Text betrifft: mittendrin darf stehen, was will ...
Realisiert mit meinem Lieblings-Spielzeug: Power Query 8-)
Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.
Gruß
Günther

Excel-ist-sexy!
Wenn du keine Excel-Version angegeben hast, gehe ich von mindestens Excel 2016 aus.
Hilfe zur Selbsthilfe, das ist IMHO der Sinn eines Forums, nicht Komplettlösungen für den kommerziellen Einsatz und das "natürlich" gratis!
Benutzeravatar
GMG-CC
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 3177
Registriert: 12. Nov 2011, 23:17
Wohnort: Geesthacht bei Hamburg

Re: Erstes UND letztes Zeichen löschen wenn...

Beitragvon slowboarder » 09. Okt 2017, 17:35

Hi Günther

sehr schön, aber kannst du uns bitte erklären, was man tun muss, um von der ersten Tabelle auf die zweite Tabelle zu kommen?
Powerquery habe ich installiert.
Aber wie erstellt man jetzt solche Umwandlungen?
Gruß Daniel
slowboarder
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 23689
Registriert: 18. Apr 2009, 13:33


Zurück zu Excel Forum (provisorisch)

Wer ist online?

Mitglieder in diesem Forum: Bing [Bot], Der Steuerfuzzi, GiuStyler, Jonas0806, snb, steve1da und 21 Gäste