Nur ganze Monate zählen

Moderator: ModerationP

Nur ganze Monate zählen

Beitragvon Ronny_ » 09. Jul 2019, 11:12

Hallo,

in Spalte A (Beginn) und Spalte B (Ende) stehen Daten, s. u.

Nun möchte ich, dass mir für einen Zeitraum nur die Anzahl der ganzen Monate angezeigt wird, sprich exklusive Anfangs- und Endmonat.

05.07.2017 - 30.01.2018 = 5 (Monate: Aug, Sept, Okt, Nov, Dez)
Formel: =DATEDIF(A1;B1;"m")-1

Das "-1" scheint aber nicht immer zu funktionieren:

24.05.2017 - 10.04.2019 = 22
Zähle ich hier nach, komme ich auf 22, die Formel wirft mir allerdings 21 raus.

Wie muss ich die Formel anpassen?

Grüße
Ronny
Ronny_
 

Re: Nur ganze Monate zählen

Beitragvon steve1da » 09. Jul 2019, 11:16

Hola,

Code: Alles auswählen
=WENN(TAG(MONATSENDE(B1;0))=TAG(B1);MONAT(B1);MONAT(B1)-1)-WENN(TAG(A1)=1;MONAT(A1)-1;MONAT(A1))+((JAHR(B1)-JAHR(A1))*12)


Gruß,
steve1da
Benutzeravatar
steve1da
Moderator
 
Beiträge: 29137
Registriert: 24. Sep 2003, 10:54

Re: Nur ganze Monate zählen

Beitragvon Ronny_ » 09. Jul 2019, 12:43

Hallo steve1da,

danke für deine schnelle Rückmeldung.

Ist es möglich, dass man das Beginn- und Enddatum komplett beim "Monatszählen" ausblendet?

01.06.2017 - 31.01.2018 sind laut Formel richtigerweise 8 Monate. Da ich den Beginn- und Endmonat allerdings in meiner Aufstellung nicht berücksichtigen muss, würde ich das Ergebnis "6" benötigen.

05.07.2017 - 30.01.2018 sind laut deiner Formel 5, so wie es sein soll, weil die beiden Beginn- und Enddaten mitten im jeweiligen Monat liegen.

Viele Grüße
Ronny
Ronny_
 

Re: Nur ganze Monate zählen

Beitragvon slowboarder » 09. Jul 2019, 12:47

Hi
das Problem ist, das anteilige Monate beim DateDif nicht mehr mitgezählt werden, dh das -1 brauchst du nur dann, wenn der Tag des Startdatums kleiner ist als der Tag des Enddatums

entweder du machst es von den Tagen abhängig ob noch -1 gerechnet wird, oder du normierst die Tage im Datum auf den Monatsletzten (Start) und Monatsersten (Ende)

=DATEDIF(A1;B1;"m")-Wenn(Tag(B1)>=Tag(A1);1;0)
wobei man das noch eleganter schreiben kann, wenn man weiß dass ein WAHR als 1 und ein FALSCH als 0 gewertet wird:
=DATEDIF(A1;B1;"m")-(Tag(B1)>=Tag(A1))


oder die zweite Variante:

=DATEDIF(DATUM(JAHR(A1);MONAT(A1)+1;0);DATUM(JAHR(B1);MONAT(B1);1);"m")

Gruß Daniel
slowboarder
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 25932
Registriert: 18. Apr 2009, 13:33

Re: Nur ganze Monate zählen

Beitragvon Ronny_ » 09. Jul 2019, 13:20

Hallo slowboarder,

deine Formeln werfen das aus, was ich benötige. Vielen Dank dafür!

Interessehalber: Ist die Logik auch in der Formel von steve1da integrierbar?

Und weiterhin: Wie habt ihr euch dieses ganze Formelwissen angeeignet? Ihr wisst ja immer einen Rat - ist beeindruckend. Würde da auch gerne mein Wissen erweitern. :wink:

Viele Grüße
Ronny
Ronny_
 

Re: Nur ganze Monate zählen

Beitragvon slowboarder » 09. Jul 2019, 13:33

Hi
ich hab keinen Plan, was sich Steve bei seiner Formel gedacht hat.

ansonsten:
Viel mit Excel arbeiten, in der Hilfe zu dein einzelnen Formen nachlesen.
außerdem:
beteilige dich aktiv am Forum, lese mit und versuche zu den Fragestellungen, die in deinem Erfahrungsbereich antworten zu geben.
auch wenn du am Anfang die Lösung nicht findest oder deine Lösung nicht die Optimale ist, du siehst aber die Lösungsansätze der anderen Forenteilnehmer und kannst von ihnen lernen, auch wenn das aktuelle Problem nicht unbedingt auch dein Problem ist.

Gruß Daniel
slowboarder
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 25932
Registriert: 18. Apr 2009, 13:33

Re: Nur ganze Monate zählen

Beitragvon steve1da » 09. Jul 2019, 13:37

Hola,
ich hab keinen Plan, was sich Steve bei seiner Formel gedacht hat.


ehrlich gesagt habe ich 5 Sekunden gegooglet :D

https://www.ms-office-forum.net/forum/s ... p?t=177712

Gruß,
steve1da
Benutzeravatar
steve1da
Moderator
 
Beiträge: 29137
Registriert: 24. Sep 2003, 10:54

Re: Nur ganze Monate zählen

Beitragvon Ronny_ » 09. Jul 2019, 14:04

Ok, danke für die Infos.

Einzelne Formeln oder Bestandteile kennt man, aber die Verkettung ist ja teilweise - zumindest für den Laien - zunächst recht komplex. Aber Übung macht natürlich den Meister..

Zu deinen Formeln, Daniel, noch eine Frage.

Was muss man hier anpassen, damit der Endmonat mitgezählt wird? Also Anfangsmonat nicht, Endmonat ja (egal ob das "Enddatum" z. B. mitten im Monat liegt, wie 05.06.2019 - der Monat soll als "ganzer" gewertet bzw. gezählt werden).
Bsp. 19.09.2017 - 24.01.2018 = 4

PS: Ich habe aktuell deine letzte Formel angewendet.

Viele Grüße
Ronny
Ronny_
 

Re: Nur ganze Monate zählen

Beitragvon Ronny_ » 10. Jul 2019, 12:57

Hallo nochmal,

hat vielleicht noch jemand einen Tipp? Ich habe selbst rumprobiert, aber keine zufriedenstellende Lösung erhalten.

Aufgrund von einer Kündigung soll nämlich keine anteilige Monatsberechnung stattfinden, sondern der volle letzte Monat berechnet werden.

Viele Grüße
Ronny
Ronny_
 

Re: Nur ganze Monate zählen

Beitragvon slowboarder » 10. Jul 2019, 13:28

naja, dann die zweite Variante verwenden und für das Enddatum den Tag auf den Monatsletzten setzen, dann wird dieser Monat immer voll berechnet.
wie das geht, kannst du dir beim Startdatum abschauen.


Gruß Daniel
slowboarder
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 25932
Registriert: 18. Apr 2009, 13:33

Re: Nur ganze Monate zählen

Beitragvon snb » 10. Jul 2019, 13:30

=DATEDIF(EOMONTH(A1;0);B1-DAY(B1);"m")+1
snb
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 6917
Registriert: 25. Sep 2014, 16:37

Re: Nur ganze Monate zählen

Beitragvon Ronny_ » 11. Jul 2019, 10:24

Hallo snb, hallo Daniel,

@ snb: Deine Formel wirft mir leider nicht das gewünschte Ergebnis aus.
Beispiel: 30.01.2018 - 25.03.2019 (Ergebnis laut Formel 13 - zählt man die Monate aber vom 01.02.2018 bis 01.03.2019 kommt man auf 14)

@ Daniel: Ich bin deinem Rat gefolgt und habe die "+1" ergänzt :wink: Sieht bei mir dann so aus und wirft für den o. g. Zeitraum den richtigen Wert aus - danke für den Hinweis!
=DATEDIF(DATUM(JAHR(I46);MONAT(I46)+1;0);DATUM(JAHR(J46);MONAT(J46)+1;1);"m")

Ich möchte nur sicher gehen, dass die Formel die richtige Logik abbildet: Sie errechnet den Unterschied zwischen Start- und Endmonat exkl. "Beginnmonat", korrekt?
Weil mit "+x" kann man sich in einer Formel ja schnell das gewünschte Ergebnis herrichten, allerdings sollte es ja grundsätzlich schon stimmen. :D

Danke für die Hilfe und viele Grüße
Ronny
Ronny_
 

Re: Nur ganze Monate zählen

Beitragvon GMG-CC » 12. Jul 2019, 00:23

Moin Ronny,

ich habe mich eine ganze Zeit aus der Diskussion heraus gehalten, da ja so einige Lösungen kamen und viele dem ersten Anschein nach auch funktionierten. Da du scheinbar immer noch Zweifel hast, habe ich mich mal des Themas angenommen. Eine (aus meiner Sicht) absolut sichere Methode ist die Berechnung per Power Query. Also ab dem 2. Monat jeden Monat voll zählen, den ersten Monat anteilig (bis zu 100%). Die einzige Einschränkung: Es wird genau 1 Zeitraum berechnet, 2 Zellen; mehrere Zeilen mit Start-Ende Daten bringen ein falsches Ergebnis.

Da das ganze doch etwas mehr Aufwand bedeutete als ich es vorausgesehen hatte (und ich eine transparente Lösung einem mehr oder weniger verständlichen Block M-Code vorziehe), werde ich das "Projekt" am 27.07.19 in meinem Blog veröffentlichen. Interessenten sind also eingeladen... 8-)
Gruß
Günther

Excel-ist-sexy!
Wenn du keine Excel-Version angegeben hast, gehe ich von mindestens Excel 2016 aus.
Hilfe zur Selbsthilfe, das ist IMHO der Sinn eines Forums, nicht Komplettlösungen für den kommerziellen Einsatz und das "natürlich" gratis!
Benutzeravatar
GMG-CC
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 4090
Registriert: 12. Nov 2011, 23:17
Wohnort: Geesthacht bei Hamburg

Re: Nur ganze Monate zählen

Beitragvon Ronny_ » 12. Jul 2019, 08:12

Hallo GMG-CC,

das klingt interessant, ich werde definitiv reinschauen.

Mit Power Query habe ich neulich meine erste Auswertung erstellt. Die Logik dahinter, einmal Aufwand in die Regeln reinstecken und dann können z.B. neue Daten in gleicher Struktur automatisch neu ausgewertet werden, ist schon klasse.

Nach mehreren Tests mit der Formel von Daniel scheint mir seine Formel aber für diesen Sachverhalt zu passen.

Danke für eure Hilfe insgesamt.

Gruß
Ronny
Ronny_
 

Re: Nur ganze Monate zählen

Beitragvon slowboarder » 12. Jul 2019, 08:17

Hi


Mit DATUM(...;...+1;1) bekommst du den ersten des Folgemonats
Mit DATUM(...;...+1;0) den letzten des aktuellen Monats. Was du für deine Berechnung benötigt, musst du ausprobieren.

Wenn du dem nicht traust, kannst du auch so rechnen.

=(Jahr(Ende)-Jahr(Start))*12+Monat(Ende)-Monat(Start)

Gruß Daniel

PS PoweQuery wäre hier aber die Kanone, mit der man auf einen Spatzen schießt
slowboarder
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 25932
Registriert: 18. Apr 2009, 13:33

Nächste

Zurück zu Excel Forum (provisorisch)

Wer ist online?

Mitglieder in diesem Forum: MisterBurns, TommyDerWalker und 15 Gäste