Makro umd neue Arbeitsblätter nach Vorlage mit Namen aus Tab

Moderator: ModerationP

Makro umd neue Arbeitsblätter nach Vorlage mit Namen aus Tab

Beitragvon sweetmarille » 11. Mai 2019, 16:58

Einen schönen Abend,

bin gerade dabei für die Schule eine Excelvorlage zu erstellen. Dabei gibt es eine Arbeitsblatt "Vorlage", das kopiert werden soll und zwar so oft, wie im Arbeitsblatt 2 "Klassenübersicht" in der Spalte C ein Nachname steht. Dazu soll der Name der kopierten Arbeitsblätter die jeweiligen Nachnamen aus Arbeitsblatt "Klassenübersicht" erhalten.
Und wenn dann noch der Name ebenfalls auf dem kopierten Blatt erscheinen würde, dann wäre ich vollends glücklich :D

Grüße und Danke an alle Helfer

sweetmarille
sweetmarille
 

Re: Makro umd neue Arbeitsblätter nach Vorlage mit Namen aus

Beitragvon Nepumuk » 11. Mai 2019, 17:41

Hallo sweetmarille,

teste mal:

Code: Alles auswählen
Option Explicit

Public Sub Tabellen_erstellen()
    Dim lngRow As Long
    With Application
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    With ThisWorkbook.Worksheets("Klassen?bersicht")
        For lngRow = 1 To .Cells(.Rows.Count, 3).End(xlUp).Row
            Call ThisWorkbook.Worksheets("Vorlage").Copy( _
                After:=ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count))
            ActiveSheet.Name = Left$(.Cells(lngRow, 3).Value, 31)
            ActiveSheet.Cells(1, 1).Value = .Cells(lngRow, 3).Value
        Next
        Call .Select
    End With
    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Der Code gehört in ein Standardmodul (Menüleiste im VBA-Editor - Einfügen - Modul).
De fontibus non est disputandum

Gruß
Nepumuk 8-)
Benutzeravatar
Nepumuk
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 14762
Registriert: 10. Aug 2004, 08:40
Wohnort: Regensburg

Re: Makro umd neue Arbeitsblätter nach Vorlage mit Namen aus

Beitragvon sweetmarille » 11. Mai 2019, 19:36

Funktioniert ganz so wie gewollt. Es ist so übersichtlich geschrieben, dass die notwndigen Anpassungen leicht von der Hand gehen.

Vielen Dank Nepumuk.
sweetmarille
 


Zurück zu Excel Forum (provisorisch)

Wer ist online?

Mitglieder in diesem Forum: PacersFan, Pearli123 und 8 Gäste