txt Datei Zeile für Zeile auslesen

[sebastianbraun6]

Hallo!

Ich verwende folgenden Code um den gesamten Text einer txt auszulesen und in einer TextBox in einem Userform anzuzeigen.

Code: Alles auswählen

On Error GoTo errhandlerComboBox1
Dim TextFileComboBox1 As Integer
Dim FilePathComboBox1 As String
Dim FileContentComboBox1 As String
  FilePathComboBox1 = "C:\Test\Test.txt"
  TextFileComboBox1 = FreeFile
  Open FilePathComboBox1 For Input As TextFileComboBox1
  FileContentComboBox1 = Input(LOF(TextFileComboBox1), TextFileComboBox1)
  Close TextFileComboBox1
TextBox1.Value = FileContentComboBox1
errhandlerComboBox1:

Jetzt brächte ich das ganze genau so, nur dass er nur die z.b: Zeile 2 ausliest. (Txt besteht nur aus 3 Zeilen).
Gibt es da eine Möglichkeit einzuschränken was der FileContentComboBox1 Wert ist? Eben hald nur die 2te Zeile dieser txt.

PS: Das Beispiel ist sehr vereinfacht, im Endeffekt sind es tausende txt Dateien, wo eben nur die X-te Zeile ausgelesen werden soll.

lg. Sebastian

[Eierlein]

Code: Alles auswählen

 
...
...
  DIM Zeile AS LONG
    Zeile = 0

...
...

    OPEN FilePathComboBox1 FOR INPUT AS TextFileComboBox1
    WHILE NOT EOF(TextFileComboBox1)
        Zeile = Zeile +1
        LINE INPUT #TextFileComboBox1, FileContentComboBox1
        IF Zeile = 2 THEN
            CLOSE TextFileComboBox1
        END IF
    WEND
    CLOSE TextFileComboBox1   '<---- Zur Sicherheit, falls Zeile 2 nicht vorhanden
    TextBox1.Value = FileContentComboBox1


[sebastianbraun6]

Hallo! Danke für die Antwort.

Da bekommen ich für

Code: Alles auswählen

Dim TextFileComboBox1 As Integer
Dim FilePathComboBox1 As String
Dim FileContentComboBox1 As String
Dim Zeile As Long
    Zeile = 0
'File Path of Text File
  FilePathComboBox1 = "Q:\NOE\1_Gruppen\Abt23\Sachbearbeitung\+ Vorlagen +\Makros\ZVFueller\Verbindungsstellen\" & ComboBox1.Value & ".txt"
'Determine the next file number available for use by the FileOpen function
  TextFileComboBox1 = FreeFile
'Open the text file
   Open FilePathComboBox1 For Input As TextFileComboBox1
    While Not EOF(TextFileComboBox1)
        Zeile = Zeile + 1
        Line Input #TextFileComboBox1, FileContentComboBox1
        If Zeile = 2 Then
            Close TextFileComboBox1
        End If
    Wend
    Close TextFileComboBox1   '<---- Zur Sicherheit, falls Zeile 2 nicht vorhanden
    TextBox1.Value = FileContentComboBox1

einen Fehler bei

Code: Alles auswählen

    While Not EOF(TextFileComboBox1)

Laufzeitfehler 52:
Dateiname oder -nummer falsch

[knobbi38]

Hallo Sebastian,

ich habe mal die Idee von Eierlein aufgegriffen und das als Funktion umgebaut, wobei die Fehlerausgabe im Direktfenster erfolgt:

Code: Alles auswählen

Option Explicit

Public Function ReadLineFromFile( _
    ByVal Filename As String, _
    Optional ByVal LineNo As Integer = 1) As String
 
  Dim strLineBuffer As String
  Dim intFNr As Integer
  Dim intLine As Integer
   
  On Error GoTo Err_Handler
 
  If LineNo > 0 Then
    intFNr = FreeFile()
    intLine = 0
 
    Open Filename For Input Access Read As #intFNr
 
    ' Lese vorwärst bis zur bestimmten Zeile
    ' oder bis das Dateiende erreicht wird,
    ' je nachdem, was zuerst Eintritt
    Do While Not EOF(intFNr) And intLine < LineNo
      Line Input #intFNr, strLineBuffer
      intLine = intLine + 1
    Loop
 
    ' Wenn die bestimmte Zeile gelesen worden ist,
    ' gebe den Inhalt zurück.
    If intLine = LineNo Then
      ReadLineFromFile = strLineBuffer
    End If
  End If
 
Exit_Handler:
  Close #intFNr
  Exit Function
 
Err_Handler:
  Debug.Print "ReadLineFromFile() Error:"; _
      Err.Number; Err.Description; "!"
  Resume Exit_Handler
End Function


Der Code gehört in ein Modul und würde dann bei dir so aufgerufen:

Code: Alles auswählen

TextBox1.Value = ReadLineFromFile(FilePathComboBox1,2)

Gruß Ulrich

[Eierlein]

Das passiert wenn man nicht testet.

Entweder so

Code: Alles auswählen

.....
  Open FilePathComboBox1 For Input As TextFileComboBox1
    While Not EOF(TextFileComboBox1)
        Zeile = Zeile + 1
        Line Input #TextFileComboBox1, FileContentComboBox1
        If Zeile = 2 Then
              TextBox1.Value = FileContentComboBox1
        End If
    Wend
    Close TextFileComboBox1   
 


oder wenn deine TextDatei tausende Zeilen hat so:

Code: Alles auswählen

...
  Open FilePathComboBox1 For Input As TextFileComboBox1
    Do While Not EOF(TextFileComboBox1)
        Zeile = Zeile + 1
        Line Input #TextFileComboBox1, FileContentComboBox1

        If Zeile = 2 Then Exit Do   '<----
    Loop
    Close TextFileComboBox1   
   TextBox1.Value = FileContentComboBox1


[knobbi38]

@Eierlein:
zwei Anmerkungen zu deinem zweiten Beispiel:
1) die Zeile "If Zeile = 2 Then Exit Do '<----"
kann auch gleich mit in die Bedingung für die Schleife aufgenommen werden:

Code: Alles auswählen

Zeile = 0
Do While Not EOF(TextFileComboBox1) and Zeile < 2
  ...
Loop

2) Wenn die Datei nur eine Zeile hat, wird das falsche Ergebnis zurück geliefert, ohne daß das bemerkt werden könnte -> sehr schwer zu findender Fehler!

Gruß Ulrich

[Eierlein]

2) Wenn die Datei nur eine Zeile hat, wird das falsche Ergebnis zurück geliefert, ohne daß das bemerkt werden könnte

ToDo Liste für Sebastion:
Prüfen ob eine 2. Zeile vorhanden ist.
Prüfen ob in der 2. Zeile Text drin steht. Nicht nur CrLf.
Wenn nicht Fehlerbehandlung.

Kann entfallen wenn sicher ist, das alle Dateien 3 Zeilen enthalten. Wie behauptet.

[knobbi38]

@Eierlein:

...Kann entfallen wenn sicher ist, das alle Dateien 3 Zeilen enthalten. Wie behauptet.

Das sind dann die Programme, die manchmal laufen und machmal nicht - und keiner weiß warum.
Das ist Basteln und hat mit Programmierung nichts mehr zu tun!

Ulrich

[theoS]

Grundsätzliche Frage...
Woher kommt die txt?
Welche Kodierung?
Welches Zeilenende?

[sebastianbraun6]

Grundsätzliche Frage...
Woher kommt die txt?
Welche Kodierung?
Welches Zeilenende?

Oh Gott, jetzt kommt wieder so eine Frage die offenlegt wie wenig Ahnung ich vom Programmieren habe.

Simpel gesagt: Für jeden Kunden wird eine txt Datei angelegt, in der in der ersten Zeile Name, in der zweiten Zeile Adresse und in der dritten Zeile eine Bemerkung steht. Diese txt Dateien liegen auf einem Abteilungsordner, auf dem jeder User zugriff hat. So kann ich Kunden anlegen und löschen, ohne das Userform bei jedem User zu aktualisieren (Derzeit sind alle Kunden im Userform Code einzeln aufgelistet, was natürlich ein riesen Aufwand ist/war).

Ich werde eure Vorschläge mal testen und dann Rückmeldung geben.

[knobbi38]

Hallo,

dafür gab es früher ein analoges Rolodex auf dem Schreibtisch - das war einfacher.

Gruß Ulrich

[sebastianbraun6]

Hallo!

Funktioniert alles soweit super! Vielen Dank