Index und Vergleich mit ignorieren von leeren Feldern oder 0

Moderator: ModerationP

Index und Vergleich mit ignorieren von leeren Feldern oder 0

Beitragvon ToGe2 » 24. Jul 2019, 14:50

Hallo zusammen,

ich habe mehrere Probleme bei der Auswertung von Tabellenblättern. Eine Beispieldatei habe ich angehängt.

Das erste Problem ist vermutlich trivial, aber ich finde einfach keine Lösung dafür.
Hier soll ein Eingabefeld mit Werten in einem anderen Tabellenblatt (Pr) verglichen werden und dann ein Wert aus einer anderen Spalte (C) ausgegeben werden. Problem: diese zu vergleichenden Werte kommen mehrmals vor und in der Spalte des gewünschten Ausgabewerts kommen leere Felder und Nullen vor.
Wie kann man diese leeren Felder oder Nullen überspringen?

Das zweite Problem ist, den Wert aus dem Eingabefeld in Tabellenblatt 1 (Pr) zu finden und diesen Wert in Tabellenblatt 2 (St) zu suchen und den zugehörigen Wert einer anderen Spalte auszugeben.

Das dritte Problem ist wie Problem zwei mit einer zusätzlichen Auswahl aus einem Dropdown-Menü. Den Wert aus dem Eingabefeld in Tabellenblatt 1 (Pr) zu finden und diesen Wert in Tabellenblatt 2 (St) zu suchen und den zugehörigen Wert einer anderen Spalte, die durch ein Dropdown-Menü bestimmt wird, auszugeben.

Für jegliche Hinweise zur Problemlösung wäre ich sehr dankbar.

Viele Grüße
ToGe2
Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.
ToGe2
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 11
Registriert: 24. Jul 2019, 12:00

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon shift-del » 25. Jul 2019, 20:20

Moin

1.
Code: Alles auswählen
=MAXWENNS(Pr!C1:C12;Pr!A1:A12;B3)


2.
Code: Alles auswählen
=SVERWEIS(MAXWENNS(Pr!D1:D12;Pr!A1:A12;B3);St!A2:D22;4;FALSCH)


3.
Code: Alles auswählen
=SVERWEIS(MAXWENNS(Pr!D1:D12;Pr!A1:A12;B3);St!A2:D22;VERGLEICH(B1;St!A1:D1;0);FALSCH)
Wir sehen uns!
... shift-del
Eine Mustertabelle hilft beim Helfen.
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
Benutzeravatar
shift-del
Moderator
 
Beiträge: 20701
Registriert: 25. Jan 2009, 22:54
Wohnort: Ehemaliges Fabrikgelände

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon ToGe2 » 25. Jul 2019, 20:54

Hallo,

Wahnsinn! Herzlichen Dank!

Viele Grüße
ToGe2

Edit: Ich nehme an der Workaround für Excel 2013 ist dann MAX mit WENN verknüfen?
ToGe2
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 11
Registriert: 24. Jul 2019, 12:00

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon ToGe2 » 26. Jul 2019, 11:30

Hallo,

falls es jemand anderes auch benötigt. Die ersten beiden habe ich schon "übersetzt" in Excel 2013.

1. Arrayformel mit "STRG+UMSCHALT+EINGABE"
Code: Alles auswählen
{=MAX(WENN(Pr!A1:A12=$B$3;Pr!C1:C12;""))}


2. Arrayformel mit "STRG+UMSCHALT+EINGABE"
Code: Alles auswählen
{=INDEX(St!D:D;VERGLEICH(MAX(WENN(Pr!A1:A12=$B$3;Pr!D1:D12;""));St!A:A;0))}


Die 3. schaffe ich hoffentlich auch noch :)

Viele Grüße
ToGe2
ToGe2
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 11
Registriert: 24. Jul 2019, 12:00

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon ToGe2 » 29. Jul 2019, 07:26

Hallo,

jetzt habe ich auch die Lösung für die 3. Formel für Excel 2013.

Code: Alles auswählen
{=INDEX(St!A:D;VERGLEICH(MAX(WENN(Pr!A1:A12=$B$3;Pr!D1:D12;""));St!A:A;0);VERGLEICH(B1;St!A1:C1;0))}


Viele Grüße
ToGe2
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 11
Registriert: 24. Jul 2019, 12:00

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon ToGe2 » 16. Aug 2019, 11:47

Hallo,

ich habe wieder ein Problem bei dieser Tabelle. Ich habe die Beispieldatei etwas erweitert. Ich benutze Excel 2013.

1. Ich möchte den Wert aus dem Eingabefeld mit der Spalte A der Tabelle "Pr" vergleichen und in Spalte D prüfen, ob der dort angezeigte Wert größer als 10001 ist. Zusätzlich würde ich gerne in der selben Zeile in Spalte E prüfen, ob der Wert gleich 1 ist. Falls beides zutrifft, dann "Übereinstimmung" ausgeben, falls eines oder beide nicht zutreffen "Keine Übereinstimmung" ausgeben.

2.a) Möchte ich das eben beschriebene Feld prüfen, ob dort "Übereinstimmung" steht. Falls ja, dann möchte ich den Wert aus "St" in Spalte B oder C (je nach Auswahl in B1) plus dem Wert aus A13 ausgegeben haben. Jedoch wieder mit Angabe der Formel, ohne Bezug auf Zeile A13 zu nehmen.
2.b) Falls in dem Feld "Keine Übereinstimmung" steht, möchte ich nur den Wert aus A13, wieder mit einfügen der Formel aus A13, ohne Bezug auf A13.

Mein großes Problem ist, dass keine Möglichkeit finde, die Zeile auszulesen. Falls in der Tabelle "Pr" in Spalte D ein Wert mehrfach vorkommt (im Beispiel 10004), dann findet meine Formel immer die erste Stelle, an der die 10004 vorkommt (im Beispiel Zeile 11). Richtig wäre, diese im Bereich der Nummer in Spalte A (im Beispiel Zeile 16) zu finden. Dann könnte ich sagen prüfe in Tabelle "Pr", Spalte E in der Zeile 16, ob dort die 1 steht.

Für Hilfe bin ich sehr dankbar!

Viele Grüße
ToGe2
Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.
ToGe2
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 11
Registriert: 24. Jul 2019, 12:00

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon juvee » 16. Aug 2019, 12:38

Hi,

jo, das ist logisch, da du lediglich nach 10004 suchst. Du mußt aber nach der Kombination aus 1114 und 10004 suchen

Code: Alles auswählen
{=VERGLEICH(B3&MAX(WENN(Pr!A1:A20=$B$3;Pr!D1:D20;""));Pr!A1:A20&Pr!D1:D20;0)}


dann erhälst du die korrekte Zeile 16

VG Juvee
Ich habe "juvee" am 25.01.2018 gegoogelt. Ich distanziere mich von den ungefähr 252 Einträgen ausdrücklich.
Da binich nich dabei, dat is pri ima, vivaaaaa....lalalala!
juvee
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 2619
Registriert: 05. Jun 2014, 12:48

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon ToGe2 » 17. Aug 2019, 11:10

Hallo,

vielen Dank für den Denkanstoss. Habe zumindest schon mal die erste Lösung.

Code: Alles auswählen
{=WENN(UND(INDIREKT("Pr!"&"D"&VERGLEICH($B$3&MAX(WENN(Pr!A:A=$B$3;Pr!D:D;""));Pr!A:A&Pr!D:D;0))>10001;INDIREKT("Pr!"&"E"&VERGLEICH($B$3&MAX(WENN(Pr!A:A=$B$3;Pr!D:D;""));Pr!A:A&Pr!D:D;0))=1);"Übereinstimmung";"Keine Übereinstimmung")}


Viele Grüße
ToGe2
ToGe2
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 11
Registriert: 24. Jul 2019, 12:00

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon juvee » 17. Aug 2019, 13:25

Hi,

nimm statt Indirekt() Index(), da Indirekt() als volatile Funktion Performance frisst

VG Juvee
Ich habe "juvee" am 25.01.2018 gegoogelt. Ich distanziere mich von den ungefähr 252 Einträgen ausdrücklich.
Da binich nich dabei, dat is pri ima, vivaaaaa....lalalala!
juvee
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 2619
Registriert: 05. Jun 2014, 12:48

Re: Index und Vergleich mit ignorieren von leeren Feldern od

Beitragvon ToGe2 » 17. Aug 2019, 19:42

Hallo juvee,

okay, danke für den HInweis. Ich werde das mal ausprobieren.

Viele Grüße ToGe2

Edit:
Dann wohl so?
Code: Alles auswählen
{=WENN(UND(INDEX(Pr!D:D;VERGLEICH(B3&MAX(WENN(Pr!A1:A20=$B$3;Pr!D1:D20;""));Pr!A1:A20&Pr!D1:D20;0))>10001;INDEX(Pr!E:E;VERGLEICH(B3&MAX(WENN(Pr!A1:A20=$B$3;Pr!D1:D20;""));Pr!A1:A20&Pr!D1:D20;0))=1);"Übereinstimmung";"Keine Übereinstimmung")}
ToGe2
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 11
Registriert: 24. Jul 2019, 12:00


Zurück zu Excel Forum (provisorisch)

Wer ist online?

Mitglieder in diesem Forum: TommyDerWalker und 14 Gäste