Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
bestimter teil eines textes soll in einer anderen zelle ausg
zurück: Horoskop weiter: Excel Vergleich einer Zelle mit einer ganzen Spalte Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Bitte Status wählen ! Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
gast0815
Gast


Verfasst am:
03. Aug 2005, 11:14
Rufname:

bestimter teil eines textes soll in einer anderen zelle ausg - bestimter teil eines textes soll in einer anderen zelle ausg

Nach oben
       

Halli Hallo,

Ich habe jetzt schon einige Zeit mit dem Formelsuchen verbracht, jedoch bin ich immer noch nicht auf eine Lösung gekommen.

Mein Problem:

Ich habe eine Namensspalte in dieser sich Vornamen und Nachnamen getrennt durch leerzeichen befinden.
Teilweise steht in der zelle auch noch ein zweiter vorname und familiennamen können mit bindestrich verbunden sein.

Was will ich:
nur den ges. Familienname soll in eine nebenstehende zelle geschrieben werden.

z.B.
Michael Beran
Ing. Karl Kobierski
Martin Gruber
Alexander Szadeczky-Kardoss
Dr. Kurt-Wolfram Rodatz


Schon mal vor ab, danke für die infos
ae
Mein Name ist Ente


Verfasst am:
03. Aug 2005, 11:20
Rufname: Andreas
Wohnort: Reppenstedt bei Lüneburg


AW: bestimter teil eines textes soll in einer anderen zelle - AW: bestimter teil eines textes soll in einer anderen zelle

Nach oben
       

Hallo,
schau dir mal diesen Beitrag an

http://excelformeln.de/formeln.html?welcher=158

_________________
Gruß
Andreas E
------
Oh Mann, ich fühl mich heute wie =DATEDIF(DATUM(1961;6;12);HEUTE();"y") Jahre alt
fridgenep
Gast


Verfasst am:
03. Aug 2005, 13:30
Rufname:

AW: bestimter teil eines textes soll in einer anderen zelle - AW: bestimter teil eines textes soll in einer anderen zelle

Nach oben
       

Hallo,

ich kann den Link von Andreas nicht öffnen, daher hier mal eine kleine Formel:

Code:
=RECHTS(A1;LÄNGE(A1)-FINDEN(" ";A1))


in A1 steht der Vor- und Zuname.
ae
Mein Name ist Ente


Verfasst am:
03. Aug 2005, 13:33
Rufname: Andreas
Wohnort: Reppenstedt bei Lüneburg

AW: bestimter teil eines textes soll in einer anderen zelle - AW: bestimter teil eines textes soll in einer anderen zelle

Nach oben
       

Hallo fridgenep,
hier das ganze mal als Zitat - der Vorteil dran ist das auch Namenszusätze erkannt werden

Zitat:
Vornamen (auch doppelte) und Nachnamen (mit Titel) trennen (158)


Aufgabe
Vornamen und Nachnamen sollen getrennt werden.
Dabei sollen auch zwei oder keine Vornamen vorkommen dürfen genauso wie Zusätze zum Nachnamen.
Beispiele:

Cher wird zu Cher
Anne Brügger wird zu Anne / Brügger
Eva Maria Reininger wird zu Eva Maria / Reininger
Karl Maria von Weber wird zu Karl Maria / von Weber
Gräfin Carlotta Theresa von der Lippe wird zu Gräfin Carlotta Theresa / von der Lippe
Prof. Dr. habil. Franz ob der Tauber wird zu Prof. Dr. habil. Franz / ob der Tauber


Lösung
Der komplett ausgeschriebene Name steht in A1.

Vorname in B1 (für den Normalfall: nur ein Vorname und ein Nachname)
=LINKS(A1;FINDEN(" ";A1))

in B1: max. 2 Vornamen; Adelstitel; akademische Grade
(funktioniert logischerweise auch für den "Normalfall")

=WENN(ODER(ISTFEHLER(FINDEN(" ";A1));CODE(LINKS(A1;1))>96);"";WENN(UND(ISTFEHLER(FINDEN("ob ";A1));ISTFEHLER(FINDEN("von ";A1));ISTFEHLER(FINDEN("zu ";A1))); WENN(UND(CODE(TEIL(A1;FINDEN(" ";A1)+1;1)) < 97;LÄNGE(A1)-LÄNGE(WECHSELN(A1;" ";)) > 1);TEIL(A1;1;FINDEN(" ";A1;FINDEN(" ";A1)+1));TEIL(A1;1;FINDEN(" ";A1)));LINKS(A1; WENN(NICHT(ISTFEHLER(FINDEN("von ";A1)));FINDEN("von ";A1);WENN(NICHT(ISTFEHLER(FINDEN("zu ";A1)));FINDEN("zu ";A1);FINDEN("ob ";A1)))-1)))

Nachname in C1
=RECHTS(A1;LÄNGE(A1)-LÄNGE(B1))

Alternative (als Array-Formel ganz anders aufgebaut):
Nachname in C1:
{=WENN(ANZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A1));TEIL(A1;MIN(WENN(ISTZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A1));FINDEN({" von ";" zu ";" ob ";" van ";" de "};A1)))+1;99);TEIL(A1;MAX((TEIL(A1;SPALTE($1:$1);1)=" ")*SPALTE($1:$1))+1;99))}

Vorname:
=GLÄTTEN(LINKS(A1;LÄNGE(A1)-LÄNGE(C1)))

Erläuterung
Die Array-Alternative ist prinzipiell besser (und kürzer), läßt mehr als 2 Vornamen zu und trennt auch Namen in kleinbuchstaben.
Der Nachteil: man muß alle Namenszusätze definitiv vorgeben; - in der Ursprungsformel wird außer den dominierenden "von "; "zu "; "ob " nach einem Kleinbuchstaben gesucht (bei exotischen/ausländischen - also unbekannten - Namenszusätzen noch unschlagbar).
Das non-plus-ultra wird ne' Kombi von beiden werden; - wir tun was!
WF

_________________
Gruß
Andreas E
------
Oh Mann, ich fühl mich heute wie =DATEDIF(DATUM(1961;6;12);HEUTE();"y") Jahre alt
fridgenep
Gast


Verfasst am:
03. Aug 2005, 13:39
Rufname:


AW: bestimter teil eines textes soll in einer anderen zelle - AW: bestimter teil eines textes soll in einer anderen zelle

Nach oben
       

Hi Andreas,

danke für Ansicht der verborgenen Seite.

Ich hoffe nur, dass du den Gast damit nicht überrumpelt hast.

Aber du hast Recht, hab den 2. Vornamen übersehen.
fridgenep
Gast


Verfasst am:
03. Aug 2005, 13:48
Rufname:

AW: bestimter teil eines textes soll in einer anderen zelle - AW: bestimter teil eines textes soll in einer anderen zelle

Nach oben
       

Hallo,

wie wäre es so?

Code:
=WENN(A1="";"";WENN(ISTFEHLER(FINDEN(" ";A1;FINDEN(" ";A1)+1));RECHTS(A1;LÄNGE(A1)-FINDEN(" ";A1));RECHTS(A1;LÄNGE(A1)-FINDEN(" ";A1;FINDEN(" ";A1)+1))))
ae
Mein Name ist Ente


Verfasst am:
03. Aug 2005, 14:10
Rufname: Andreas
Wohnort: Reppenstedt bei Lüneburg

AW: bestimter teil eines textes soll in einer anderen zelle - AW: bestimter teil eines textes soll in einer anderen zelle

Nach oben
       

Hallo fridgenep -
das ist ja schon wesentlich kürzer und greift vieles ab !
Allerdings sind da einige Ausreisser

Tabelle2
 ABC
1 FRIDGENEPEXCELFORMELN
2Andreas EntenmannEntenmannEntenmann
3Hein von der Werftder Werftvon der Werft
4Susi Freifrau von Steinvon Steinvon Stein
5Frau Professor BardenBardenBarden
6Herr Dr. EntenmannEntenmannEntenmann
7Götz von BerlichingenBerlichingenvon Berlichingen
Formeln der Tabelle
B2 : =WENN(A2="";"";WENN(ISTFEHLER(FINDEN(" ";A2;FINDEN(" ";A2)+1));RECHTS(A2;LÄNGE(A2)-FINDEN(" ";A2));RECHTS(A2;LÄNGE(A2)-FINDEN(" ";A2;FINDEN(" ";A2)+1))))
C2 : {=WENN(ANZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A2));TEIL(A2;MIN(WENN(ISTZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A2));FINDEN({" von ";" zu ";" ob ";" van ";" de "};A2)))+1;99);TEIL(A2;MAX((TEIL(A2;SPALTE($1:$1);1)=" ")*SPALTE($1:$1))+1;99))}
B3 : =WENN(A3="";"";WENN(ISTFEHLER(FINDEN(" ";A3;FINDEN(" ";A3)+1));RECHTS(A3;LÄNGE(A3)-FINDEN(" ";A3));RECHTS(A3;LÄNGE(A3)-FINDEN(" ";A3;FINDEN(" ";A3)+1))))
C3 : {=WENN(ANZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A3));TEIL(A3;MIN(WENN(ISTZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A3));FINDEN({" von ";" zu ";" ob ";" van ";" de "};A3)))+1;99);TEIL(A3;MAX((TEIL(A3;SPALTE($1:$1);1)=" ")*SPALTE($1:$1))+1;99))}
B4 : =WENN(A4="";"";WENN(ISTFEHLER(FINDEN(" ";A4;FINDEN(" ";A4)+1));RECHTS(A4;LÄNGE(A4)-FINDEN(" ";A4));RECHTS(A4;LÄNGE(A4)-FINDEN(" ";A4;FINDEN(" ";A4)+1))))
C4 : {=WENN(ANZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A4));TEIL(A4;MIN(WENN(ISTZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A4));FINDEN({" von ";" zu ";" ob ";" van ";" de "};A4)))+1;99);TEIL(A4;MAX((TEIL(A4;SPALTE($1:$1);1)=" ")*SPALTE($1:$1))+1;99))}
B5 : =WENN(A5="";"";WENN(ISTFEHLER(FINDEN(" ";A5;FINDEN(" ";A5)+1));RECHTS(A5;LÄNGE(A5)-FINDEN(" ";A5));RECHTS(A5;LÄNGE(A5)-FINDEN(" ";A5;FINDEN(" ";A5)+1))))
C5 : {=WENN(ANZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A5));TEIL(A5;MIN(WENN(ISTZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A5));FINDEN({" von ";" zu ";" ob ";" van ";" de "};A5)))+1;99);TEIL(A5;MAX((TEIL(A5;SPALTE($1:$1);1)=" ")*SPALTE($1:$1))+1;99))}
B6 : =WENN(A6="";"";WENN(ISTFEHLER(FINDEN(" ";A6;FINDEN(" ";A6)+1));RECHTS(A6;LÄNGE(A6)-FINDEN(" ";A6));RECHTS(A6;LÄNGE(A6)-FINDEN(" ";A6;FINDEN(" ";A6)+1))))
C6 : {=WENN(ANZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A6));TEIL(A6;MIN(WENN(ISTZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A6));FINDEN({" von ";" zu ";" ob ";" van ";" de "};A6)))+1;99);TEIL(A6;MAX((TEIL(A6;SPALTE($1:$1);1)=" ")*SPALTE($1:$1))+1;99))}
B7 : =WENN(A7="";"";WENN(ISTFEHLER(FINDEN(" ";A7;FINDEN(" ";A7)+1));RECHTS(A7;LÄNGE(A7)-FINDEN(" ";A7));RECHTS(A7;LÄNGE(A7)-FINDEN(" ";A7;FINDEN(" ";A7)+1))))
C7 : {=WENN(ANZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A7));TEIL(A7;MIN(WENN(ISTZAHL(FINDEN({" von ";" zu ";" ob ";" van ";" de "};A7));FINDEN({" von ";" zu ";" ob ";" van ";" de "};A7)))+1;99);TEIL(A7;MAX((TEIL(A7;SPALTE($1:$1);1)=" ")*SPALTE($1:$1))+1;99))}

Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 

_________________
Gruß
Andreas E
------
Oh Mann, ich fühl mich heute wie =DATEDIF(DATUM(1961;6;12);HEUTE();"y") Jahre alt
fridgenep
Gast


Verfasst am:
03. Aug 2005, 14:38
Rufname:

AW: bestimter teil eines textes soll in einer anderen zelle - AW: bestimter teil eines textes soll in einer anderen zelle

Nach oben
       

Hi,

nee, nee... nun mal langsam.

Vorgabe war:

2 Vornamen: erfüllt
mehere Nachnamen werden durch Bindestrich getrennt.: erfüllt


und das war´s schon.

Ich wollt mit meiner Formel hier keine bisher erarbeitet Lösung auf den Kopf stellen.

Aber für den Zweck des Gastes sollte es reichen.
ae
Mein Name ist Ente


Verfasst am:
03. Aug 2005, 14:43
Rufname: Andreas
Wohnort: Reppenstedt bei Lüneburg


AW: bestimter teil eines textes soll in einer anderen zelle - AW: bestimter teil eines textes soll in einer anderen zelle

Nach oben
       

Hallo,

Zitat:
Vorgabe war:

2 Vornamen: erfüllt
mehere Nachnamen werden durch Bindestrich getrennt.: erfüllt


Da hast du völlig recht - mir ging es darum, daß diese von dir erarbeitete Lösung schon fast so viel abgreift wie die andere und wesentlich kürzer und verständlicher ist

_________________
Gruß
Andreas E
------
Oh Mann, ich fühl mich heute wie =DATEDIF(DATUM(1961;6;12);HEUTE();"y") Jahre alt
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Vertauschen von Wörter innerhalb einer Zelle 2 Excel 2000 3208 27. Jan 2005, 11:31
Arnim Vertauschen von Wörter innerhalb einer Zelle
Keine neuen Beiträge Excel Formeln: Dateinamen für zu öffnende Tabelle in Zelle vorgeben, wie? 4 excessor 1698 24. Jan 2005, 22:52
A.Knecht Dateinamen für zu öffnende Tabelle in Zelle vorgeben, wie?
Keine neuen Beiträge Excel Formeln: Teilinhalt einer Zelle in einer neuen Zelle kopieren 2 nastromo2001 2812 24. Jan 2005, 18:48
nastromo2001 Teilinhalt einer Zelle in einer neuen Zelle kopieren
Keine neuen Beiträge Excel Formeln: Daten in einer Zelle trennen 2 bsailer 7161 07. Jan 2005, 13:39
bsailer Daten in einer Zelle trennen
Keine neuen Beiträge Excel Formeln: Bei der Formel "=C5-((B6-B5)*G3)" soll die Zelle G 2 Gast 1502 26. Nov 2004, 15:55
Gast Bei der Formel "=C5-((B6-B5)*G3)" soll die Zelle G
Keine neuen Beiträge Excel Formeln: "=TEIL" mit "SVERWEIS" 3 fredi! 1211 10. Nov 2004, 13:01
fredi! "=TEIL" mit "SVERWEIS"
Keine neuen Beiträge Excel Formeln: Werte aus Liste mit Validation in Zelle 1 Gast 2516 18. Okt 2004, 15:20
icke Werte aus Liste mit Validation in Zelle
Keine neuen Beiträge Excel Formeln: spalte einer bestimmten zelle in einer anderen zelle anzeige 1 brouwe 1290 13. Okt 2004, 18:41
Arnim spalte einer bestimmten zelle in einer anderen zelle anzeige
Keine neuen Beiträge Excel Formeln: Leerzeichen in Zelle löschen 3 pkegelking 1807 01. Okt 2004, 11:57
pkegelking Leerzeichen in Zelle löschen
Keine neuen Beiträge Excel Formeln: Formatieren in Abhängigkeit von Zelle 'links'? 9 abidmon 2819 06. Sep 2004, 10:03
abidmon Formatieren in Abhängigkeit von Zelle 'links'?
Keine neuen Beiträge Excel Formeln: übernehmen von werten in eine andere zelle 6 Gast 3717 21. Aug 2004, 18:38
alex81 übernehmen von werten in eine andere zelle
Keine neuen Beiträge Excel Formeln: Zelle Schützen 8 mika2002 1890 29. Jul 2004, 14:51
mika2002 Zelle Schützen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Expression Web