Einfache Herangehensweise für Textfunktion gesucht

Moderator: ModerationP

Einfache Herangehensweise für Textfunktion gesucht

Beitragvon Manni12 » 12. Aug 2018, 10:52

Hallo in die Runde der Excel-Textfunktionsexperten,

gesucht ist diesmal von mir aus nicht die Lösung, sondern eher, wie man eine lange Textformel sinnvoll zerlegt, so dass es auch ein Laie versteht.

Zunächst die Namen, die in Vor-und Nachname mittels Textfunktion zerlegt werden sollen:

Meier, Hedwig
Seeler, Gerhard
Gründel, Georg
Binsen Hans
Pfaff-Mendes, Karla

Teilweise gibt es Kommata als Trennzeichen, dann sind es Leerzeichen. Die richtigen Formel lauten:

=LINKS(GLÄTTEN(WECHSELN(A1;",";));SUCHEN(" ";GLÄTTEN(WECHSELN(A1;",";" ")))) und
=RECHTS(GLÄTTEN(WECHSELN(A1;",";));LÄNGE(GLÄTTEN(WECHSELN(A1;",";)))-SUCHEN(" ";GLÄTTEN(WECHSELN(A1;",";" "))))

Mich würde interessieren, wie ihr die Formel möglichst einfach in Hilfsspalten zerlegt, so dass dies auch ein nicht so geübter Anwender relativ einfach hinbekommt.

Die einzelnen Schritte zu Lösung habe ich schon mal beschrieben:

Zunächst müssen Komma und Leerzeichen zusammengebracht werden. Dies erfolgt mittels der Funktion WECHSELN.
Später werden zu viel erzeugte Leerzeichen wieder entfernt
Alle unnötigen Leerzeichen werden durch die Funktion GLÄTTEN entfernt
Nun muss die Position des Leerzeichens ermittelt werden. Dies erfolgt durch die Funktion SUCHEN
Alles, was rechts vom Komma steht, gehört zum Vornamen. Da dieser unterschiedlich lang und auch mehrteilig sein kann, berechnen sich die Anzahl der
Zeichen nach dem Leerzeichen. Dazu subtrahieren Sie die Gesamtlänge des Namens - ermittelt mit LÄNGE - die Position des Leerzeichens - also LÄNGE - SUCHEN.
Die so gewonnene Längeninformation zum Text rechts vom Leerzeichen nutzen Sie, um mit RECHTS den Vornamen auszulesen.
Mit SUCHEN und LINKS ermitteln Sie den Nachnamen.


Wäre lieb, wenn ihr mir da ein wenig mit Tipps weiterhelfen könntet.

LG Manni
Manni12
 

Re: Einfache Herangehensweise für Textfunktion gesucht

Beitragvon Klaus-Dieter » 12. Aug 2018, 11:07

Hallo,

das würde ich gar nicht mit Formeln lösen. Spalte markieren, Reiter daten / Text in Spalten / Trennzeichen Komma und Leerzeichen anhaken, fertig.
Viele Grüße
Klaus-Dieter
Lösungsvorschläge sind, wenn es keinen anders lautenden Hinweis gibt, von mir getestet.
Künstliche Intelligenz ist besser als natürliche Dummheit.
Benutzeravatar
Klaus-Dieter
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 17397
Registriert: 27. Nov 2003, 23:03
Wohnort: Sassenburg

Re: Einfache Herangehensweise für Textfunktion gesucht

Beitragvon shift-del » 12. Aug 2018, 11:12

Hallo

Bei deiner ersten Formel bleibt noch ein Leerzeichen am Ende übrig.

Meine Formeln sind in Summe kürzer.

D1: =WECHSELN(A1;",";)
E1: =SUCHEN(" ";D1)
F1: =LINKS(A1;E1-1)
G1: =GLÄTTEN(WECHSELN(D1;F1;))
Wir sehen uns!
... shift-del
Eine Mustertabelle hilft beim Helfen.
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
Benutzeravatar
shift-del
Moderator
 
Beiträge: 19814
Registriert: 25. Jan 2009, 22:54
Wohnort: Ehemaliges Fabrikgelände

Re: Einfache Herangehensweise für Textfunktion gesucht

Beitragvon Manni12 » 12. Aug 2018, 12:00

@Klaus-Dieter: Danke für Deine Antwort und die einfache Lösung.
Bei mir passiert dann aber Folgendes, wenn ich die Trennung Text in Spalten vornehme

Die Einrückung stimmt teilweise nicht, denn teilweise sind auch Leerzeichen vor dem ersten Buchstaben (habe ich in meinem Beispiel nicht aufgeführt - sorry!)

Meier Hedwig
Seeler Gerhard
Gründel Georg
Binsen Hans
Pfaff-Mendes Katja

Geht es dann immer noch so einfach mit Text in Spalten?

@shift-del: Prima, so die Formel zu zerlegen und noch ein wenig einfacher. Danke hierfür.
Manni12
 

Re: Einfache Herangehensweise für Textfunktion gesucht

Beitragvon M. Gottschalk » 13. Aug 2018, 10:44

Hallo Manni,

ich würde das ganze so lösen:

B1:
Code: Alles auswählen
=TEIL(A1;1;D1-1)

C1:
Code: Alles auswählen
=GLÄTTEN(TEIL(A1;D1+1;LÄNGE(A1)))

D1:
Code: Alles auswählen
=WENNFEHLER(FINDEN(",";A1);FINDEN(" ";A1))


Die Formeln sind zwar etwas länger wie die von Shift-Del, dafür brauchst du nur eine Hilfsspalte
Viele Grüße,
Matthias

-------------------------------------------------------------------------------------------
Man muß nicht alles wissen, man muß nur wissen, wie man die Lösung findet.
Benutzeravatar
M. Gottschalk
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 2949
Registriert: 07. Nov 2013, 13:26

Re: Einfache Herangehensweise für Textfunktion gesucht

Beitragvon BoskoBiati » 13. Aug 2018, 11:57

Hi,

die Formeln des TE gehen auch einfacher, dann kann sie auch ein ungeübter Anwender verstehen:

Code: Alles auswählen
=GLÄTTEN(WECHSELN(LINKS(A1;SUCHEN(" ";GLÄTTEN(A1)));",";))
=GLÄTTEN(WECHSELN(WECHSELN(A1;B1;);",";))


oder mit einer Spalte mehr:
Code: Alles auswählen
=GLÄTTEN(A1)
=WECHSELN(LINKS(B1;SUCHEN(" ";B1)-1);",";)
=GLÄTTEN(WECHSELN(WECHSELN(B1;C1;);",";))

Bei Text in Spalten müsste man über die Nachnamen noch mal mit Suchen/Ersetzen die Leerzeichen entfernen.
Gruß

Bosko

Ich würde mich freuen zu erfahren, ob ich helfen konnte.
BoskoBiati
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 8041
Registriert: 26. Jul 2009, 21:46

Re: Einfache Herangehensweise für Textfunktion gesucht

Beitragvon Manni12 » 13. Aug 2018, 14:14

Hallo Matthias,
hallo Bosko,

habe gar nicht gedacht, dass es Tage später noch so tolle Lösungen gibt. Beide Formeln sind doch deutlich einfacher als meine "Monsterformeln" und ich habe sie sofort verstanden.
Ganz lieben Dank Euch beiden - einfach großartig - das Forum hier.

LG Manni
Manni12
 


Zurück zu Excel Forum (provisorisch)

Wer ist online?

Mitglieder in diesem Forum: MisterBurns und 21 Gäste